[kde-base] Add KDE SC 4.6.0

(Portage version: 2.2.0_alpha19_p2/cvs/Linux x86_64, RepoMan options: --force)

2 files changed, 77 insertions, 1 deletions

diff --git a/kde-base/kdepimlibs/ChangeLog b/kde-base/kdepimlibs/ChangeLog
index bd623ab86815..66e469b352bb 100644
--- a/kde-base/kdepimlibs/ChangeLog
+++ b/kde-base/kdepimlibs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdepimlibs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.88 2011/01/10 11:53:29 tampakrap Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.89 2011/01/26 20:28:41 alexxy Exp $
+
+*kdepimlibs-4.6.0 (26 Jan 2011)
+
+  26 Jan 2011; Alexey Shvetsov <alexxy@gentoo.org> +kdepimlibs-4.6.0.ebuild:
+  Version bump KDE SC 4.6.0
 
 *kdepimlibs-4.5.5 (10 Jan 2011)
 
diff --git a/kde-base/kdepimlibs/kdepimlibs-4.6.0.ebuild b/kde-base/kdepimlibs/kdepimlibs-4.6.0.ebuild
new file mode 100644
index 000000000000..44a24c27e71a
--- /dev/null
+++ b/kde-base/kdepimlibs/kdepimlibs-4.6.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.6.0.ebuild,v 1.1 2011/01/26 20:28:41 alexxy Exp $
+
+EAPI="3"
+
+KDE_HANDBOOK="optional"
+CPPUNIT_REQUIRED="optional"
+inherit kde4-base
+
+DESCRIPTION="Common library for KDE PIM apps."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug ldap semantic-desktop"
+
+# some akonadi tests timeout, that probaly needs more work as its ~700 tests
+RESTRICT="test"
+
+DEPEND="
+	>=app-crypt/gpgme-1.1.6
+	>=dev-libs/boost-1.35.0-r5
+	dev-libs/libgpg-error
+	>=dev-libs/libical-0.43
+	dev-libs/cyrus-sasl
+	semantic-desktop? (
+		>=app-office/akonadi-server-1.4.52
+		$(add_kdebase_dep kdelibs 'semantic-desktop')
+		media-sound/phonon
+		x11-misc/shared-mime-info
+	)
+	ldap? ( net-nds/openldap )
+"
+RDEPEND="${DEPEND}"
+
+# libakonadi-kcal moved here from akonadi in 4.3.86
+add_blocker akonadi '<4.3.86'
+# @since 4.3 - libkholidays is in kdepimlibs now
+add_blocker libkholidays
+# @since 4.4 - kontactinterfaces is in kdepimlibs now
+add_blocker kontactinterfaces
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Disable hardcoded checks
+	sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
+		-e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
+		-e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
+		-i CMakeLists.txt || die
+	if ! use semantic-desktop; then
+		sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
+			-i CMakeLists.txt || die
+		# More reliable than -DBUILD_akonadi=OFF
+		rm -r akonadi mailtransport || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook doc)
+		$(cmake-utils_use_with ldap)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+	)
+
+	kde4-base_src_configure
+}