[kde-base] Add long waiting KDE SC 4.7.4

(Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/kde-base/kdepimlibs/ChangeLog b/kde-base/kdepimlibs/ChangeLog
index 459be6196a18..cbe6a0b52137 100644
--- a/kde-base/kdepimlibs/ChangeLog
+++ b/kde-base/kdepimlibs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kdepimlibs
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.118 2011/12/07 23:07:51 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/ChangeLog,v 1.119 2011/12/11 18:52:21 alexxy Exp $
+
+*kdepimlibs-4.7.4 (11 Dec 2011)
+
+  11 Dec 2011; Alexey Shvetsov <alexxy@gentoo.org> +kdepimlibs-4.7.4.ebuild:
+  Version bump KDE SC 4.7.4
 
   07 Dec 2011; Andreas K. Huettel <dilfridge@gentoo.org>
   -kdepimlibs-4.7.2.ebuild:
diff --git a/kde-base/kdepimlibs/kdepimlibs-4.7.4.ebuild b/kde-base/kdepimlibs/kdepimlibs-4.7.4.ebuild
new file mode 100644
index 000000000000..818995dc5980
--- /dev/null
+++ b/kde-base/kdepimlibs/kdepimlibs-4.7.4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdepimlibs/kdepimlibs-4.7.4.ebuild,v 1.1 2011/12/11 18:52:21 alexxy Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+CPPUNIT_REQUIRED="optional"
+KDE_SCM="git"
+inherit kde4-base
+
+DESCRIPTION="Common library for KDE PIM apps."
+HOMEPAGE="http://www.kde.org/"
+
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug ldap semantic-desktop"
+
+# some akonadi tests timeout, that probaly needs more work as its ~700 tests
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=app-crypt/gpgme-1.1.6
+	dev-libs/libgpg-error
+	>=dev-libs/libical-0.43
+	dev-libs/cyrus-sasl
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	semantic-desktop? (
+		>=app-office/akonadi-server-1.5.80
+		media-libs/phonon
+		x11-misc/shared-mime-info
+	)
+	ldap? ( net-nds/openldap )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.35.0-r5
+"
+RDEPEND="${COMMON_DEPEND}"
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	# Disable hardcoded checks
+	sed -r -e '/find_package\((Akonadi|SharedDesktopOntologies|Soprano|Nepomuk)/{/macro_optional_/!s/find/macro_optional_&/}' \
+		-e '/macro_log_feature\((Akonadi|SHAREDDESKTOPONTOLOGIES|Soprano|Nepomuk)_FOUND/s/ TRUE / FALSE /' \
+		-e '/add_subdirectory\((akonadi|mailtransport)/{/macro_optional_/!s/add/macro_optional_&/}' \
+		-i CMakeLists.txt || die
+	if ! use semantic-desktop; then
+		sed -e '/include(SopranoAddOntology)/s/^/#DISABLED /' \
+			-i CMakeLists.txt || die
+		# More reliable than -DBUILD_akonadi=OFF
+		rm -r akonadi mailtransport || die
+	fi
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook doc)
+		$(cmake-utils_use_with ldap)
+		$(cmake-utils_use_with semantic-desktop Akonadi)
+		$(cmake-utils_use_with semantic-desktop SharedDesktopOntologies)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		# $(cmake-utils_use_with prison)
+		-DWITH_Prison=NO
+	)
+
+	kde4-base_src_configure
+}