Version bump KDE SC 4.9.3

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 42618354)

1 files changed, 51 insertions, 0 deletions

diff --git a/kde-base/gwenview/gwenview-4.9.3.ebuild b/kde-base/gwenview/gwenview-4.9.3.ebuild
new file mode 100644
index 000000000000..2462399e9419
--- /dev/null
+++ b/kde-base/gwenview/gwenview-4.9.3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/gwenview-4.9.3.ebuild,v 1.1 2012/11/08 23:26:56 creffett Exp $
+
+EAPI=4
+
+KDE_HANDBOOK="optional"
+inherit kde4-base
+
+DESCRIPTION="KDE image viewer"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug kipi semantic-desktop"
+
+# tests hang, last checked for 4.2.96
+RESTRICT="test"
+
+DEPEND="
+	$(add_kdebase_dep kdelibs 'semantic-desktop=')
+	$(add_kdebase_dep libkonq)
+	>=media-gfx/exiv2-0.19
+	virtual/jpeg
+	kipi? ( $(add_kdebase_dep libkipi) )
+"
+RDEPEND="${DEPEND}"
+
+KMLOADLIBS="libkonq"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with kipi)
+	)
+
+	if use semantic-desktop; then
+		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Nepomuk)
+	else
+		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
+	fi
+
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	echo
+	elog "For SVG support, emerge -va kde-base/svgpart"
+	echo
+	use kipi && elog "The plugins for the KIPI inteface can be found in media-plugins/kipi-plugins"
+	use kipi && echo
+}