Bump to 3.5.5 (pre-release).

(Portage version: 2.1.2_pre2-r1)

3 files changed, 98 insertions, 1 deletions

diff --git a/kde-base/arts/ChangeLog b/kde-base/arts/ChangeLog
index e3bffedb7b48..6b8bfc075bb8 100644
--- a/kde-base/arts/ChangeLog
+++ b/kde-base/arts/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/arts
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.234 2006/09/17 22:53:05 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.235 2006/10/03 08:46:09 flameeyes Exp $
+
+*arts-3.5.5 (03 Oct 2006)
+
+  03 Oct 2006; Diego Pettenò <flameeyes@gentoo.org> +arts-3.5.5.ebuild:
+  Bump to 3.5.5 (pre-release).
 
   17 Sep 2006; Carsten Lohrke <carlo@gentoo.org> -arts-3.4.3.ebuild,
   -arts-3.4.3-r1.ebuild:
diff --git a/kde-base/arts/arts-3.5.5.ebuild b/kde-base/arts/arts-3.5.5.ebuild
new file mode 100644
index 000000000000..0b385b2190c8
--- /dev/null
+++ b/kde-base/arts/arts-3.5.5.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/arts-3.5.5.ebuild,v 1.1 2006/10/03 08:46:09 flameeyes Exp $
+
+inherit kde flag-o-matic eutils versionator
+set-kdedir 3.5
+
+MY_PV="1.$(get_version_component_range 2-3)"
+S=${WORKDIR}/${PN}-${MY_PV}
+
+RESTRICT="test"
+
+DESCRIPTION="aRts, the KDE sound (and all-around multimedia) server/output manager"
+HOMEPAGE="http://multimedia.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${PN}-${MY_PV}.tar.bz2"
+#SRC_URI="mirror://kde/stable/3.5/src/${PN}-${MY_PV}.tar.bz2"
+LICENSE="GPL-2 LGPL-2"
+
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa esd artswrappersuid jack mp3 nas vorbis"
+
+RDEPEND="$(qt_min_version 3.3)
+	>=dev-libs/glib-2
+	alsa? ( media-libs/alsa-lib )
+	vorbis? ( media-libs/libogg
+			  media-libs/libvorbis )
+	esd? ( media-sound/esound )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.90 )
+	mp3? ( media-libs/libmad )
+	nas? ( media-libs/nas )
+	media-libs/audiofile"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+PATCHES="${FILESDIR}/arts-1.5.0-bindnow.patch
+	${FILESDIR}/arts-1.5.4-multilib.patch"
+
+src_unpack() {
+	kde_src_unpack
+
+	# Alternative to arts-1.4-mcopidl.patch, make sure that flags are supported
+	# before trying to use them, for non-GCC, vanilla GCC or GCC 4.1 compilers
+	local nosspflags
+
+	nosspflags="$(test-flags -fno-stack-protector -fno-stack-protector-all)"
+	sed -i -e "s:KDE_CXXFLAGS =\(.*\):KDE_CXXFLAGS = \1 ${nosspflags}:" \
+		"${S}/mcopidl/Makefile.am"
+
+	# Fix libao/gaim problems with aRTs. See bug #116290.
+	epatch "${FILESDIR}/arts-1.5.0-check_tmp_dir.patch"
+
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	myconf="$(use_enable alsa) $(use_enable vorbis)
+			$(use_enable mp3 libmad) $(use_with jack)
+			$(use_with esd) $(use_with nas)
+		--with-audiofile --without-mas"
+
+	#fix bug 13453
+	filter-flags -foptimize-sibling-calls
+
+	# breaks otherwise <gustavoz>
+	use sparc && export CFLAGS="-O1" && export CXXFLAGS="-O1"
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# used for realtime priority, but off by default as it is a security hazard
+	use artswrappersuid && chmod u+s "${D}/${PREFIX}/bin/artswrapper"
+}
+
+pkg_postinst() {
+	if ! use artswrappersuid ; then
+		einfo "Run chmod u+s ${PREFIX}/bin/artswrapper to let artsd use realtime priority"
+		einfo "and so avoid possible skips in sound. However, on untrusted systems this"
+		einfo "creates the possibility of a DoS attack that'll use 100% cpu at realtime"
+		einfo "priority, and so is off by default. See bug #7883."
+		einfo "Or, you can set the local artswrappersuid USE flag to make the ebuild do this."
+	fi
+}
diff --git a/kde-base/arts/files/digest-arts-3.5.5 b/kde-base/arts/files/digest-arts-3.5.5
new file mode 100644
index 000000000000..4c4ca8e7b2e9
--- /dev/null
+++ b/kde-base/arts/files/digest-arts-3.5.5
@@ -0,0 +1,3 @@
+MD5 3b0aa1ee08c6ef2aefd8d2d88d1ec146 arts-1.5.5.tar.bz2 967552
+RMD160 9884d410a7b22a4221b57d9c170b5260739c68a1 arts-1.5.5.tar.bz2 967552
+SHA256 2e5d5f07078ac79911815c25c6768b7fbf3c54989a4fc5b52a07e4a73b50aec1 arts-1.5.5.tar.bz2 967552