Version bump, adds new implementations for XML, TLS/SSL, and sorting algorithms

(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

2 files changed, 82 insertions, 1 deletions

diff --git a/gnustep-base/gnustep-base/ChangeLog b/gnustep-base/gnustep-base/ChangeLog
index 409ef97c8ed5..bedb592d3fbd 100644
--- a/gnustep-base/gnustep-base/ChangeLog
+++ b/gnustep-base/gnustep-base/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnustep-base/gnustep-base
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/ChangeLog,v 1.117 2013/03/05 13:37:07 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/ChangeLog,v 1.118 2013/03/08 15:19:53 voyageur Exp $
+
+*gnustep-base-1.24.3 (08 Mar 2013)
+
+  08 Mar 2013; Bernard Cafarelli <voyageur@gentoo.org>
+  +gnustep-base-1.24.3.ebuild:
+  Version bump, adds new implementations for XML, TLS/SSL, and sorting
+  algorithms
 
   05 Mar 2013; Bernard Cafarelli <voyageur@gentoo.org>
   gnustep-base-1.24.0-r1.ebuild:
diff --git a/gnustep-base/gnustep-base/gnustep-base-1.24.3.ebuild b/gnustep-base/gnustep-base/gnustep-base-1.24.3.ebuild
new file mode 100644
index 000000000000..536ee222ff7f
--- /dev/null
+++ b/gnustep-base/gnustep-base/gnustep-base-1.24.3.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnustep-base/gnustep-base/gnustep-base-1.24.3.ebuild,v 1.1 2013/03/08 15:19:53 voyageur Exp $
+
+EAPI=5
+inherit eutils gnustep-base
+
+DESCRIPTION="A library of general-purpose, non-graphical Objective C objects."
+HOMEPAGE="http://www.gnustep.org"
+SRC_URI="ftp://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+IUSE="+icu +libffi ssl zeroconf"
+
+RDEPEND="${GNUSTEP_CORE_DEPEND}
+	>=gnustep-base/gnustep-make-2.6.0
+	icu? ( >=dev-libs/icu-4.0:= )
+	!libffi? ( dev-libs/ffcall
+		gnustep-base/gnustep-make[-native-exceptions] )
+	libffi? ( virtual/libffi )
+	ssl? ( net-libs/gnutls )
+	>=dev-libs/libxml2-2.6
+	>=dev-libs/libxslt-1.1
+	>=dev-libs/gmp-4.1
+	>=dev-libs/openssl-0.9.7
+	>=sys-libs/zlib-1.2
+	zeroconf? ( net-dns/avahi )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	egnustep_env
+
+	local myconf
+	if use libffi;
+	then
+		myconf="--enable-libffi --disable-ffcall --with-ffi-include=$(pkg-config --variable=includedir libffi)"
+	else
+		myconf="--disable-libffi --enable-ffcall"
+	fi
+
+	myconf="$myconf $(use_enable icu)"
+	myconf="$myconf $(use_enable ssl tls)"
+	myconf="$myconf $(use_enable zeroconf)"
+	myconf="$myconf --with-xml-prefix=${EPREFIX}/usr"
+	myconf="$myconf --with-gmp-include=${EPREFIX}/usr/include --with-gmp-library=${EPREFIX}/usr/lib"
+	myconf="$myconf --with-default-config=${EPREFIX}/etc/GNUstep/GNUstep.conf"
+
+	econf $myconf
+}
+
+src_install() {
+	# We need to set LD_LIBRARY_PATH because the doc generation program
+	# uses the gnustep-base libraries.  Since egnustep_env "cleans the
+	# environment" including our LD_LIBRARY_PATH, we're left no choice
+	# but doing it like this.
+
+	egnustep_env
+	egnustep_install
+
+	if use doc ; then
+		export LD_LIBRARY_PATH="${S}/Source/obj:${LD_LIBRARY_PATH}"
+		egnustep_doc
+	fi
+	egnustep_install_config
+}
+
+pkg_postinst() {
+	ewarn "The shared library version has changed in this release."
+	ewarn "You will need to recompile all Applications/Tools/etc in order"
+	ewarn "to use this library. Please run revdep-rebuild to do so"
+}