Add gnome-power-manager-2.24.4 from overlay (p.masked due to bug 247614)

(Portage version: 2.2_rc23/cvs/Linux i686)

4 files changed, 142 insertions, 1 deletions

diff --git a/gnome-extra/gnome-power-manager/ChangeLog b/gnome-extra/gnome-power-manager/ChangeLog
index 82e268fc3931..13b211ffd926 100644
--- a/gnome-extra/gnome-power-manager/ChangeLog
+++ b/gnome-extra/gnome-power-manager/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/gnome-power-manager
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.100 2009/02/07 15:48:10 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.101 2009/03/11 15:10:43 nirbheek Exp $
+
+*gnome-power-manager-2.24.4 (11 Mar 2009)
+
+  11 Mar 2009; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +files/org.freedesktop.hal.power-management.policy, metadata.xml,
+  +gnome-power-manager-2.24.4.ebuild:
+  Bump to 2.24.4 -- p.masked due to CPU freq regression bug 247614
 
   07 Feb 2009; Arun Raghavan <ford_prefect@gentoo.org>
   gnome-power-manager-2.22.1.ebuild:
diff --git a/gnome-extra/gnome-power-manager/files/org.freedesktop.hal.power-management.policy b/gnome-extra/gnome-power-manager/files/org.freedesktop.hal.power-management.policy
new file mode 100644
index 000000000000..0711ec8a8168
--- /dev/null
+++ b/gnome-extra/gnome-power-manager/files/org.freedesktop.hal.power-management.policy
@@ -0,0 +1,27 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE policyconfig PUBLIC
+ "-//freedesktop//DTD PolicyKit Policy Configuration 1.0//EN"
+ "http://www.freedesktop.org/standards/PolicyKit/1.0/policyconfig.dtd">
+
+<policyconfig>
+
+  <action id="org.freedesktop.hal.power-management.suspend">
+    <description>Suspend the system</description>
+    <message>System policy prevents suspending the system</message>
+    <defaults>
+      <allow_inactive>no</allow_inactive>
+      <allow_active>yes</allow_active>
+    </defaults>
+  </action>
+
+  <action id="org.freedesktop.hal.power-management.hibernate">
+    <description>Hibernate the system</description>
+    <message>System policy prevents hibernating the system</message>
+    <defaults>
+      <allow_inactive>no</allow_inactive>
+      <allow_active>yes</allow_active>
+    </defaults>
+  </action>
+
+
+</policyconfig>
diff --git a/gnome-extra/gnome-power-manager/gnome-power-manager-2.24.4.ebuild b/gnome-extra/gnome-power-manager/gnome-power-manager-2.24.4.ebuild
new file mode 100644
index 000000000000..d3c2cb1af1e9
--- /dev/null
+++ b/gnome-extra/gnome-power-manager/gnome-power-manager-2.24.4.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.24.4.ebuild,v 1.1 2009/03/11 15:10:43 nirbheek Exp $
+
+inherit eutils gnome2 virtualx
+
+DESCRIPTION="Gnome Power Manager"
+HOMEPAGE="http://www.gnome.org/projects/gnome-power-manager/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc policykit test"
+
+# See bug #196490
+RESTRICT="test"
+
+RDEPEND=">=dev-libs/glib-2.6.0
+		 >=x11-libs/gtk+-2.11.0
+		 >=gnome-base/gnome-keyring-0.6.0
+		 >=gnome-base/libgnome-2.14.0
+		 >=gnome-base/libgnomeui-2.14.0
+		 >=sys-apps/hal-0.5.9
+		 >=dev-libs/dbus-glib-0.71
+		 >=gnome-base/libglade-2.5.0
+		 >=x11-libs/libnotify-0.4.3
+		 >=x11-libs/libwnck-2.10.0
+		 >=x11-libs/cairo-1.0.0
+		 >=gnome-base/gnome-panel-2
+		 >=gnome-base/gconf-2
+		  =media-libs/gstreamer-0.10*
+
+		 >=x11-apps/xrandr-1.2
+
+		   x11-libs/libX11
+		   x11-libs/libXext"
+DEPEND="${RDEPEND}
+		  sys-devel/gettext
+		 ~app-text/docbook-xml-dtd-4.3
+		>=dev-util/pkgconfig-0.9
+		>=dev-util/intltool-0.35
+		  app-text/scrollkeeper
+		>=app-text/gnome-doc-utils-0.3.2
+		doc?	(
+					 app-text/xmlto
+					 app-text/docbook-sgml-utils
+					~app-text/docbook-xml-dtd-4.4
+					~app-text/docbook-sgml-dtd-4.1
+					~app-text/docbook-xml-dtd-4.1.2
+				)"
+
+# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
+# (files under ${S}/man).
+# docbook-xml-dtd-4.4 and -4.1.2 are used by the xml files under ${S}/docs.
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		$(use_enable test tests)
+		$(use_enable doc docbook-docs)
+		$(use_enable policykit)
+		$(use_enable policykit gconf-defaults)
+		--with-dpms-ext
+		--enable-xevents
+		--enable-applets"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	if ! use doc; then
+		# Remove the docbook2man rules here since it's not handled by a proper
+		# parameter in configure.in.
+		sed -i -e 's:@HAVE_DOCBOOK2MAN_TRUE@.*::' "${S}/man/Makefile.in"
+	fi
+
+	# glibc splits this out, whereas other libc's do not tend to
+	use elibc_glibc || sed -i -e 's/-lresolv//' configure
+}
+
+src_test() {
+	Xemake check || die "Test phase failed"
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use policykit; then
+		insinto /usr/share/PolicyKit/policy
+		doins "${FILESDIR}/org.freedesktop.hal.power-management.policy"
+	fi
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	elog
+	elog "To enable frequency scaling interface, use the following command:"
+	elog "	gconftool-2 /apps/gnome-power-manager/ui/cpufreq_show"
+	elog "Note that this will conflict with other power managment utility"
+	elog "like app-laptop/laptop-mode-tools."
+	elog
+}
diff --git a/gnome-extra/gnome-power-manager/metadata.xml b/gnome-extra/gnome-power-manager/metadata.xml
index be43eccdb570..401f431e919c 100644
--- a/gnome-extra/gnome-power-manager/metadata.xml
+++ b/gnome-extra/gnome-power-manager/metadata.xml
@@ -6,5 +6,9 @@
 		Power Manager daemon for the GNOME desktop environment that makes it
 		easy to manage your laptop or desktop system.
 	</longdescription>
+	<use>
+		<flag name="policykit">Enable <pkg>sys-auth/policykit</pkg>
+			authentication support</flag>
+	</use>
 </pkgmetadata>