gnome-base/gnome-panel: bump to 2.22.2, bugfix release and translation updates

(Portage version: 2.1.5.2)

2 files changed, 86 insertions, 1 deletions

diff --git a/gnome-base/gnome-panel/ChangeLog b/gnome-base/gnome-panel/ChangeLog
index 45bbfa4fac24..3a11d126ad89 100644
--- a/gnome-base/gnome-panel/ChangeLog
+++ b/gnome-base/gnome-panel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.250 2008/04/19 20:47:13 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.251 2008/05/30 15:14:45 remi Exp $
+
+*gnome-panel-2.22.2 (30 May 2008)
+
+  30 May 2008; Rémi Cardona <remi@gentoo.org> +gnome-panel-2.22.2.ebuild:
+  bump to 2.22.2, bugfix release and translation updates
 
 *gnome-panel-2.22.1.3 (19 Apr 2008)
 
diff --git a/gnome-base/gnome-panel/gnome-panel-2.22.2.ebuild b/gnome-base/gnome-panel/gnome-panel-2.22.2.ebuild
new file mode 100644
index 000000000000..bc3af116db30
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-2.22.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.22.2.ebuild,v 1.1 2008/05/30 15:14:45 remi Exp $
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="The GNOME panel"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc eds networkmanager"
+
+RDEPEND=">=gnome-base/gnome-desktop-2.12
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.15.6
+	>=x11-libs/gtk+-2.11.3
+	>=dev-libs/libgweather-2.22.1
+	dev-libs/libxml2
+	>=gnome-base/libglade-2.5
+	>=gnome-base/libgnome-2.13
+	>=gnome-base/libgnomeui-2.5.4
+	>=gnome-base/libbonoboui-2.1.1
+	>=gnome-base/orbit-2.4
+	>=x11-libs/libwnck-2.19.5
+	>=gnome-base/gconf-2.6.1
+	>=gnome-base/gnome-menus-2.11.1
+	>=gnome-base/libbonobo-2
+	gnome-base/librsvg
+	>=dev-libs/dbus-glib-0.71
+	>=sys-apps/dbus-1.1.2
+	x11-libs/libXau
+	>=x11-libs/cairo-1.0.0
+	eds? ( >=gnome-extra/evolution-data-server-1.6 )
+	networkmanager? ( >=net-misc/networkmanager-0.6 )"
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.3.2
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.35
+	~app-text/docbook-xml-dtd-4.1.2
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--disable-polkit
+		--with-in-process-applets=clock,notification-area,wncklet
+		$(use_enable networkmanager network-manager)
+		$(use_enable eds)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# FIXME : uh yeah, this is nice
+	# We should patch in a switch here and send it upstream
+	sed -i 's:--load:-v:' "${S}/gnome-panel/Makefile.in" || die "sed failed"
+}
+
+pkg_postinst() {
+	local entries="/etc/gconf/schemas/panel-default-setup.entries"
+	local gconftool="${ROOT}usr/bin/gconftool-2"
+
+	if [ -e "$entries" ]; then
+		einfo "setting panel gconf defaults..."
+
+		GCONF_CONFIG_SOURCE=$("${gconftool}" --get-default-source)
+
+		"${gconftool}" --direct --config-source \
+			"${GCONF_CONFIG_SOURCE}" --load="${entries}"
+	fi
+
+	# Calling this late so it doesn't process the GConf schemas file we already
+	# took care of.
+	gnome2_pkg_postinst
+}