Version bump with small fixes and xdg-mime code sync with GIO

(Portage version: 2.2_rc11/cvs/Linux 2.6.26-gentoo-r1 x86_64)

2 files changed, 119 insertions, 1 deletions

diff --git a/gnome-base/gnome-vfs/ChangeLog b/gnome-base/gnome-vfs/ChangeLog
index 858b9653fcb8..7e65cefcc55c 100644
--- a/gnome-base/gnome-vfs/ChangeLog
+++ b/gnome-base/gnome-vfs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gnome-vfs
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v 1.291 2008/09/25 14:17:50 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/ChangeLog,v 1.292 2008/09/30 21:34:58 leio Exp $
+
+*gnome-vfs-2.24.0 (30 Sep 2008)
+
+  30 Sep 2008; Mart Raudsepp <leio@gentoo.org> +gnome-vfs-2.24.0.ebuild:
+  Version bump with small fixes and xdg-mime code sync with GIO
 
   25 Sep 2008; Jeroen Roovers <jer@gentoo.org> gnome-vfs-2.22.0.ebuild:
   Stable for HPPA (bug #236971).
diff --git a/gnome-base/gnome-vfs/gnome-vfs-2.24.0.ebuild b/gnome-base/gnome-vfs/gnome-vfs-2.24.0.ebuild
new file mode 100644
index 000000000000..6d2c8ac815e7
--- /dev/null
+++ b/gnome-base/gnome-vfs/gnome-vfs-2.24.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.24.0.ebuild,v 1.1 2008/09/30 21:34:58 leio Exp $
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="Gnome Virtual Filesystem"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="acl avahi doc fam gnutls hal ipv6 kerberos samba ssl"
+
+RDEPEND=">=gnome-base/gconf-2
+	>=dev-libs/glib-2.9.3
+	>=dev-libs/libxml2-2.6
+	app-arch/bzip2
+	fam? ( virtual/fam )
+	gnome-base/gnome-mime-data
+	>=x11-misc/shared-mime-info-0.14
+	>=dev-libs/dbus-glib-0.71
+	samba? ( >=net-fs/samba-3 )
+	gnutls?	(
+				net-libs/gnutls
+				!gnome-extra/gnome-vfs-sftp
+			)
+	ssl?	(
+		!gnutls?	(
+				>=dev-libs/openssl-0.9.5
+				!gnome-extra/gnome-vfs-sftp
+				)
+		)
+	hal? ( >=sys-apps/hal-0.5.7 )
+	avahi? ( >=net-dns/avahi-0.6 )
+	kerberos? ( virtual/krb5 )
+	acl? (
+		sys-apps/acl
+		sys-apps/attr
+	)"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	gnome-base/gnome-common
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/gtk-doc-am-1.10-r1
+	doc? ( >=dev-util/gtk-doc-1 )"
+PDEPEND="hal? ( >=gnome-base/gnome-mount-0.6 )"
+
+DOCS="AUTHORS ChangeLog HACKING NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-schemas-install
+		--disable-cdda
+		--disable-howl
+		$(use_enable acl)
+		$(use_enable avahi)
+		$(use_enable fam)
+		$(use_enable gnutls)
+		$(use_enable hal)
+		$(use_enable ipv6)
+		$(use_enable kerberos krb5)
+		$(use_enable samba)
+		$(use_enable ssl openssl)"
+		# Useless ? --enable-http-neon
+
+	if use hal ; then
+		G2CONF="${G2CONF}
+			--with-hal-mount=/usr/bin/gnome-mount
+			--with-hal-umount=/usr/bin/gnome-umount
+			--with-hal-eject=/usr/bin/gnome-eject"
+	fi
+
+	# this works because of the order of configure parsing
+	# so should always be behind the use_enable options
+	# foser <foser@gentoo.org 19 Apr 2004
+	use gnutls && use ssl && G2CONF="${G2CONF} --disable-openssl"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Allow the Trash on afs filesystems (#106118)
+	epatch "${FILESDIR}"/${PN}-2.12.0-afs.patch
+
+	# Fix compiling with headers missing
+	epatch "${FILESDIR}"/${PN}-2.15.2-headers-define.patch
+
+	# Fix for crashes running programs via sudo
+	epatch "${FILESDIR}"/${PN}-2.16.0-no-dbus-crash.patch
+
+	# Fix automagic dependencies, upstream bug #493475
+	epatch "${FILESDIR}"/${PN}-2.20.0-automagic-deps.patch
+	epatch "${FILESDIR}"/${PN}-2.20.1-automagic-deps.patch
+
+	# Fix to identify ${HOME} (#200897)
+	# thanks to debian folks
+	epatch "${FILESDIR}"/${PN}-2.20.0-home_dir_fakeroot.patch
+
+	# Fix deprecated API disabling in used libraries - this is not future-proof, bug 212163
+	# upstream bug #519632
+	sed -i -e '/DISABLE_DEPRECATED/d' \
+		daemon/Makefile.am daemon/Makefile.in \
+		libgnomevfs/Makefile.am libgnomevfs/Makefile.in \
+		modules/Makefile.am modules/Makefile.in \
+		test/Makefile.am test/Makefile.in
+	sed -i -e 's:-DG_DISABLE_DEPRECATED:$(NULL):g' \
+		programs/Makefile.am programs/Makefile.in
+
+	eautoreconf
+	intltoolize --force || die "intltoolize failed"
+}