Patch from Dennis Schridde, bug #183810

(Portage version: 2.1.3_rc6)

1 files changed, 58 insertions, 0 deletions

diff --git a/games-strategy/warzone2100/warzone2100-2.0.7-r1.ebuild b/games-strategy/warzone2100/warzone2100-2.0.7-r1.ebuild
new file mode 100644
index 000000000000..c12084857abb
--- /dev/null
+++ b/games-strategy/warzone2100/warzone2100-2.0.7-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/warzone2100-2.0.7-r1.ebuild,v 1.1 2007/07/01 18:09:17 nyhm Exp $
+
+inherit eutils versionator games
+
+MY_PV=$(get_version_component_range -2)
+DESCRIPTION="3D real-time strategy game"
+HOMEPAGE="http://wz2100.net/"
+SRC_URI="http://download.gna.org/warzone/releases/${MY_PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~ppc ~x86"
+# upstream requested debug support
+IUSE="debug mp3"
+
+RDEPEND="dev-games/physfs
+	media-libs/jpeg
+	media-libs/libogg
+	media-libs/libpng
+	media-libs/libsdl
+	media-libs/libvorbis
+	>=media-libs/openal-0.0.8-r1
+	media-libs/sdl-net
+	virtual/glu
+	virtual/opengl
+	mp3? ( media-libs/libmad )"
+DEPEND="${RDEPEND}
+	app-arch/zip"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i '/^dist_doc_DATA/s:COPYING.*$:TODO:' Makefile.in || die "sed failed"
+	epatch "${FILESDIR}"/${P}-hotfix1.patch
+}
+
+src_compile() {
+	egamesconf \
+		--disable-dependency-tracking \
+		--docdir=/usr/share/doc/${PF} \
+		--with-icondir=/usr/share/pixmaps \
+		--with-applicationdir=/usr/share/applications \
+		--with-ogg=/usr \
+		--with-vorbis=/usr \
+		--enable-ogg \
+		$(use_enable mp3) \
+		$(use_enable debug) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	prepalldocs
+	prepgamesdirs
+}