version bump

(Portage version: 2.1.11.62/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 105 insertions, 1 deletions

diff --git a/games-engines/scummvm/ChangeLog b/games-engines/scummvm/ChangeLog
index c50412e4f3fb..dbebce0b9567 100644
--- a/games-engines/scummvm/ChangeLog
+++ b/games-engines/scummvm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-engines/scummvm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.127 2013/02/02 22:57:26 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.128 2013/06/02 03:44:35 mr_bones_ Exp $
+
+*scummvm-1.6.0 (02 Jun 2013)
+
+  02 Jun 2013; Michael Sterrett <mr_bones_@gentoo.org> +scummvm-1.6.0.ebuild:
+  version bump
 
   02 Feb 2013; Julian Ospald <hasufell@gentoo.org>
   files/scummvm-1.5.0-EE.patch:
diff --git a/games-engines/scummvm/scummvm-1.6.0.ebuild b/games-engines/scummvm/scummvm-1.6.0.ebuild
new file mode 100644
index 000000000000..d7963db0a7a6
--- /dev/null
+++ b/games-engines/scummvm/scummvm-1.6.0.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/scummvm-1.6.0.ebuild,v 1.1 2013/06/02 03:44:35 mr_bones_ Exp $
+
+EAPI=5
+inherit eutils flag-o-matic gnome2-utils toolchain-funcs games
+
+DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/scummvm/${P/_/}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="aac alsa debug flac fluidsynth mp3 opengl truetype vorbis"
+RESTRICT="test"  # it only looks like there's a test there #77507
+
+RDEPEND=">=media-libs/libsdl-1.2.2[audio,joystick,video]
+	sys-libs/zlib
+	vorbis? ( media-libs/libogg media-libs/libvorbis )
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	mp3? ( media-libs/libmad )
+	flac? ( media-libs/flac )
+	opengl? ( virtual/opengl )
+	truetype? ( media-libs/freetype:2 )
+	fluidsynth? ( media-sound/fluidsynth )"
+DEPEND="${RDEPEND}
+	x86? ( dev-lang/nasm )"
+
+S=${WORKDIR}/${P/_/}
+
+src_prepare() {
+	# -g isn't needed for nasm here
+	sed -i \
+		-e '/NASMFLAGS/ s/-g//' \
+		configure || die
+	sed -i \
+		-e '/INSTALL.*doc/d' \
+		-e '/INSTALL.*\/pixmaps/d' \
+		-e 's/-s //' \
+		ports.mk || die
+}
+
+src_configure() {
+	local myconf
+
+	# bug #137547
+	use fluidsynth || myconf="${myconf} --disable-fluidsynth"
+
+	use x86 && append-ldflags -Wl,-z,noexecstack
+
+	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
+	./configure \
+		--backend=sdl \
+		--host=$CHOST \
+		--enable-verbose-build \
+		--prefix=/usr \
+		--bindir="${GAMES_BINDIR}" \
+		--datadir="${GAMES_DATADIR}"/${PN} \
+		--libdir="${GAMES_LIBDIR}" \
+		--enable-zlib \
+		$(use_enable debug) \
+		$(use_enable aac faad) \
+		$(use_enable alsa) \
+		$(use_enable mp3 mad) \
+		$(use_enable flac) \
+		$(use_enable opengl) \
+		$(use_enable vorbis) \
+		$(use_enable truetype freetype2) \
+		$(use_enable x86 nasm) \
+		${myconf} || die
+}
+
+src_compile() {
+	emake AR="$(tc-getAR) cru" RANLIB=$(tc-getRANLIB)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS NEWS README TODO
+	doicon -s scalable icons/scummvm.svg
+	make_desktop_entry scummvm ScummVM scummvm "Game;AdventureGame"
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}