Version bump

(Portage version: 2.1.9.25/cvs/Linux x86_64)

3 files changed, 96 insertions, 2 deletions

diff --git a/dev-vcs/rabbitvcs/ChangeLog b/dev-vcs/rabbitvcs/ChangeLog
index 7ceb11b6af13..9fec0ac54be3 100644
--- a/dev-vcs/rabbitvcs/ChangeLog
+++ b/dev-vcs/rabbitvcs/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/rabbitvcs
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog,v 1.1 2010/10/26 20:59:03 xmw Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog,v 1.2 2011/02/06 18:34:40 xmw Exp $
+
+*rabbitvcs-0.14.1.1 (06 Feb 2011)
+
+  06 Feb 2011; Michael Weber <xmw@gentoo.org> +rabbitvcs-0.14.1.1.ebuild:
+  Version bump (thanks to Rion <rion4ik@gmail.com> for the ebuild on bug
+  350686) and added use flag git.
 
 *rabbitvcs-0.13.3 (26 Oct 2010)
 
diff --git a/dev-vcs/rabbitvcs/metadata.xml b/dev-vcs/rabbitvcs/metadata.xml
index 83c5a0fa26f5..1dbaef1d8c1a 100644
--- a/dev-vcs/rabbitvcs/metadata.xml
+++ b/dev-vcs/rabbitvcs/metadata.xml
@@ -13,6 +13,7 @@
 <flag name='diff'>Use for diff command <pkg>dev-util/meld</pkg></flag>
 <flag name='cli'>Eanble console based frontend</flag>
 <flag name='gedit'>Enable plugin for <pkg>app-editors/gedit</pkg></flag>
+<flag name='git'>Enable plugin for <pkg>dev-vcs/git</pkg></flag>
 <flag name='nautilus'>Enable extension for <pkg>gnome-base/nautilus</pkg></flag>
 <flag name='thunar'>Enable extension for <pkg>xfce-base/thunar</pkg></flag>
 </use>
diff --git a/dev-vcs/rabbitvcs/rabbitvcs-0.14.1.1.ebuild b/dev-vcs/rabbitvcs/rabbitvcs-0.14.1.1.ebuild
new file mode 100644
index 000000000000..f834734f6173
--- /dev/null
+++ b/dev-vcs/rabbitvcs/rabbitvcs-0.14.1.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/rabbitvcs-0.14.1.1.ebuild,v 1.1 2011/02/06 18:34:40 xmw Exp $
+
+EAPI=2
+
+PYTHON_DEPEND="2:2.5"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.4 3.*"
+
+inherit gnome2-utils distutils
+
+DESCRIPTION="Integrated version control support for your desktop"
+HOMEPAGE="http://rabbitvcs.org"
+SRC_URI="http://rabbitvcs.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli diff gedit git nautilus spell thunar"
+
+RDEPEND="dev-python/configobj
+	dev-python/pygobject
+	dev-python/pygtk
+	dev-python/pysvn
+	dev-python/simplejson
+	diff? ( dev-util/meld )
+	gedit? ( app-editors/gedit )
+	git? ( dev-python/dulwich )
+	nautilus? ( >=dev-python/nautilus-python-0.7.0
+		dev-python/dbus-python )
+	spell? ( dev-python/gtkspell-python )
+	thunar? ( dev-python/thunarx-python
+		dev-python/dbus-python )"
+
+src_prepare() {
+	python_convert_shebangs -r 2 .
+
+	distutils_src_prepare
+
+	# we should not do gtk-update-icon-cache from setup script
+	# we prefer portage for that
+	sed -e 's/"install"/"fakeinstall"/' -i "${S}/setup.py" || die
+}
+
+src_install() {
+	distutils_src_install
+
+	if use cli ; then
+		dobin clients/cli/${PN} || die
+	fi
+	if use gedit ; then
+		insinto /usr/$(get_libdir)/gedit-2/plugins
+		doins clients/gedit/${PN}-plugin.py || die
+		doins clients/gedit/${PN}.gedit-plugin || die
+	fi
+	if use nautilus ; then
+		insinto /usr/$(get_libdir)/nautilus/extensions-2.0/python
+		doins clients/nautilus/RabbitVCS.py || die
+	fi
+	if use thunar ; then
+		has_version '>=xfce-base/thunar-1.1.0' && tv=2 || tv=1
+		insinto "/usr/$(get_libdir)/thunarx-${tv}/python"
+		doins clients/thunar/RabbitVCS.py || die
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	gnome2_icon_cache_update
+
+	elog "You should restart file manager to changes take effect:"
+	use nautilus && elog "\$ nautilus -q && nautilus &"
+	use thunar && elog "\$ thunar -q && thunar &"
+	elog ""
+	elog "Also you should really look at known issues page:"
+	elog "http://wiki.rabbitvcs.org/wiki/support/known-issues"
+}
+
+pkg_postrm() {
+	distutils_pkg_postrm
+	gnome2_icon_cache_update
+}