Version bump

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

2 files changed, 84 insertions, 1 deletions

diff --git a/dev-vcs/tortoisehg/ChangeLog b/dev-vcs/tortoisehg/ChangeLog
index 0b11c3452e32..d40d7f3e6f11 100644
--- a/dev-vcs/tortoisehg/ChangeLog
+++ b/dev-vcs/tortoisehg/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-vcs/tortoisehg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.65 2014/11/06 21:26:17 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.66 2014/12/03 08:35:20 polynomial-c Exp $
+
+*tortoisehg-3.2.1 (03 Dec 2014)
+
+  03 Dec 2014; Lars Wendler <polynomial-c@gentoo.org> +tortoisehg-3.2.1.ebuild:
+  Version bump.
 
 *tortoisehg-3.2 (06 Nov 2014)
 
diff --git a/dev-vcs/tortoisehg/tortoisehg-3.2.1.ebuild b/dev-vcs/tortoisehg/tortoisehg-3.2.1.ebuild
new file mode 100644
index 000000000000..b27046acca85
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-3.2.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-3.2.1.ebuild,v 1.1 2014/12/03 08:35:20 polynomial-c Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1 eutils
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.bitbucket.org/${PN}/targz/downloads/${P}.tar.gz"
+	HG_DEPEND=">=dev-vcs/mercurial-3.0 <dev-vcs/mercurial-3.3"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
+	EHG_REVISION="stable"
+	KEYWORDS=""
+	SRC_URI=""
+	HG_DEPEND="dev-vcs/mercurial"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="http://tortoisehg.bitbucket.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="${HG_DEPEND}
+	dev-python/iniparse[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt4[svg,${PYTHON_USEDEP}]
+	dev-python/qscintilla-python[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-1.0.3 )"
+
+# Workaround race condition in build_qt
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	if [[ ${LINGUAS+set} ]]; then
+		cd i18n/tortoisehg || die
+		local x y keep
+		for x in *.po; do
+			keep=false
+			for y in ${LINGUAS}; do
+				if [[ ${y} == ${x%.po}* ]]; then
+					keep=true
+					break
+				fi
+			done
+			${keep} || rm "${x}" || die
+		done
+		cd "${S}" || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+	if use doc ; then
+		dohtml -r doc/build/html/
+	fi
+	newicon -s scalable icons/scalable/apps/thg-logo.svg thg_logo.svg
+	domenu contrib/thg.desktop
+}
+
+pkg_postinst() {
+	elog "When startup of ${PN} fails with an API version mismatch error"
+	elog "between dev-python/sip and dev-python/PyQt4 please rebuild"
+	elog "dev-python/qscintilla-python."
+}