Version bump by request of maintainer. Bug 391973.

(Portage version: 2.2.0_alpha86/cvs/Linux x86_64)

2 files changed, 90 insertions, 2 deletions

diff --git a/dev-vcs/mercurial-server/ChangeLog b/dev-vcs/mercurial-server/ChangeLog
index b72b525891f0..79ecb197e8b5 100644
--- a/dev-vcs/mercurial-server/ChangeLog
+++ b/dev-vcs/mercurial-server/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-vcs/mercurial-server
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/mercurial-server/ChangeLog,v 1.1 2011/01/13 20:22:42 rafaelmartins Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/mercurial-server/ChangeLog,v 1.2 2012/02/16 01:33:50 floppym Exp $
+
+*mercurial-server-1.2 (16 Feb 2012)
+
+  16 Feb 2012; Mike Gilbert <floppym@gentoo.org> +mercurial-server-1.2.ebuild:
+  Version bump by request of maintainer. Bug 391973.
 
 *mercurial-server-9999 (13 Jan 2011)
 *mercurial-server-1.1 (13 Jan 2011)
diff --git a/dev-vcs/mercurial-server/mercurial-server-1.2.ebuild b/dev-vcs/mercurial-server/mercurial-server-1.2.ebuild
new file mode 100644
index 000000000000..fb57bdf4e17f
--- /dev/null
+++ b/dev-vcs/mercurial-server/mercurial-server-1.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/mercurial-server/mercurial-server-1.2.ebuild,v 1.1 2012/02/16 01:33:50 floppym Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+
+if [[ "${PV}" = "9999" ]]; then
+	EHG_REVISION="default"
+	inherit distutils eutils mercurial
+	EHG_REPO_URI="http://hg.opensource.lshift.net/mercurial-server"
+	KEYWORDS=""
+	S="${WORKDIR}/${PN}"
+else
+	inherit distutils eutils
+	MY_P="${PN}_${PV}"
+	SRC_URI="http://dev.lshift.net/paul/mercurial-server/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Mercurial authentication and authorization tools"
+HOMEPAGE="http://www.lshift.net/mercurial-server.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="dev-vcs/mercurial"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxslt
+	)"
+
+pkg_setup() {
+	enewgroup hg
+	enewuser hg -1 /bin/bash "/var/lib/${PN}" hg
+}
+
+src_prepare() {
+	# remove useless makefile
+	rm Makefile
+
+	# fix installation paths
+	sed -i -e "s|'init'|'share/${PN}/init'|" setup.py \
+		|| die 'sed setup.py failed.'
+
+	# fix documentation
+	if [[ "${PV}" = "1.1" ]]; then
+		epatch "${FILESDIR}/${P}_documentation.patch"
+	fi
+}
+
+src_compile() {
+	distutils_src_compile
+
+	# build documentation
+	if use doc; then
+		xsltproc --nonet -o manual.html \
+		/usr/share/sgml/docbook/xsl-stylesheets/html/docbook.xsl \
+		doc/manual.docbook || die "xsltproc failed"
+	fi
+}
+
+src_install() {
+	distutils_src_install --install-scripts="/usr/share/${PN}"
+
+	# install configuration files
+	insinto "/etc/${PN}"
+	doins -r src/init/conf/*
+	keepdir /etc/mercurial-server/keys/{root,users}
+
+	# install documentation
+	if use doc; then
+		dohtml manual.html
+	fi
+
+	# install hg home directory
+	keepdir "/var/lib/${PN}"
+	fowners hg:hg "/var/lib/${PN}"
+	fperms 750 "/var/lib/${PN}"
+}