Add patch to fix qmake projects.

(Portage version: 2.1.2-r8)

3 files changed, 110 insertions, 1 deletions

diff --git a/dev-util/kdevelop/ChangeLog b/dev-util/kdevelop/ChangeLog
index 7f425da25aa1..dcc5639b71de 100644
--- a/dev-util/kdevelop/ChangeLog
+++ b/dev-util/kdevelop/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/kdevelop
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/ChangeLog,v 1.137 2007/01/31 21:11:32 corsair Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/ChangeLog,v 1.138 2007/02/07 16:31:33 flameeyes Exp $
+
+*kdevelop-3.4.0-r1 (07 Feb 2007)
+
+  07 Feb 2007; Diego Pettenò <flameeyes@gentoo.org>
+  +kdevelop-3.4.0-r1.ebuild:
+  Add patch to fix qmake projects.
 
   31 Jan 2007; Markus Rothe <corsair@gentoo.org> kdevelop-3.3.5.ebuild:
   Stable on ppc64; bug #164062
diff --git a/dev-util/kdevelop/files/digest-kdevelop-3.4.0-r1 b/dev-util/kdevelop/files/digest-kdevelop-3.4.0-r1
new file mode 100644
index 000000000000..7361292eb8ba
--- /dev/null
+++ b/dev-util/kdevelop/files/digest-kdevelop-3.4.0-r1
@@ -0,0 +1,6 @@
+MD5 45772000febb6e2ebb7a5c4a6eef6085 kdevelop-3.4.0-qmake-parser.patch.bz2 36754
+RMD160 8317d2145d7e859996fdfda0ddaa155423f7c006 kdevelop-3.4.0-qmake-parser.patch.bz2 36754
+SHA256 3cb8f748640b26f4fd75cdbceec5a0235c2774049e2eb971a14f11e9cc480045 kdevelop-3.4.0-qmake-parser.patch.bz2 36754
+MD5 9cf367c89329acf23738e23c0b663ee9 kdevelop-3.4.0.tar.bz2 9158370
+RMD160 7a3fb362e456965f5c35f2a8a3293178d596c845 kdevelop-3.4.0.tar.bz2 9158370
+SHA256 c477c8980b5dfd4d512ad793d69dd4d5c7987e376789f68796a8013db08d3194 kdevelop-3.4.0.tar.bz2 9158370
diff --git a/dev-util/kdevelop/kdevelop-3.4.0-r1.ebuild b/dev-util/kdevelop/kdevelop-3.4.0-r1.ebuild
new file mode 100644
index 000000000000..737d6803114a
--- /dev/null
+++ b/dev-util/kdevelop/kdevelop-3.4.0-r1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/kdevelop-3.4.0-r1.ebuild,v 1.1 2007/02/07 16:31:33 flameeyes Exp $
+
+inherit kde eutils db-use
+
+DESCRIPTION="Integrated Development Environment for Unix, supporting KDE/Qt, C/C++ and many other languages."
+HOMEPAGE="http://www.kdevelop.org"
+SRC_URI="mirror://kde/stable/${P}/src/${P}.tar.bz2
+	mirror://gentoo/${P}-qmake-parser.patch.bz2"
+
+LICENSE="GPL-2"
+
+SLOT="3"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ada clearcase cvs fortran haskell java pascal perforce perl php python ruby sql subversion graphviz"
+
+DEPEND="sys-devel/gdb
+	>=sys-libs/db-4.1
+	cvs? ( || ( kde-base/cervisia kde-base/kdesdk ) )
+	graphviz? ( media-gfx/graphviz )"
+
+RDEPEND="${DEPEND}
+	subversion? ( || ( kde-base/kdesdk-kioslaves kde-base/kdesdk ) )"
+DEPEND="${DEPEND}
+	sys-devel/flex"
+need-kde 3.5
+
+PATCHES="${DISTDIR}/${P}-qmake-parser.patch.bz2"
+
+src_unpack() {
+	kde_src_unpack
+
+	# Update the admin dir used in KDE template projects.
+	# See also kde bug 104386.
+	for i in ${S}/admin/*; do
+		cp "${i}" "${S}/parts/appwizard/common/admin/"
+	done
+
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	local myconf="--with-kdelibsdoxy-dir=$(kde-config --prefix)/share/doc/HTML/en/kdelibs-apidocs"
+
+	# languages
+	myconf="${myconf} $(use_enable java) $(use_enable python)
+			$(use_enable ruby) $(use_enable ada) $(use_enable fortran)
+			$(use_enable haskell) $(use_enable pascal) $(use_enable perl)
+			$(use_enable php) $(use_enable sql)"
+
+	# build tools
+	myconf="${myconf} $(use_enable java antproject)"
+
+	# version control systems
+	myconf="${myconf} $(use_enable cvs) $(use_enable clearcase)
+		$(use_enable perforce) $(use_enable subversion)"
+
+	# Explicitly set db include directory (bug 128897)
+	myconf="${myconf} --with-db-includedir=${ROOT}$(db_includedir)
+		   --with-db-lib=$(db_libname)"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# Default to exuberant-ctags so that we don't end up trying to run emacs's
+	# ctags.
+	cat - >> "${D}/usr/share/config/kdeveloprc" <<EOF
+
+[CTAGS]
+ctags binary=/usr/bin/exuberant-ctags
+
+EOF
+}
+
+pkg_postinst() {
+	elog "kdevelop can use a wide range of apps for extra functionality. This is an almost"
+	elog "complete list. All these packages can be emerged after kdevelop."
+	elog
+	elog "kde-base/kdebase:			   (RECOMMENDED) embed konsole kpart in kdevelop ide"
+	elog "dev-util/kdbg:				   (RECOMMENDED) kde frontend to gdb"
+	elog "dev-util/valgrind:			   (RECOMMENDED) integrates valgrind (memory debugger) commands"
+	elog "kde-base/kompare:			   (RECOMMENDED) show differences between files"
+	elog "dev-java/ant:				   support projects using the ant build tool"
+	elog "dev-util/ctags:				   faster and more powerful code browsing logic"
+	elog "app-doc/doxygen:				   generate KDE-style documentation for your project"
+	elog "www-misc/htdig:					index and search your project's documentation"
+	elog "app-arch/rpm:				   support creating RPMs of your project"
+	elog "app-emulation/visualboyadvance: create and run projects for this gameboy"
+	elog
+	elog "Support for GNU-style make, tmake, qmake is included."
+	elog "Support for using clearcase, perforce and subversion"
+	elog "as version control systems is optional."
+}