Revbump to add sys-devel/flex (thanks to bay, bug 387651). EAPI-4, cleanups.

(Portage version: 2.1.10.11/cvs/Linux x86_64)

3 files changed, 59 insertions, 51 deletions

diff --git a/dev-util/cutils/ChangeLog b/dev-util/cutils/ChangeLog
index 0a6844cc49ee..d2f261d09a7e 100644
--- a/dev-util/cutils/ChangeLog
+++ b/dev-util/cutils/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/cutils
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/cutils/ChangeLog,v 1.26 2009/09/23 17:42:34 patrick Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/cutils/ChangeLog,v 1.27 2011/11/12 14:50:02 xmw Exp $
+
+*cutils-1.6-r4 (12 Nov 2011)
+
+  12 Nov 2011; Michael Weber <xmw@gentoo.org> -cutils-1.6-r3.ebuild,
+  +cutils-1.6-r4.ebuild:
+  Revbump to add sys-devel/flex (thanks to bay, bug 387651). EAPI-4, cleanups.
 
   23 Sep 2009; Patrick Lauer <patrick@gentoo.org> cutils-1.6-r2.ebuild:
   Remove virtual/libc
diff --git a/dev-util/cutils/cutils-1.6-r3.ebuild b/dev-util/cutils/cutils-1.6-r3.ebuild
deleted file mode 100644
index 71573dca079d..000000000000
--- a/dev-util/cutils/cutils-1.6-r3.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 1999-2008 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/cutils/cutils-1.6-r3.ebuild,v 1.2 2008/11/24 23:23:51 tcunha Exp $
-
-inherit eutils toolchain-funcs
-
-DESCRIPTION="C language utilities"
-HOMEPAGE="http://www.sigala.it/sandro/software.php#cutils"
-SRC_URI="http://www.sigala.it/sandro/files/${P}.tar.gz"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
-IUSE=""
-
-src_unpack() {
-	unpack ${A}
-
-	epatch "${FILESDIR}"/${PN}-infopage.patch
-
-	mv "${S}"/src/cdecl/cdecl.1 			\
-		"${S}"/src/cdecl/cutils-cdecl.1 || die "mv cdecl failed"
-	# Force rebuild of cutils.info
-	rm -f "${S}"/doc/cutils.info
-
-	sed -i "s/cdecl/cutils-cdecl/g"			\
-		"${S}"/doc/cutils.texi || die "sed cutils.info failed"
-	sed -i "/PROG/s/cdecl/cutils-cdecl/" 	\
-		"${S}"/src/cdecl/Makefile.in || die "sed cdecl failed"
-	sed -i "/Xr/s/cdecl/cutils-cdecl/"		\
-		"${S}"/src/cundecl/cundecl.1 || die "sed cundecl.1 failed"
-	sed -i "/Nm/s/cdecl/cutils-cdecl/"		\
-		"${S}"/src/cdecl/cutils-cdecl.1 || die "sed cutils-cdecl.1 failed"
-}
-
-src_compile() {
-	econf
-	emake CC="$(tc-getCC)" -j1 || die "emake failed"
-}
-
-src_install () {
-	emake DESTDIR="${D}" install || die "emake install failed"
-	dodoc CREDITS HISTORY NEWS README || die "dodoc failed"
-}
-
-pkg_postinst () {
-	elog "cdecl was installed as cutils-cdecl because of a naming conflict"
-	elog "with dev-util/cdecl."
-}
diff --git a/dev-util/cutils/cutils-1.6-r4.ebuild b/dev-util/cutils/cutils-1.6-r4.ebuild
new file mode 100644
index 000000000000..523a8467bea0
--- /dev/null
+++ b/dev-util/cutils/cutils-1.6-r4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/cutils/cutils-1.6-r4.ebuild,v 1.1 2011/11/12 14:50:02 xmw Exp $
+
+EAPI=4
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="C language utilities"
+HOMEPAGE="http://www.sigala.it/sandro/software.php#cutils"
+SRC_URI="http://www.sigala.it/sandro/files/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND="sys-devel/flex"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-infopage.patch
+
+	mv "${S}"/src/cdecl/cdecl.1 			\
+		"${S}"/src/cdecl/cutils-cdecl.1 || die
+	# Force rebuild of cutils.info
+	rm -f "${S}"/doc/cutils.info || die
+
+	sed -e "s/cdecl/cutils-cdecl/g"	\
+		-i "${S}"/doc/cutils.texi || die
+	sed -e "/PROG/s/cdecl/cutils-cdecl/" \
+		-i "${S}"/src/cdecl/Makefile.in || die
+	sed -e "/Xr/s/cdecl/cutils-cdecl/" \
+		-i "${S}"/src/cundecl/cundecl.1 || die
+	sed -i "/Nm/s/cdecl/cutils-cdecl/" \
+		"${S}"/src/cdecl/cutils-cdecl.1 || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" -j1
+}
+
+src_install () {
+	emake DESTDIR="${D}" install
+	dodoc CREDITS HISTORY NEWS README
+}
+
+pkg_postinst () {
+	elog "cdecl was installed as cutils-cdecl because of a naming conflict"
+	elog "with dev-util/cdecl."
+}