Version bump for gnome-3.6. Update license.

(Portage version: 2.2.0_alpha148/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

6 files changed, 174 insertions, 7 deletions

diff --git a/dev-util/anjuta/ChangeLog b/dev-util/anjuta/ChangeLog
index 99a1ddc16bab..40b724d828ba 100644
--- a/dev-util/anjuta/ChangeLog
+++ b/dev-util/anjuta/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/anjuta
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/ChangeLog,v 1.151 2012/11/17 12:31:47 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/ChangeLog,v 1.152 2012/12/17 10:19:26 tetromino Exp $
+
+*anjuta-3.6.2-r1 (17 Dec 2012)
+
+  17 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org> anjuta-3.4.3.ebuild,
+  anjuta-3.4.4.ebuild, +files/anjuta-3.5.91-cxx-check.patch,
+  +anjuta-3.6.2-r1.ebuild, metadata.xml:
+  Version bump for gnome-3.6. Update license.
 
   17 Nov 2012; Pacho Ramos <pacho@gentoo.org> -anjuta-2.32.1.1.ebuild,
   -anjuta-3.2.2.ebuild, anjuta-3.4.4.ebuild, metadata.xml:
diff --git a/dev-util/anjuta/anjuta-3.4.3.ebuild b/dev-util/anjuta/anjuta-3.4.3.ebuild
index ee8571e53d22..7ed2a50ca3df 100644
--- a/dev-util/anjuta/anjuta-3.4.3.ebuild
+++ b/dev-util/anjuta/anjuta-3.4.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/anjuta-3.4.3.ebuild,v 1.5 2012/10/28 15:47:42 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/anjuta-3.4.3.ebuild,v 1.6 2012/12/17 10:19:26 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="yes"
@@ -12,7 +12,7 @@ inherit gnome2 flag-o-matic multilib python
 DESCRIPTION="A versatile IDE for GNOME"
 HOMEPAGE="http://www.anjuta.org"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="amd64 ppc sparc x86 ~x86-fbsd"
 IUSE="debug devhelp doc glade graphviz +introspection packagekit subversion test vala"
diff --git a/dev-util/anjuta/anjuta-3.4.4.ebuild b/dev-util/anjuta/anjuta-3.4.4.ebuild
index a29a6c197159..105ccda70733 100644
--- a/dev-util/anjuta/anjuta-3.4.4.ebuild
+++ b/dev-util/anjuta/anjuta-3.4.4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/anjuta-3.4.4.ebuild,v 1.2 2012/11/17 12:31:47 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/anjuta-3.4.4.ebuild,v 1.3 2012/12/17 10:19:26 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="yes"
@@ -14,7 +14,7 @@ inherit gnome2 flag-o-matic multilib python vala
 DESCRIPTION="A versatile IDE for GNOME"
 HOMEPAGE="http://www.anjuta.org"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
 IUSE="debug devhelp glade graphviz +introspection packagekit subversion test vala"
diff --git a/dev-util/anjuta/anjuta-3.6.2-r1.ebuild b/dev-util/anjuta/anjuta-3.6.2-r1.ebuild
new file mode 100644
index 000000000000..25a76887d56c
--- /dev/null
+++ b/dev-util/anjuta/anjuta-3.6.2-r1.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/anjuta/anjuta-3.6.2-r1.ebuild,v 1.1 2012/12/17 10:19:26 tetromino Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_6,2_7} )
+# libanjuta-language-vala.so links to a specific slot of libvala; we want to
+# avoid automagic behavior.
+VALA_MIN_API_VERSION="0.18"
+VALA_MAX_API_VERSION="${VALA_MIN_API_VERSION}"
+
+inherit autotools eutils gnome2 flag-o-matic multilib python-single-r1 vala
+
+DESCRIPTION="A versatile IDE for GNOME"
+HOMEPAGE="http://www.anjuta.org"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="debug devhelp glade +introspection packagekit subversion test vala"
+
+# FIXME: make python dependency non-automagic
+COMMON_DEPEND=">=dev-libs/glib-2.32:2
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.4:3
+	>=x11-libs/vte-0.27.6:2.90
+	>=dev-libs/libxml2-2.4.23
+	>=dev-libs/gdl-3.5.5:3=
+	>=x11-libs/gtksourceview-3:3.0
+
+	sys-devel/autogen
+
+	>=gnome-extra/libgda-5:5=
+	dev-util/ctags
+
+	x11-libs/libXext
+	x11-libs/libXrender
+
+	${PYTHON_DEPS}
+
+	devhelp? ( >=dev-util/devhelp-3.4.2:= )
+	glade? ( >=dev-util/glade-3.12:3.10= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	subversion? (
+		>=dev-vcs/subversion-1.5.0:=
+		>=net-libs/neon-0.28.2:=
+		>=dev-libs/apr-1:=
+		>=dev-libs/apr-util-1:= )
+	vala? ( $(vala_depend) )
+"
+RDEPEND="${COMMON_DEPEND}
+	packagekit? ( app-admin/packagekit-base )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-lang/perl-5
+	>=dev-util/gtk-doc-am-1.4
+	>=dev-util/intltool-0.40.1
+	sys-devel/bison
+	sys-devel/flex
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	!!dev-libs/gnome-build
+	test? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/docbook-xml-dtd:4.5 )
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+# eautoreconf requires: gtk-doc-am, gnome-common, gobject-introspection-common
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# COPYING is used in Anjuta's help/about entry
+	DOCS="AUTHORS ChangeLog COPYING FUTURE MAINTAINERS NEWS README ROADMAP THANKS TODO"
+
+	G2CONF="${G2CONF}
+		--disable-static
+		--docdir=/usr/share/doc/${PF}
+		$(use_enable debug)
+		$(use_enable devhelp plugin-devhelp)
+		$(use_enable glade plugin-glade)
+		$(use_enable introspection)
+		$(use_enable packagekit)
+		$(use_enable subversion plugin-subversion)
+		$(use_enable vala)"
+
+	# Conflicts with -pg in a plugin, bug #266777
+	filter-flags -fomit-frame-pointer
+
+	# python2.7-configure in Fedora vs. python-configure in Gentoo
+	sed -e 's:$PYTHON-config:$PYTHON$PYTHON_VERSION-config:g' \
+		-i plugins/am-project/tests/anjuta.lst || die "sed failed"
+
+	# https://bugzilla.gnome.org/show_bug.cgi?id=684758
+	epatch "${FILESDIR}/${PN}-3.5.91-cxx-check.patch"
+	eautoreconf
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_install() {
+	# COPYING is used in Anjuta's help/about entry
+	docompress -x "/usr/share/doc/${PF}/COPYING"
+
+	# Anjuta uses a custom rule to install DOCS, get rid of it
+	gnome2_src_install
+	rm -rf "${ED}"/usr/share/doc/${PN} || die "rm failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog ""
+	elog "Some project templates may require additional development"
+	elog "libraries to function correctly. It goes beyond the scope"
+	elog "of this ebuild to provide them."
+
+	if use vala; then
+		elog ""
+		elog "To create a generic vala project you will need to specify"
+		elog "desired valac versioned binary to be used, to do that you"
+		elog "will need to:"
+		elog "1. Go to 'Build' -> 'Configure project'"
+		elog "2. Add 'VALAC=/usr/bin/valac-X.XX' (respecting quotes) to"
+		elog "'Configure options'."
+	fi
+}
diff --git a/dev-util/anjuta/files/anjuta-3.5.91-cxx-check.patch b/dev-util/anjuta/files/anjuta-3.5.91-cxx-check.patch
new file mode 100644
index 000000000000..db844e07fb68
--- /dev/null
+++ b/dev-util/anjuta/files/anjuta-3.5.91-cxx-check.patch
@@ -0,0 +1,28 @@
+From 4d59f47b7f42951638f4390ef1a4a3373486d083 Mon Sep 17 00:00:00 2001
+From: Alexandre Rostovtsev <tetromino@gentoo.org>
+Date: Tue, 25 Sep 2012 02:32:31 -0400
+Subject: [PATCH] configure: fix C++ compiler check
+
+AC_PROG_CXX sets CXX, not ac_ct_CXX
+
+https://bugzilla.gnome.org/show_bug.cgi?id=684758
+---
+ configure.ac | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/configure.ac b/configure.ac
+index 106c1b4..21e9386 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -80,7 +80,7 @@ fi
+ AC_LANG([C])
+ AC_LANG([C++])
+ AC_PROG_CXX
+-if test "x$ac_ct_CXX" = "x"
++if test "x$CXX" = "x"
+ then
+   AC_MSG_ERROR([C++ Compiler required to compile Anjuta])
+ fi
+-- 
+1.7.12
+
diff --git a/dev-util/anjuta/metadata.xml b/dev-util/anjuta/metadata.xml
index 38db6ea0d782..9f12d4b2e897 100644
--- a/dev-util/anjuta/metadata.xml
+++ b/dev-util/anjuta/metadata.xml
@@ -5,8 +5,6 @@
   <use>
     <flag name="devhelp">Enable devhelp integration</flag>
     <flag name="glade">Build glade plugin for anjuta</flag>
-    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
-    	for introspection</flag>
 	<flag name="packagekit">Use packagekit to search for missing tools</flag>
     <flag name='vala'>Enable support for the Vala programming
     	language</flag>