Version bump, alerted to it by upstream author.

(Portage version: 2.2_rc63/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/dev-util/wiggle/ChangeLog b/dev-util/wiggle/ChangeLog
index c78b7694cd32..8ad1550eac76 100644
--- a/dev-util/wiggle/ChangeLog
+++ b/dev-util/wiggle/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/wiggle
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/wiggle/ChangeLog,v 1.19 2010/01/10 22:30:18 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/wiggle/ChangeLog,v 1.20 2010/03/24 18:15:28 robbat2 Exp $
+
+*wiggle-0.8 (24 Mar 2010)
+
+  24 Mar 2010; Robin H. Johnson <robbat2@gentoo.org> +wiggle-0.8.ebuild:
+  Version bump, alerted to it by upstream author.
 
   10 Jan 2010; Jonathan Callen <abcd@gentoo.org> wiggle-0.6-r3.ebuild:
   QA: die on failure, spelling fix; add prefix keywords
diff --git a/dev-util/wiggle/wiggle-0.8.ebuild b/dev-util/wiggle/wiggle-0.8.ebuild
new file mode 100644
index 000000000000..5f87bb974847
--- /dev/null
+++ b/dev-util/wiggle/wiggle-0.8.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/wiggle/wiggle-0.8.ebuild,v 1.1 2010/03/24 18:15:28 robbat2 Exp $
+
+inherit eutils fixheadtails toolchain-funcs
+
+DESCRIPTION="program for applying patches that patch cannot apply because of conflicting changes"
+HOMEPAGE="http://neil.brown.name/wiggle http://neil.brown.name/git?p=wiggle"
+SRC_URI="http://neil.brown.name/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+# The 'p' tool does support bitkeeper, but I'm against just dumping it in here
+# due to it's size.  I've explictly listed every other dependancy here due to
+# the nature of the shell program 'p'
+RDEPEND="dev-util/diffstat
+	dev-util/patchutils
+	sys-apps/diffutils
+	sys-apps/findutils
+	sys-apps/gawk
+	sys-apps/grep
+	sys-apps/less
+	sys-apps/sed
+	sys-apps/coreutils
+	sys-devel/patch"
+DEPEND="${RDEPEND}
+	sys-apps/groff
+	test? ( sys-process/time )"
+
+src_unpack() {
+	use prefix || EPREFIX=
+	unpack ${A}
+	cd "${S}"
+
+	# Fix the reference to the help file so `p help' works
+	sed -i "s:\$0.help:${EPREFIX}/usr/share/wiggle/p.help:" p || die "sed failed on p"
+
+	# Don't add Neil Brown's default sign off line to every patch
+	sed -i '/$CERT/,+4s,^,#,' p || die "sed failed on p"
+
+	# Use prefixed time binary
+	sed -i "s:/usr/bin/time:${EPREFIX}/usr/bin/time:" dotest || die "sed failed on dotest"
+
+	ht_fix_file p
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" CFLAGS="${CFLAGS} -Wall" \
+		wiggle || die "emake wiggle failed."
+}
+
+src_install() {
+	dobin wiggle p || die "failed to install binaries"
+	doman wiggle.1 || die "failed to install man page"
+	dodoc ANNOUNCE INSTALL TODO DOC/diff.ps notes || die "failed to install docs"
+	insinto /usr/share/wiggle
+	doins p.help || die "failed to install help file"
+}