Version bump. Ebuild by Arfrever.

(Portage version: 2.2.0_alpha109/cvs/Linux x86_64)

2 files changed, 78 insertions, 1 deletions

diff --git a/dev-util/global/ChangeLog b/dev-util/global/ChangeLog
index 032574af5fcf..4ab2e23d26c7 100644
--- a/dev-util/global/ChangeLog
+++ b/dev-util/global/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/global
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.97 2012/04/24 10:03:49 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.98 2012/06/02 20:30:58 floppym Exp $
+
+*global-6.2.4 (02 Jun 2012)
+
+  02 Jun 2012; Mike Gilbert <floppym@gentoo.org> +global-6.2.4.ebuild:
+  Version bump. Ebuild by Arfrever.
 
   24 Apr 2012; Michał Górny <mgorny@gentoo.org> global-5.9.5.ebuild,
   global-5.9.7.ebuild, global-6.1.ebuild, global-6.2.ebuild,
diff --git a/dev-util/global/global-6.2.4.ebuild b/dev-util/global/global-6.2.4.ebuild
new file mode 100644
index 000000000000..a3dff4333964
--- /dev/null
+++ b/dev-util/global/global-6.2.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-6.2.4.ebuild,v 1.1 2012/06/02 20:30:58 floppym Exp $
+
+EAPI="4"
+
+inherit elisp-common
+
+DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
+HOMEPAGE="http://www.gnu.org/software/global/global.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="doc emacs vim"
+
+RDEPEND="emacs? ( virtual/emacs )
+	vim? ( || ( app-editors/vim app-editors/gvim ) )"
+DEPEND="${DEPEND}
+	doc? ( app-text/texi2html sys-apps/texinfo )"
+
+SITEFILE="50gtags-gentoo.el"
+
+src_configure() {
+	econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
+}
+
+src_compile() {
+	if use doc; then
+		texi2pdf -q -o doc/global.pdf doc/global.texi
+		texi2html -o doc/global.html doc/global.texi
+	fi
+
+	if use emacs; then
+		elisp-compile *.el || die "elisp-compile failed"
+	fi
+
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		dohtml doc/global.html
+		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
+	fi
+
+	dodoc AUTHORS FAQ NEWS README THANKS
+
+	insinto /etc
+	doins gtags.conf
+
+	if use vim; then
+		insinto /usr/share/vim/vimfiles/plugin
+		doins gtags.vim
+	fi
+
+	if use emacs; then
+		elisp-install ${PN} *.{el,elc} || die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die "elisp-site-file-install failed"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}