version bump, bug #347461

(Portage version: 2.2.0_alpha11/cvs/Linux x86_64)

2 files changed, 86 insertions, 2 deletions

diff --git a/dev-tex/pdftex/ChangeLog b/dev-tex/pdftex/ChangeLog
index 28798f0c1e9d..9333d118fc9d 100644
--- a/dev-tex/pdftex/ChangeLog
+++ b/dev-tex/pdftex/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-tex/pdftex
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-tex/pdftex/ChangeLog,v 1.28 2010/06/09 10:07:00 aballier Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-tex/pdftex/ChangeLog,v 1.29 2011/01/02 16:16:50 aballier Exp $
+
+*pdftex-1.40.11 (02 Jan 2011)
+
+  02 Jan 2011; Alexis Ballier <aballier@gentoo.org> +pdftex-1.40.11.ebuild:
+  version bump, bug #347461
 
   09 Jun 2010; Alexis Ballier <aballier@gentoo.org> -pdftex-1.40.9.ebuild,
   -files/pdftex-1.40.9-getline.patch, -files/pdftex-1.40.9-poppler.patch,
diff --git a/dev-tex/pdftex/pdftex-1.40.11.ebuild b/dev-tex/pdftex/pdftex-1.40.11.ebuild
new file mode 100644
index 000000000000..c2cf82c71f4c
--- /dev/null
+++ b/dev-tex/pdftex/pdftex-1.40.11.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-tex/pdftex/pdftex-1.40.11.ebuild,v 1.1 2011/01/02 16:16:50 aballier Exp $
+
+EAPI=2
+inherit libtool toolchain-funcs
+
+DESCRIPTION="Standalone version of pdftex that can be used to replace TeX Live's"
+HOMEPAGE="http://www.pdftex.org/"
+SLOT="0"
+LICENSE="GPL-2"
+
+SRC_URI="http://sarovar.org/frs/download.php/1300/${P}.tar.bz2"
+
+KEYWORDS="~amd64 ~arm ~hppa ~x86"
+IUSE=""
+
+RDEPEND=">=app-text/poppler-0.12.3-r3[xpdf-headers]
+	media-libs/libpng
+	sys-libs/zlib
+	dev-libs/kpathsea
+	app-admin/eselect-pdftex"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${P}/build
+
+src_prepare() {
+	mkdir "${S}"
+	cd "${WORKDIR}/${P}/src"
+	elibtoolize
+}
+
+src_configure() {
+	# Too many regexps use A-Z a-z constructs, what causes problems with locales
+	# that don't have the same alphabetical order than ascii. Bug #293199
+	# So we set LC_ALL to C in order to avoid problems.
+	export LC_ALL=C
+
+	ECONF_SOURCE="${WORKDIR}/${P}/src" econf -C \
+		--disable-cxx-runtime-hack	\
+		--disable-all-pkgs			\
+		--disable-ptex				\
+		--enable-pdftex				\
+		--disable-native-texlive-build \
+		--without-mf-x-toolkit		\
+		--without-x					\
+		--disable-shared			\
+		--disable-largefile			\
+		--with-system-xpdf			\
+		--with-system-zlib			\
+		--with-system-pnglib		\
+		--disable-multiplatform		\
+		--with-system-kpathsea		\
+		--with-system-ptexenc
+}
+
+src_compile() {
+	emake SHELL=/bin/sh || die
+	cd "${S}/texk/web2c"
+	emake pdftex || die
+}
+
+src_install() {
+	cd "${S}/texk/web2c"
+	emake DESTDIR="${D}" \
+		SUBDIRS="" \
+		bin_PROGRAMS="pdftex" \
+		nodist_man_MANS="" \
+		dist_man_MANS="" \
+		install-binPROGRAMS || die
+	# Rename it
+	mv "${D}/usr/bin/pdftex" "${D}/usr/bin/pdftex-${P}" || die "renaming failed"
+}
+
+pkg_postinst(){
+	einfo "Calling eselect pdftex update"
+	eselect pdftex update
+}