initial import, split out of texlive-latexextra for getting proper building and deps, part of bug #342317

(Portage version: 2.2.0_alpha24/cvs/Linux x86_64)

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-tex/pdfannotextractor/pdfannotextractor-0.1i.ebuild b/dev-tex/pdfannotextractor/pdfannotextractor-0.1i.ebuild
new file mode 100644
index 000000000000..e9b4390281c1
--- /dev/null
+++ b/dev-tex/pdfannotextractor/pdfannotextractor-0.1i.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-tex/pdfannotextractor/pdfannotextractor-0.1i.ebuild,v 1.1 2011/02/17 19:43:44 aballier Exp $
+
+EAPI=3
+
+inherit latex-package java-utils-2 java-pkg-2 java-ant-2 eutils
+
+DESCRIPTION="Extract annotations from pdf files"
+HOMEPAGE="http://www.ctan.org/tex-archive/macros/latex/contrib/pax/"
+SRC_URI="mirror://gentoo/${P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+CDEPEND="virtual/latex-base
+	dev-java/pdfbox
+	dev-java/fontbox"
+DEPEND="${CDEPEND}
+	app-arch/unzip
+	>=virtual/jdk-1.5"
+RDEPEND="${CDEPEND}
+	virtual/perl-Getopt-Long
+	dev-perl/File-Which
+	>=virtual/jre-1.5
+	!<=dev-texlive/texlive-latexextra-2010"
+
+TEXMF=/usr/share/texmf-site
+S=${WORKDIR}
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_GENTOO_CLASSPATH="pdfbox fontbox"
+
+src_prepare() {
+	epatch "${FILESDIR}/javajars.patch"
+	java-pkg-2_src_prepare
+}
+
+src_compile() {
+	cd "${S}/source/latex/pax"
+	eant || die
+}
+
+src_install() {
+	newbin scripts/pax/pdfannotextractor.pl pdfannotextractor || die
+	java-pkg_dojar "${S}/source/latex/pax/pax.jar" || die
+	insinto ${TEXMF}
+	doins -r tex || die
+	dodoc doc/latex/pax/README || die
+}