Add ruby21 target.

(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key )

2 files changed, 53 insertions, 1 deletions

diff --git a/dev-ruby/ruby-xslt/ChangeLog b/dev-ruby/ruby-xslt/ChangeLog
index 8d6f9bd0bad9..4b65e175186c 100644
--- a/dev-ruby/ruby-xslt/ChangeLog
+++ b/dev-ruby/ruby-xslt/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/ruby-xslt
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-xslt/ChangeLog,v 1.40 2014/04/24 16:50:56 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-xslt/ChangeLog,v 1.41 2014/10/11 00:12:14 mrueg Exp $
+
+*ruby-xslt-0.9.9-r3 (11 Oct 2014)
+
+  11 Oct 2014; Manuel Rüger <mrueg@gentoo.org> +ruby-xslt-0.9.9-r3.ebuild:
+  Add ruby21 target.
 
   24 Apr 2014; Manuel Rüger <mrueg@gentoo.org> ruby-xslt-0.9.9-r2.ebuild:
   Remove ruby18 support.
diff --git a/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r3.ebuild b/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r3.ebuild
new file mode 100644
index 000000000000..a97e0597460f
--- /dev/null
+++ b/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-xslt/ruby-xslt-0.9.9-r3.ebuild,v 1.1 2014/10/11 00:12:14 mrueg Exp $
+
+EAPI=5
+USE_RUBY="ruby19 ruby20 ruby21"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_EXTRADOC="ChangeLog.rdoc AUTHORS.rdoc README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="A Ruby class for processing XSLT"
+HOMEPAGE="http://www.rubyfr.net/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND+=" >=dev-libs/libxslt-1.1.12"
+RDEPEND+=" >=dev-libs/libxslt-1.1.12"
+
+all_ruby_prepare() {
+	# Remove forced -g compiler flag.
+	sed -i -e 's/-g //' ext/xslt_lib/extconf.rb || die
+
+	# One test fails but we have installed this code already for a long
+	# time so this probably isn't a regression. No upstream bug tracker
+	# to report the problem :-(
+	sed -i -e '/test_transformation_error/,/^  end/ s:^:#:' test/test.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} -C ext/xslt_lib extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake -C ext/xslt_lib V=1
+	cp ext/xslt_lib/xslt_lib$(get_modname) lib/xml/ || die
+}
+
+each_ruby_test() {
+	${RUBY} -I../lib:lib -Ctest test.rb || die
+}