Install stub gemspec since we don't need these dependencies. Install rbcairo.h file.

(Portage version: 2.1.9.25/cvs/Linux x86_64)

2 files changed, 90 insertions, 1 deletions

diff --git a/dev-ruby/rcairo/ChangeLog b/dev-ruby/rcairo/ChangeLog
index 2894f4127627..6a73ce200218 100644
--- a/dev-ruby/rcairo/ChangeLog
+++ b/dev-ruby/rcairo/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.48 2011/01/22 08:07:31 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.49 2011/02/02 19:24:20 graaff Exp $
+
+*rcairo-1.10.0-r1 (02 Feb 2011)
+
+  02 Feb 2011; Hans de Graaff <graaff@gentoo.org> +rcairo-1.10.0-r1.ebuild:
+  Install stub gemspec since we don't need these dependencies. Install
+  rbcairo.h file.
 
 *rcairo-1.10.0 (22 Jan 2011)
 
diff --git a/dev-ruby/rcairo/rcairo-1.10.0-r1.ebuild b/dev-ruby/rcairo/rcairo-1.10.0-r1.ebuild
new file mode 100644
index 000000000000..ced13e840eb3
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.10.0-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.10.0-r1.ebuild,v 1.1 2011/02/02 19:24:20 graaff Exp $
+
+EAPI=2
+
+# ruby19 → fails, and even crashes Ruby
+# jruby → cannot work, it's a compiled extension
+USE_RUBY="ruby18"
+
+RUBY_FAKEGEM_NAME="cairo"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Depends on test-unit-2 which is currently masked.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS NEWS"
+
+inherit multilib ruby-ng ruby-fakegem
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="http://cairographics.org/rcairo/"
+
+IUSE=""
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
+
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg]"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg]
+	dev-util/pkgconfig"
+
+ruby_add_bdepend "test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+each_ruby_prepare() {
+	# Remove a failing test for the new recording surface. It's not
+	# clear if this is a test failure or not, but we need to move on
+	# with cairo 1.10.
+	rm test/test_recording_surface.rb || die
+
+	# We don't need pkg-config since we compile directly so remove
+	# metadata because otherwise rubygems or bundler may get confused.
+	rm ../metadata || die
+}
+
+each_ruby_configure() {
+	${RUBY} extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+	emake || die "make failed"
+
+	# again, try to make it more standard, to install it more easily.
+	cp ext/cairo/cairo$(get_modname) lib/ || die
+}
+
+each_ruby_test() {
+	# don't rely on the Rakefile because it's a mess to load with
+	# their hierarchy, do it manually.
+	${RUBY} -Ilib -r ./test/cairo-test-utils.rb \
+		-e 'gem "test-unit"; require "test/unit"; Dir.glob("test/**/test_*.rb") {|f| load f}' || die "tests failed"
+}
+
+each_ruby_install() {
+	each_fakegem_install
+
+	insinto $(ruby_get_hdrdir)
+	doins ext/cairo/rb_cairo.h || die "Cannot install header file."
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/samples
+	doins -r samples/* || die "Cannot install sample files."
+}