bump; add dep for doc build, fix doc build & install, fixes Bug #519392

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

3 files changed, 76 insertions, 5 deletions

diff --git a/dev-python/fabric/ChangeLog b/dev-python/fabric/ChangeLog
index b569c00fec0d..3cbb341676d2 100644
--- a/dev-python/fabric/ChangeLog
+++ b/dev-python/fabric/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/fabric
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/ChangeLog,v 1.45 2014/06/24 10:03:58 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/ChangeLog,v 1.46 2014/08/10 14:56:05 idella4 Exp $
+
+*fabric-1.9.1 (10 Aug 2014)
+
+  10 Aug 2014; Ian Delaney <idella4@gentoo.org> +fabric-1.9.1.ebuild,
+  fabric-1.9.0.ebuild:
+  bump; add dep for doc build, fix doc build & install, fixes Bug #519392
 
   24 Jun 2014; Ian Delaney <idella4@gentoo.org> fabric-1.9.0.ebuild:
   re-set paramiko in RDEPEND, noted by Arfrever
diff --git a/dev-python/fabric/fabric-1.9.0.ebuild b/dev-python/fabric/fabric-1.9.0.ebuild
index 10e393773385..f470ef6eecdb 100644
--- a/dev-python/fabric/fabric-1.9.0.ebuild
+++ b/dev-python/fabric/fabric-1.9.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/fabric-1.9.0.ebuild,v 1.2 2014/06/24 10:03:58 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/fabric-1.9.0.ebuild,v 1.3 2014/08/10 14:56:05 idella4 Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_7 )
@@ -23,13 +23,22 @@ IUSE="doc test"
 RDEPEND="dev-python/paramiko[${PYTHON_USEDEP}]"
 DEPEND="${RDEPEND}
 	dev-python/setuptools[${PYTHON_USEDEP}]
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/alabaster[${PYTHON_USEDEP}] )
 	test? ( <dev-python/fudge-1.0[${PYTHON_USEDEP}] )"
 
 S="${WORKDIR}/${MY_P}"
 
+python_prepare_all() {
+	sed -e "s/, 'sphinx.ext.intersphinx'//" -i sites/docs/conf.py || die
+	distutils-r1_python_prepare_all
+
+}
+
 python_compile_all() {
-	use doc && emake -C docs html
+	if use doc; then
+		sphinx-build -b html -c sites/docs/ sites/docs/ sites/docs/html || die
+	fi
 }
 
 src_test() {
@@ -42,6 +51,6 @@ python_test() {
 }
 
 python_install_all() {
-	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use doc && local HTML_DOCS=( sites/docs/html/. )
 	distutils-r1_python_install_all
 }
diff --git a/dev-python/fabric/fabric-1.9.1.ebuild b/dev-python/fabric/fabric-1.9.1.ebuild
new file mode 100644
index 000000000000..7db62c151327
--- /dev/null
+++ b/dev-python/fabric/fabric-1.9.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/fabric-1.9.1.ebuild,v 1.1 2014/08/10 14:56:05 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="Fabric"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A simple pythonic tool for remote execution and deployment."
+HOMEPAGE="http://fabfile.org http://pypi.python.org/pypi/Fabric"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+# since 'paramiko>=1.10' is what we have in portage, paramiko can be set unversioned
+RDEPEND="dev-python/paramiko[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/alabaster[${PYTHON_USEDEP}] )
+	test? ( <dev-python/fudge-1.0[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -e "s/, 'sphinx.ext.intersphinx'//" -i sites/docs/conf.py || die
+	distutils-r1_python_prepare_all
+
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build -b html -c sites/docs/ sites/docs/ sites/docs/html || die
+	fi
+}
+
+src_test() {
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	nosetests tests || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( sites/docs/html/. )
+	distutils-r1_python_install_all
+}