New ebuild, thanks to gentoofan23 on freenode for testing.

(Portage version: 2.1.2.8)

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-python/pypam/pypam-0.5.0.ebuild b/dev-python/pypam/pypam-0.5.0.ebuild
new file mode 100644
index 000000000000..93bbda4bfeab
--- /dev/null
+++ b/dev-python/pypam/pypam-0.5.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pypam/pypam-0.5.0.ebuild,v 1.1 2007/05/28 19:04:57 marienz Exp $
+
+inherit distutils eutils
+
+MY_P=${P/pypam/PyPAM}
+
+DESCRIPTION="Python Bindings for PAM (Pluggable Authentication Modules)"
+HOMEPAGE="http://www.pangalactic.org/PyPAM"
+SRC_URI="http://www.pangalactic.org/PyPAM/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~x86"
+IUSE=""
+
+DEPEND=">=sys-libs/pam-0.64"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS="AUTHORS examples/pamtest.py"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Fix a PyObject/PyMEM mixup.
+	epatch "${FILESDIR}/${P}-python-2.5.patch"
+	# Fix a missing include.
+	epatch "${FILESDIR}/${P}-stricter.patch"
+}
+
+src_test() {
+	"${python}" setup.py install --home="${T}/test" \
+		|| die "testinstall failed"
+	PYTHONPATH="${T}/test/$(get_libdir)/python" "${python}" tests/PamTest.py \
+		|| die "tests failed"
+}
+
+pkg_postinst() {
+	# HACK: we do not install any .py files, so there is no reason to
+	# run python_mod_optimize here, like distutils_pkg_postrm does.
+	:
+}
+
+pkg_postrm() {
+	# HACK: we do not install any .py files, so there is no reason to
+	# run python_mod_cleanup here, like distutils_pkg_postrm does.
+	:
+}