dev-python/pycuda: Version Bump; fix usage of python r1 eclasses

(Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

5 files changed, 183 insertions, 59 deletions

diff --git a/dev-python/pycuda/ChangeLog b/dev-python/pycuda/ChangeLog
index beae917bdbce..2d946d04e7c3 100644
--- a/dev-python/pycuda/ChangeLog
+++ b/dev-python/pycuda/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pycuda
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/ChangeLog,v 1.20 2013/02/02 19:33:22 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/ChangeLog,v 1.21 2013/07/07 19:15:38 jlec Exp $
+
+*pycuda-2013.1.1 (07 Jul 2013)
+
+  07 Jul 2013; Justin Lecher <jlec@gentoo.org> pycuda-2012.1.ebuild,
+  +pycuda-2013.1.1.ebuild, pycuda-9999.ebuild, metadata.xml:
+  Version Bump; fix usage of python r1 eclasses
 
   02 Feb 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Assign to new maintainers per http://gentoo.2317880.n4.nabble.com/Packages-up-
diff --git a/dev-python/pycuda/metadata.xml b/dev-python/pycuda/metadata.xml
index ebc7b1038d7d..858a4b6936dd 100644
--- a/dev-python/pycuda/metadata.xml
+++ b/dev-python/pycuda/metadata.xml
@@ -1,7 +1,7 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci</herd>
+  <herd>sci</herd>
   <upstream>
     <remote-id type="pypi">pycuda</remote-id>
   </upstream>
diff --git a/dev-python/pycuda/pycuda-2012.1.ebuild b/dev-python/pycuda/pycuda-2012.1.ebuild
index 4c1feda1eb4c..725c61bef8bc 100644
--- a/dev-python/pycuda/pycuda-2012.1.ebuild
+++ b/dev-python/pycuda/pycuda-2012.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/pycuda-2012.1.ebuild,v 1.1 2013/01/15 15:25:13 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/pycuda-2012.1.ebuild,v 1.2 2013/07/07 19:15:38 jlec Exp $
 
 EAPI=5
 
@@ -18,24 +18,24 @@ KEYWORDS="~amd64 ~x86"
 IUSE="examples opengl test"
 
 RDEPEND="
-	dev-libs/boost[python]
-	dev-python/decorator
-	dev-python/mako
-	dev-python/numpy
-	>=dev-python/pytools-2011.2
+	dev-libs/boost[python,${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pytools-2011.2[${PYTHON_USEDEP}]
 	dev-util/nvidia-cuda-toolkit
 	x11-drivers/nvidia-drivers
 	opengl? ( virtual/opengl )"
 DEPEND="${RDEPEND}
 	test? (
-		dev-python/mako
+		dev-python/mako[${PYTHON_USEDEP}]
 		dev-python/pytest[${PYTHON_USEDEP}] )"
 
 # We need write acccess /dev/nvidia0 and /dev/nvidiactl and the portage
 # user is (usually) not in the video group
 RESTRICT="userpriv"
 
-src_prepare() {
+python_prepare_all() {
 	cuda_sanitize
 	sed \
 		-e "s:'--preprocess':\'--preprocess\', \'--compiler-bindir=$(cuda_gccdir)\':g" \
@@ -43,29 +43,29 @@ src_prepare() {
 		-e "s:/usr/include/pycuda:${S}/src/cuda:g" \
 		-i pycuda/compiler.py || die
 
-	distutils-r1_src_prepare
+	touch siteconf.py || die
+
+	distutils-r1_python_prepare_all
 }
 
-src_compile() {
+python_configure() {
 	local myopts=()
 	use opengl && myopts+=( --cuda-enable-gl )
 
-	compilation() {
-		[[ -e ./siteconf.py ]] && rm -f ./siteconf.py
-		"${EPYTHON}" configure.py \
-			--boost-inc-dir="${EPREFIX}/usr/include" \
-			--boost-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
-			--boost-python-libname=boost_python-$(echo ${EPYTHON} | sed 's/python//')-mt \
-			--boost-thread-libname=boost_thread-mt \
-			--cuda-root="${EPREFIX}/opt/cuda" \
-			--cudadrv-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
-			--cudart-lib-dir="${EPREFIX}/opt/cuda/$(get_libdir)" \
-			--cuda-inc-dir="${EPREFIX}/opt/cuda/include" \
-			--no-use-shipped-boost \
-			"${myopts[@]}"
-			distutils-r1_python_compile
-	}
-	python_foreach_impl compilation
+	mkdir "${BUILD_DIR}" || die
+	cd "${BUILD_DIR}" || die
+	[[ -e ./siteconf.py ]] && rm -f ./siteconf.py
+	"${EPYTHON}" "${S}"/configure.py \
+		--boost-inc-dir="${EPREFIX}/usr/include" \
+		--boost-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--boost-python-libname=boost_python-$(echo ${EPYTHON} | sed 's/python//')-mt \
+		--boost-thread-libname=boost_thread-mt \
+		--cuda-root="${EPREFIX}/opt/cuda" \
+		--cudadrv-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--cudart-lib-dir="${EPREFIX}/opt/cuda/$(get_libdir)" \
+		--cuda-inc-dir="${EPREFIX}/opt/cuda/include" \
+		--no-use-shipped-boost \
+		"${myopts[@]}"
 }
 
 src_test() {
@@ -78,8 +78,8 @@ src_test() {
 	distutils-r1_src_test
 }
 
-src_install() {
-	distutils-r1_src_install
+python_install_all() {
+	distutils-r1_python_install_all
 
 	if use examples; then
 		insinto /usr/share/doc/${PF}
diff --git a/dev-python/pycuda/pycuda-2013.1.1.ebuild b/dev-python/pycuda/pycuda-2013.1.1.ebuild
new file mode 100644
index 000000000000..49f0573391cd
--- /dev/null
+++ b/dev-python/pycuda/pycuda-2013.1.1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/pycuda-2013.1.1.ebuild,v 1.1 2013/07/07 19:15:38 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit cuda distutils-r1 multilib
+
+DESCRIPTION="Python wrapper for NVIDIA CUDA"
+HOMEPAGE="http://mathema.tician.de/software/pycuda/ http://pypi.python.org/pypi/pycuda"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples opengl test"
+
+RDEPEND="
+	dev-libs/boost[python,${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pytools-2011.2[${PYTHON_USEDEP}]
+	dev-util/nvidia-cuda-toolkit
+	x11-drivers/nvidia-drivers
+	opengl? ( virtual/opengl )"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mako[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
+
+# We need write acccess /dev/nvidia0 and /dev/nvidiactl and the portage
+# user is (usually) not in the video group
+RESTRICT="userpriv"
+
+python_prepare_all() {
+	cuda_sanitize
+	sed \
+		-e "s:'--preprocess':\'--preprocess\', \'--compiler-bindir=$(cuda_gccdir)\':g" \
+		-e "s:\"--cubin\":\'--cubin\', \'--compiler-bindir=$(cuda_gccdir)\':g" \
+		-e "s:/usr/include/pycuda:${S}/src/cuda:g" \
+		-i pycuda/compiler.py || die
+
+	touch siteconf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	local myopts=()
+	use opengl && myopts+=( --cuda-enable-gl )
+
+	mkdir "${BUILD_DIR}" || die
+	cd "${BUILD_DIR}" || die
+	[[ -e ./siteconf.py ]] && rm -f ./siteconf.py
+	"${EPYTHON}" "${S}"/configure.py \
+		--boost-inc-dir="${EPREFIX}/usr/include" \
+		--boost-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--boost-python-libname=boost_python-$(echo ${EPYTHON} | sed 's/python//')-mt \
+		--boost-thread-libname=boost_thread-mt \
+		--cuda-root="${EPREFIX}/opt/cuda" \
+		--cudadrv-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--cudart-lib-dir="${EPREFIX}/opt/cuda/$(get_libdir)" \
+		--cuda-inc-dir="${EPREFIX}/opt/cuda/include" \
+		--no-use-shipped-boost \
+		"${myopts[@]}"
+}
+
+src_test() {
+	# we need write access to this to run the tests
+	addwrite /dev/nvidia0
+	addwrite /dev/nvidiactl
+	python_test() {
+			py.test --debug -v -v -v || die "Tests fail with ${EPYTHON}"
+	}
+	distutils-r1_src_test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}
diff --git a/dev-python/pycuda/pycuda-9999.ebuild b/dev-python/pycuda/pycuda-9999.ebuild
index d085bfe434fb..73059b872ece 100644
--- a/dev-python/pycuda/pycuda-9999.ebuild
+++ b/dev-python/pycuda/pycuda-9999.ebuild
@@ -1,13 +1,12 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/pycuda-9999.ebuild,v 1.12 2012/02/25 01:54:53 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pycuda/pycuda-9999.ebuild,v 1.13 2013/07/07 19:15:38 jlec Exp $
 
-EAPI="4"
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"
+EAPI=5
 
-inherit distutils git-2 multilib
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit cuda distutils-r1 git-2 multilib
 
 DESCRIPTION="Python wrapper for NVIDIA CUDA"
 HOMEPAGE="http://mathema.tician.de/software/pycuda/ http://pypi.python.org/pypi/pycuda"
@@ -18,43 +17,74 @@ EGIT_HAS_SUBMODULES="True"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="examples opengl"
+IUSE="examples opengl test"
 
-RDEPEND=">=dev-libs/boost-1.48[python]
-	dev-python/decorator
-	dev-python/numpy
-	dev-python/pytools
+RDEPEND="
+	dev-libs/boost[python,${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pytools-2013[${PYTHON_USEDEP}]
 	dev-util/nvidia-cuda-toolkit
+	x11-drivers/nvidia-drivers
 	opengl? ( virtual/opengl )"
-DEPEND="${RDEPEND}"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mako[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}] )"
 
-DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"
+# We need write acccess /dev/nvidia0 and /dev/nvidiactl and the portage
+# user is (usually) not in the video group
+RESTRICT="userpriv"
 
 src_unpack() {
 	git-2_src_unpack
 }
 
-src_configure() {
+python_prepare_all() {
+	cuda_sanitize
+	sed \
+		-e "s:'--preprocess':\'--preprocess\', \'--compiler-bindir=$(cuda_gccdir)\':g" \
+		-e "s:\"--cubin\":\'--cubin\', \'--compiler-bindir=$(cuda_gccdir)\':g" \
+		-e "s:/usr/include/pycuda:${S}/src/cuda:g" \
+		-i pycuda/compiler.py || die
+
+	touch siteconf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
 	local myopts=()
 	use opengl && myopts+=(--cuda-enable-gl)
 
-	configuration() {
-		"$(PYTHON)" configure.py \
-			--boost-inc-dir="${EPREFIX}/usr/include" \
-			--boost-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
-			--boost-python-libname=boost_python-${PYTHON_ABI}-mt \
-			--boost-thread-libname=boost_thread-mt \
-			--cuda-root="${EPREFIX}/opt/cuda" \
-			--cudadrv-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
-			--cudart-lib-dir="${EPREFIX}/opt/cuda/$(get_libdir)" \
-			--no-use-shipped-boost \
-			"${myopts[@]}"
+	mkdir "${BUILD_DIR}" || die
+	cd "${BUILD_DIR}" || die
+	[[ -e ./siteconf.py ]] && rm -f ./siteconf.py
+	"${EPYTHON}" "${S}"/configure.py \
+		--boost-inc-dir="${EPREFIX}/usr/include" \
+		--boost-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--boost-python-libname=boost_python-$(echo ${EPYTHON} | sed 's/python//')-mt \
+		--boost-thread-libname=boost_thread-mt \
+		--cuda-root="${EPREFIX}/opt/cuda" \
+		--cudadrv-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--cudart-lib-dir="${EPREFIX}/opt/cuda/$(get_libdir)" \
+		--cuda-inc-dir="${EPREFIX}/opt/cuda/include" \
+		--no-use-shipped-boost \
+		"${myopts[@]}"
+	}
+src_test() {
+	# we need write access to this to run the tests
+	addwrite /dev/nvidia0
+	addwrite /dev/nvidiactl
+	python_test() {
+			py.test --debug -v -v -v || die "Tests fail with ${EPYTHON}"
 	}
-	python_execute_function -s configuration
+	distutils-r1_src_test
 }
 
-src_install() {
-	distutils_src_install
+python_install_all() {
+	distutils-r1_python_install_all
 
 	if use examples; then
 		insinto /usr/share/doc/${PF}