bump; tidy to deps syntax

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 77 insertions, 1 deletions

diff --git a/dev-python/networkx/ChangeLog b/dev-python/networkx/ChangeLog
index f9ca526ae205..00616f182c26 100644
--- a/dev-python/networkx/ChangeLog
+++ b/dev-python/networkx/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/networkx
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/networkx/ChangeLog,v 1.27 2014/08/15 00:17:57 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/networkx/ChangeLog,v 1.28 2014/10/07 16:53:03 idella4 Exp $
+
+*networkx-1.9.1 (07 Oct 2014)
+
+  07 Oct 2014; Ian Delaney <idella4@gentoo.org> +networkx-1.9.1.ebuild:
+  bump; tidy to deps syntax
 
   15 Aug 2014; Anthony G. Basile <blueness@gentoo.org> networkx-1.9.ebuild:
   Keyword ~ppc, bug #517086
diff --git a/dev-python/networkx/networkx-1.9.1.ebuild b/dev-python/networkx/networkx-1.9.1.ebuild
new file mode 100644
index 000000000000..2bccd0d95821
--- /dev/null
+++ b/dev-python/networkx/networkx-1.9.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/networkx/networkx-1.9.1.ebuild,v 1.1 2014/10/07 16:53:03 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python tools to manipulate graphs and complex networks"
+HOMEPAGE="http://networkx.github.io/ https://github.com/networkx/networkx"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+COMMON_DEPEND="dev-python/matplotlib[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/numpydoc[${PYTHON_USEDEP}]' python2_7)
+		$(python_gen_cond_dep 'dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]' python2_7 python{3_3,3_4})
+	)
+	test? (
+		${COMMON_DEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+RDEPEND="
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	examples? (
+		${COMMON_DEPEND}
+		$(python_gen_cond_dep 'dev-python/pygraphviz[${PYTHON_USEDEP}]' python2_7)
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Avoid d'loading of file objects.inv from 2 sites of python docs
+	sed -e "s/'sphinx.ext.intersphinx', //" -i doc/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# https://github.com/networkx/networkx/issues/1263
+	if use doc; then
+		sed \
+			-e "s:^\t\./:\t${PYTHON} :g" \
+			-i doc/Makefile || die
+		emake -C doc html
+	fi
+}
+
+python_test() {
+	nosetests -vv || die
+}
+
+python_install_all() {
+	# Oh my.
+	rm -r "${D}"usr/share/doc/${P} || die
+
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}