Version bump.

(Portage version: 2.2.0_alpha150/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 90 insertions, 3 deletions

diff --git a/dev-python/graph-tool/ChangeLog b/dev-python/graph-tool/ChangeLog
index 16068acb5ea8..d194a6bc4aec 100644
--- a/dev-python/graph-tool/ChangeLog
+++ b/dev-python/graph-tool/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/graph-tool
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v 1.1 2013/01/04 01:18:49 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v 1.2 2013/01/10 23:45:59 radhermit Exp $
+
+*graph-tool-2.2.21 (10 Jan 2013)
+
+  10 Jan 2013; Tim Harder <radhermit@gentoo.org> +graph-tool-2.2.21.ebuild,
+  graph-tool-9999.ebuild:
+  Version bump.
 
 *graph-tool-9999 (04 Jan 2013)
 *graph-tool-2.2.19 (04 Jan 2013)
diff --git a/dev-python/graph-tool/graph-tool-2.2.21.ebuild b/dev-python/graph-tool/graph-tool-2.2.21.ebuild
new file mode 100644
index 000000000000..06b33c6891f5
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.2.21.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-2.2.21.ebuild,v 1.1 2013/01/10 23:45:59 radhermit Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_1,3_2,3_3} )
+
+inherit eutils toolchain-funcs python-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.skewed.de/graph-tool"
+	inherit git-2
+	KEYWORDS=""
+else
+	SRC_URI="http://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="http://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+
+CDEPEND=">=dev-libs/boost-1.46.0[python]
+	dev-libs/expat
+	dev-python/numpy
+	sci-libs/scipy
+	sci-mathematics/cgal
+	cairo? (
+		dev-cpp/cairomm
+		dev-python/pycairo
+	)"
+RDEPEND="${CDEPEND}
+	dev-python/matplotlib
+	media-gfx/graphviz[python]"
+DEPEND="${CDEPEND}
+	dev-cpp/sparsehash
+	virtual/pkgconfig"
+
+# most machines don't have enough ram for parallel builds
+MAKEOPTS="${MAKEOPTS} -j1"
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	>py-compile
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir \
+		econf \
+			--disable-static \
+			--disable-optimization \
+			$(use_enable openmp) \
+			$(use_enable cairo)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	prune_libtool_files --modules
+
+	# remove unwanted extra docs
+	rm -r "${ED}"/usr/share/doc/${PN} || die
+}
+
+run_in_build_dir() {
+	pushd "${BUILD_DIR}" > /dev/null
+	"$@"
+	popd > /dev/null
+}
diff --git a/dev-python/graph-tool/graph-tool-9999.ebuild b/dev-python/graph-tool/graph-tool-9999.ebuild
index a4f686b3a5fa..30f709869bc6 100644
--- a/dev-python/graph-tool/graph-tool-9999.ebuild
+++ b/dev-python/graph-tool/graph-tool-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-9999.ebuild,v 1.1 2013/01/04 01:18:49 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-9999.ebuild,v 1.2 2013/01/10 23:45:59 radhermit Exp $
 
 EAPI="5"
 PYTHON_COMPAT=( python{2_7,3_1,3_2,3_3} )
@@ -71,7 +71,7 @@ src_install() {
 	prune_libtool_files --modules
 
 	# remove unwanted extra docs
-	rm -r "${ED}"/usr/usr || die
+	rm -r "${ED}"/usr/share/doc/${PN} || die
 }
 
 run_in_build_dir() {