Don't call dodoc on directory; bug 367547. Migrate to bash-completion-r1.

(Portage version: 2.2.0_alpha80/cvs/Linux x86_64)

3 files changed, 107 insertions, 5 deletions

diff --git a/dev-python/django/ChangeLog b/dev-python/django/ChangeLog
index a8ab5c0f7482..8dece15c7bac 100644
--- a/dev-python/django/ChangeLog
+++ b/dev-python/django/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/django
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/django/ChangeLog,v 1.72 2011/09/16 12:03:23 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django/ChangeLog,v 1.73 2011/12/14 10:23:36 floppym Exp $
+
+*django-1.3.1-r1 (14 Dec 2011)
+
+  14 Dec 2011; Mike Gilbert <floppym@gentoo.org> +django-1.3.1-r1.ebuild,
+  django-9999.ebuild:
+  Don't call dodoc on directory; bug 367547. Migrate to bash-completion-r1.
 
   16 Sep 2011; Tony Vroon <chainsaw@gentoo.org> django-1.3.1.ebuild:
   Marked stable on AMD64 based on arch testing by Agostino "ago" Sarubbo & Ian
diff --git a/dev-python/django/django-1.3.1-r1.ebuild b/dev-python/django/django-1.3.1-r1.ebuild
new file mode 100644
index 000000000000..dd9ac201fe81
--- /dev/null
+++ b/dev-python/django/django-1.3.1-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django/django-1.3.1-r1.ebuild,v 1.1 2011/12/14 10:23:36 floppym Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.*"
+
+inherit bash-completion-r1 distutils versionator webapp
+
+MY_P="Django-${PV}"
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="http://www.djangoproject.com/ http://pypi.python.org/pypi/Django"
+SRC_URI="http://media.djangoproject.com/releases/$(get_version_component_range 1-2)/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc mysql postgres sqlite test"
+
+RDEPEND="dev-python/imaging
+	sqlite? ( || ( dev-lang/python:2.7[sqlite] dev-lang/python:2.6[sqlite] dev-lang/python:2.5[sqlite] dev-python/pysqlite:2 ) )
+	postgres? ( dev-python/psycopg )
+	mysql? ( >=dev-python/mysql-python-1.2.1_p2 )"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-0.3 )
+	test? ( || ( dev-lang/python:2.7[sqlite] dev-lang/python:2.6[sqlite] dev-lang/python:2.5[sqlite] dev-python/pysqlite:2 ) )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="docs/README AUTHORS"
+WEBAPP_MANUAL_SLOT="yes"
+
+pkg_setup() {
+	python_pkg_setup
+	webapp_pkg_setup
+}
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_test() {
+	testing() {
+		# Tests have non-standard assumptions about PYTHONPATH and
+		# don't work with usual "build-${PYTHON_ABI}/lib".
+		PYTHONPATH="." "$(PYTHON)" tests/runtests.py --settings=test_sqlite -v1
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+
+	newbashcomp extras/django_bash_completion ${PN} || die
+
+	if use doc; then
+		rm -fr docs/_build/html/_sources
+		dohtml -A txt -r docs/_build/html/* || die "dohtml failed"
+	fi
+
+	insinto "${MY_HTDOCSDIR#${EPREFIX}}"
+	doins -r django/contrib/admin/media/* || die "doins failed"
+
+	webapp_src_install
+}
+
+pkg_preinst() {
+	:
+}
+
+pkg_postinst() {
+	bash-completion_pkg_postinst
+	distutils_pkg_postinst
+
+	einfo "Now, Django has the best of both worlds with Gentoo,"
+	einfo "ease of deployment for production and development."
+	echo
+	elog "A copy of the admin media is available to"
+	elog "webapp-config for installation in a webroot,"
+	elog "as well as the traditional location in python's"
+	elog "site-packages dir for easy development"
+	echo
+	ewarn "If you build Django ${PV} without USE=\"vhosts\""
+	ewarn "webapp-config will automatically install the"
+	ewarn "admin media into the localhost webroot."
+}
diff --git a/dev-python/django/django-9999.ebuild b/dev-python/django/django-9999.ebuild
index 640c2513bce3..7420daaa1b54 100644
--- a/dev-python/django/django-9999.ebuild
+++ b/dev-python/django/django-9999.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/django/django-9999.ebuild,v 1.9 2011/02/09 18:16:28 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/django/django-9999.ebuild,v 1.10 2011/12/14 10:23:36 floppym Exp $
 
 EAPI="3"
 PYTHON_DEPEND="2"
 SUPPORT_PYTHON_ABIS="1"
 RESTRICT_PYTHON_ABIS="3.*"
 
-inherit bash-completion distutils subversion webapp
+inherit bash-completion-r1 distutils subversion webapp
 
 DESCRIPTION="High-level Python web framework"
 HOMEPAGE="http://www.djangoproject.com/ http://pypi.python.org/pypi/Django"
@@ -30,7 +30,7 @@ S="${WORKDIR}"
 
 ESVN_REPO_URI="http://code.djangoproject.com/svn/django/trunk/"
 
-DOCS="docs/* AUTHORS"
+DOCS="docs/README AUTHORS"
 WEBAPP_MANUAL_SLOT="yes"
 
 pkg_setup() {
@@ -61,7 +61,7 @@ src_test() {
 src_install() {
 	distutils_src_install
 
-	dobashcompletion extras/django_bash_completion
+	dobashcomp extras/django_bash_completion ${PN}
 
 	if use doc; then
 		rm -fr docs/_build/html/_sources