Migrate to distutils-r1. Enable tests.

(Portage version: 2.2.0_alpha151/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 49 insertions, 2 deletions

diff --git a/dev-python/anyjson/ChangeLog b/dev-python/anyjson/ChangeLog
index ac24b3e24c28..3cfb06ae85f5 100644
--- a/dev-python/anyjson/ChangeLog
+++ b/dev-python/anyjson/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/anyjson
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/anyjson/ChangeLog,v 1.4 2012/07/18 04:30:33 iksaif Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/anyjson/ChangeLog,v 1.5 2013/01/13 20:41:11 mgorny Exp $
+
+*anyjson-0.3.3-r1 (13 Jan 2013)
+
+  13 Jan 2013; Michał Górny <mgorny@gentoo.org> +anyjson-0.3.3-r1.ebuild:
+  Migrate to distutils-r1. Enable tests.
 
   18 Jul 2012; Corentin Chary <iksaif@gentoo.org> anyjson-0.3.3.ebuild:
   Simplify PYTHON_DEPEND.
diff --git a/dev-python/anyjson/anyjson-0.3.3-r1.ebuild b/dev-python/anyjson/anyjson-0.3.3-r1.ebuild
new file mode 100644
index 000000000000..80b571a3ca02
--- /dev/null
+++ b/dev-python/anyjson/anyjson-0.3.3-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/anyjson/anyjson-0.3.3-r1.ebuild,v 1.1 2013/01/13 20:41:11 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} pypy{1_9,2_0} )
+
+inherit distutils-r1
+
+DESCRIPTION="Wraps the best available JSON implementation available in a common interface"
+HOMEPAGE="http://bitbucket.org/runeh/anyjson"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# python2.6+ has builtin json module
+# python2.5 needs any of the supported impls
+RDEPEND="
+	python_targets_python2_5? (
+		dev-python/simplejson[python_targets_python2_5] )"
+
+# please keep all supported implementations in 'test?'
+# to make sure the package is used in the widest way
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/simplejson[$(python_gen_usedep python2* python3_3 pypy*)]
+	)"
+
+python_test() {
+	cp -r -l tests "${BUILD_DIR}"/lib || die
+	if [[ ${EPYTHON} == python3* ]]; then
+		2to3 -w --no-diffs "${BUILD_DIR}"/lib || die
+	fi
+
+	nosetests -w "${BUILD_DIR}"/lib || die "Tests fail with ${EPYTHON}"
+}