Version bump. Should fix cross-compilation issues.

(Portage version: 2.2_rc40/cvs/Linux x86_64)

3 files changed, 148 insertions, 1 deletions

diff --git a/dev-libs/gmime/ChangeLog b/dev-libs/gmime/ChangeLog
index 6c87c7385f96..01b576bef45a 100644
--- a/dev-libs/gmime/ChangeLog
+++ b/dev-libs/gmime/ChangeLog
@@ -1,6 +1,17 @@
 # ChangeLog for dev-libs/gmime
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v 1.91 2009/08/28 12:21:22 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/ChangeLog,v 1.92 2009/08/31 21:52:49 eva Exp $
+
+*gmime-2.4.8 (31 Aug 2009)
+
+  31 Aug 2009; Gilles Dartiguelongue <eva@gentoo.org> +gmime-2.2.24.ebuild,
+  +gmime-2.4.8.ebuild:
+  Version bump. Should fix cross-compilation issues.
+
+*gmime-2.2.24 (31 Aug 2009)
+
+  31 Aug 2009; Gilles Dartiguelongue <eva@gentoo.org> +gmime-2.2.24.ebuild:
+  Version bump. Should fix cross-compilation issues.
 
   28 Aug 2009; Tobias Klausmann <klausman@gentoo.org> gmime-2.4.7.ebuild:
   Stable on alpha, bug #278718
diff --git a/dev-libs/gmime/gmime-2.2.24.ebuild b/dev-libs/gmime/gmime-2.2.24.ebuild
new file mode 100644
index 000000000000..9a4430c8ca52
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.2.24.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/gmime-2.2.24.ebuild,v 1.1 2009/08/31 21:52:49 eva Exp $
+
+inherit gnome2 eutils mono libtool autotools
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+#SRC_URI="http://spruce.sourceforge.net/${PN}/sources/v${PV%.*}/${P}.tar.gz"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/"
+
+SLOT="0"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="doc mono"
+
+RDEPEND=">=dev-libs/glib-2
+	mono? ( dev-lang/mono
+			>=dev-dotnet/gtk-sharp-2.4.0 )
+	sys-libs/zlib"
+DEPEND="${RDEPEND}
+		dev-util/pkgconfig
+		dev-util/gtk-doc-am
+		doc? (
+			>=dev-util/gtk-doc-1.0
+			app-text/docbook-sgml-utils )"
+
+DOCS="AUTHORS ChangeLog COPYING INSTALL NEWS PORTING README TODO doc/html/"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/gmime-2.2.23-sign-assembly.patch"
+	cp "${FILESDIR}/gmime-sharp.snk" mono/
+	if use doc ; then
+		#db2html should be docbook2html
+		sed -i -e 's:db2html:docbook2html -o gmime-tut:g' \
+			docs/tutorial/Makefile.am docs/tutorial/Makefile.in \
+			|| die "sed failed (1)"
+		# Fix doc targets (bug #97154)
+		sed -i -e 's!\<\(tmpl-build.stamp\): !\1 $(srcdir)/tmpl/*.sgml: !' \
+			gtk-doc.make docs/reference/Makefile.in || die "sed failed (3)"
+	fi
+
+	eautoreconf
+	elibtoolize
+}
+
+src_compile() {
+	econf $(use_enable mono) $(use_enable doc gtk-doc)
+	MONO_PATH="${S}" emake || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "installation failed"
+
+	if use doc ; then
+		# we don't use docinto/dodoc, because we don't want html doc gzipped
+		insinto /usr/share/doc/${PF}/tutorial
+		doins docs/tutorial/html/*
+	fi
+
+	# rename these two, so they don't conflict with app-arch/sharutils
+	# (bug #70392)	Ticho, 2004-11-10
+	mv "${D}/usr/bin/uuencode" "${D}/usr/bin/gmime-uuencode"
+	mv "${D}/usr/bin/uudecode" "${D}/usr/bin/gmime-uudecode"
+	mono_multilib_comply
+}
diff --git a/dev-libs/gmime/gmime-2.4.8.ebuild b/dev-libs/gmime/gmime-2.4.8.ebuild
new file mode 100644
index 000000000000..4aadd4294534
--- /dev/null
+++ b/dev-libs/gmime/gmime-2.4.8.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/gmime/gmime-2.4.8.ebuild,v 1.1 2009/08/31 21:52:49 eva Exp $
+
+inherit gnome2 eutils mono libtool
+
+DESCRIPTION="Utilities for creating and parsing messages using MIME"
+HOMEPAGE="http://spruce.sourceforge.net/gmime/"
+
+SLOT="2.4"
+LICENSE="LGPL-2.1"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="doc mono"
+
+RDEPEND=">=dev-libs/glib-2.12
+	mono? ( dev-lang/mono
+			>=dev-dotnet/gtk-sharp-2.4.0 )
+	sys-libs/zlib"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? (
+		>=dev-util/gtk-doc-1.0
+		app-text/docbook-sgml-utils )"
+
+DOCS="AUTHORS ChangeLog COPYING INSTALL NEWS PORTING README TODO doc/html/"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	if use doc ; then
+		#db2html should be docbook2html
+		sed -i -e 's:db2html:docbook2html -o gmime-tut:g' \
+			docs/tutorial/Makefile.am docs/tutorial/Makefile.in \
+			|| die "sed failed (1)"
+		# Fix doc targets (bug #97154)
+		sed -i -e 's!\<\(tmpl-build.stamp\): !\1 $(srcdir)/tmpl/*.sgml: !' \
+			gtk-doc.make docs/reference/Makefile.in || die "sed failed (3)"
+	fi
+
+	# Use correct libdir for mono assembly
+	sed -i -e 's:^libdir.*:libdir=@libdir@:' \
+		   -e 's:^prefix=:exec_prefix=:' \
+		   -e 's:prefix)/lib:libdir):' \
+		mono/gmime-sharp-2.4.pc.in mono/Makefile.{am,in} || die "sed failed (2)"
+
+	elibtoolize
+}
+
+src_compile() {
+	econf $(use_enable mono) $(use_enable doc gtk-doc)
+	MONO_PATH="${S}" emake || die "emake failed"
+}
+
+src_install() {
+	emake GACUTIL_FLAGS="/root '${D}/usr/$(get_libdir)' /gacdir /usr/$(get_libdir) /package ${PN}" \
+		DESTDIR="${D}" install || die "installation failed"
+
+	if use doc ; then
+		# we don't use docinto/dodoc, because we don't want html doc gzipped
+		insinto /usr/share/doc/${PF}/tutorial
+		doins docs/tutorial/html/*
+	fi
+
+	# rename these two, so they don't conflict with app-arch/sharutils
+	# (bug #70392)	Ticho, 2004-11-10
+	mv "${D}/usr/bin/uuencode" "${D}/usr/bin/gmime-uuencode-${SLOT}"
+	mv "${D}/usr/bin/uudecode" "${D}/usr/bin/gmime-uudecode-${SLOT}"
+}