Stable candidate won't have quvi support due bug #355903, keep it in testing as talked with Nirbheek.

(Portage version: 2.1.9.40/cvs/Linux x86_64)

3 files changed, 74 insertions, 6 deletions

diff --git a/dev-libs/totem-pl-parser/ChangeLog b/dev-libs/totem-pl-parser/ChangeLog
index dd9961aab0e0..4f49223e028e 100644
--- a/dev-libs/totem-pl-parser/ChangeLog
+++ b/dev-libs/totem-pl-parser/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/totem-pl-parser
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog,v 1.81 2011/02/21 20:02:11 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/ChangeLog,v 1.82 2011/02/21 20:39:00 pacho Exp $
+
+*totem-pl-parser-2.32.3-r1 (21 Feb 2011)
+
+  21 Feb 2011; Pacho Ramos <pacho@gentoo.org> totem-pl-parser-2.32.3.ebuild,
+  +totem-pl-parser-2.32.3-r1.ebuild:
+  Stable candidate won't have quvi support due bug #355903, keep it in testing
+  as talked with Nirbheek.
 
   21 Feb 2011; Pacho Ramos <pacho@gentoo.org> totem-pl-parser-2.32.3.ebuild,
   +files/totem-pl-parser-2.32.3-fix-quvi.patch:
diff --git a/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3-r1.ebuild b/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3-r1.ebuild
new file mode 100644
index 000000000000..3ae6e7f3fe0c
--- /dev/null
+++ b/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3-r1.ebuild,v 1.1 2011/02/21 20:39:00 pacho Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+
+inherit gnome2 eutils autotools
+
+DESCRIPTION="Playlist parsing library"
+HOMEPAGE="http://projects.gnome.org/totem/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc quvi +introspection"
+
+RDEPEND=">=dev-libs/glib-2.24:2
+	dev-libs/gmime:2.4
+	>=net-libs/libsoup-gnome-2.30:2.4
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	quvi? ( >=media-libs/quvi-0.2.11 )"
+DEPEND="${RDEPEND}
+	!<media-video/totem-2.21
+	>=sys-devel/gettext-0.17
+	>=dev-util/intltool-0.35
+	doc? ( >=dev-util/gtk-doc-1.11 )
+	>=dev-util/gtk-doc-am-1.11"
+# eautoreconf needs:
+#	>=dev-util/gtk-doc-am-1.11
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-static
+		$(use_enable quvi)
+		$(use_enable introspection)"
+	DOCS="AUTHORS ChangeLog NEWS"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Disable tests requiring network access, bug #346127
+	sed -e 's:\(g_test_add_func.*/parser/resolution.*\):/*\1*/:' \
+		-e 's:\(g_test_add_func.*/parser/parsing/itms_link.*\):/*\1*/:' \
+		-i plparse/tests/parser.c || die "sed failed"
+
+	# Fix --enable-quvi option
+	epatch "${FILESDIR}/${P}-fix-quvi.patch"
+
+	intltoolize --force --copy --automake || die "intltoolize failed"
+	eautoreconf
+}
+
+src_test() {
+	# This is required as told by upstream in bgo#629542
+	dbus-launch emake check || die "emake check failed"
+}
diff --git a/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3.ebuild b/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3.ebuild
index 2248921fefab..a4f59e6bb720 100644
--- a/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3.ebuild
+++ b/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3.ebuild,v 1.2 2011/02/21 20:02:11 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/totem-pl-parser/totem-pl-parser-2.32.3.ebuild,v 1.3 2011/02/21 20:39:00 pacho Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -13,13 +13,16 @@ HOMEPAGE="http://projects.gnome.org/totem/"
 LICENSE="LGPL-2"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-IUSE="doc quvi +introspection"
+IUSE="doc +introspection"
 
 RDEPEND=">=dev-libs/glib-2.24:2
 	dev-libs/gmime:2.4
 	>=net-libs/libsoup-gnome-2.30:2.4
-	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
-	quvi? ( >=media-libs/quvi-0.2.11 )"
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )"
+
+# FIXME: quvi support disabled due upstream bug #642906
+#       quvi? ( >=media-libs/quvi-0.2.11 )"
+
 DEPEND="${RDEPEND}
 	!<media-video/totem-2.21
 	>=sys-devel/gettext-0.17
@@ -32,7 +35,7 @@ DEPEND="${RDEPEND}
 pkg_setup() {
 	G2CONF="${G2CONF}
 		--disable-static
-		$(use_enable quvi)
+		--disable-quvi
 		$(use_enable introspection)"
 	DOCS="AUTHORS ChangeLog NEWS"
 }