Version bump (bug #319753).

(Portage version: 2.2_rc67/cvs/Linux x86_64)

3 files changed, 90 insertions, 1 deletions

diff --git a/dev-libs/xqilla/ChangeLog b/dev-libs/xqilla/ChangeLog
index b3f290a338aa..51ab4ede75b2 100644
--- a/dev-libs/xqilla/ChangeLog
+++ b/dev-libs/xqilla/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/xqilla
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xqilla/ChangeLog,v 1.10 2010/02/26 07:56:47 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xqilla/ChangeLog,v 1.11 2010/08/29 11:47:00 dev-zero Exp $
+
+*xqilla-2.2.4 (29 Aug 2010)
+
+  29 Aug 2010; Tiziano Müller <dev-zero@gentoo.org>
+  +files/2.2.4-respect-ldflags-no-rpath.patch, +xqilla-2.2.4.ebuild:
+  Version bump (bug #319753).
 
 *xqilla-2.2.3 (26 Feb 2010)
 
diff --git a/dev-libs/xqilla/files/2.2.4-respect-ldflags-no-rpath.patch b/dev-libs/xqilla/files/2.2.4-respect-ldflags-no-rpath.patch
new file mode 100644
index 000000000000..5188617c2585
--- /dev/null
+++ b/dev-libs/xqilla/files/2.2.4-respect-ldflags-no-rpath.patch
@@ -0,0 +1,13 @@
+diff --git a/Makefile.am b/Makefile.am
+index 1c08992..ffeb840 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -2,7 +2,7 @@ AUTOMAKE_OPTIONS = foreign dist-zip
+ SUBDIRS = include
+ 
+ INCLUDES = -I$(top_srcdir)/include/ $(xerces_include) -I$(top_srcdir)/src/lexer/ $(faxpp_include) $(tidy_include)
+-LDFLAGS = -L$(xerces_lib) -R$(xerces_lib) $(faxpp_lib) $(tidy_lib) -lxerces-c $(faxpp_library) $(tidy_library)
++LDFLAGS += -L$(xerces_lib) $(faxpp_lib) $(tidy_lib) -lxerces-c $(faxpp_library) $(tidy_library)
+ LDADD = libxqilla.la
+ ACLOCAL_AMFLAGS = -I autotools/m4
+ 
diff --git a/dev-libs/xqilla/xqilla-2.2.4.ebuild b/dev-libs/xqilla/xqilla-2.2.4.ebuild
new file mode 100644
index 000000000000..cf10fb921cfc
--- /dev/null
+++ b/dev-libs/xqilla/xqilla-2.2.4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xqilla/xqilla-2.2.4.ebuild,v 1.1 2010/08/29 11:47:00 dev-zero Exp $
+
+EAPI="2"
+inherit autotools eutils
+
+MY_P="XQilla-${PV}"
+
+DESCRIPTION="An XQuery and XPath 2 library and command line utility written in C++."
+HOMEPAGE="http://xqilla.sourceforge.net/HomePage"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples faxpp htmltidy"
+
+# XQilla bundles two libraries:
+# - mapm, heavily patched
+# - yajl, moderately patched
+# There's currently no way to unbundle those
+
+RDEPEND=">=dev-libs/xerces-c-3.1.0
+	faxpp? ( dev-libs/faxpp )
+	htmltidy? ( app-text/htmltidy )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# respect our LDFLAGS and don't add an rpath for the xerces-c lib
+	# since that is in the default LDPATH anyway and the binaries
+	# may need relinking at install-time because they temporary use
+	# already installed libraries
+	epatch "${FILESDIR}/${PV}-respect-ldflags-no-rpath.patch"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-xerces=/usr \
+		$(use_enable debug) \
+		$(use_with htmltidy tidy) \
+		$(use_with faxpp faxpp /usr)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		emake docs || die "emake docs failed"
+		emake devdocs || die "emake devdocs failed"
+	fi
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die "emake docs failed"
+
+	dodoc ChangeLog TODO
+
+	if use doc; then
+		cd docs
+		dohtml -r dev-api dom3-api simple-api
+	fi
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r "${S}"/src/samples/*
+	fi
+}