Use virtual/udev. Use udev.eclass to install udev helpers and rules to correct directories wrt #419423 by SpanKY

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 92 insertions, 3 deletions

diff --git a/dev-libs/openct/ChangeLog b/dev-libs/openct/ChangeLog
index eaa7a91c1535..c8c2a5d1c9bf 100644
--- a/dev-libs/openct/ChangeLog
+++ b/dev-libs/openct/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/openct
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.98 2012/06/19 13:56:54 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/ChangeLog,v 1.99 2012/11/28 22:39:36 ssuominen Exp $
+
+*openct-0.6.20-r3 (28 Nov 2012)
+
+  28 Nov 2012; Samuli Suominen <ssuominen@gentoo.org> openct-0.6.20.ebuild,
+  +openct-0.6.20-r3.ebuild:
+  Use virtual/udev. Use udev.eclass to install udev helpers and rules to
+  correct directories wrt #419423 by SpanKY
 
 *openct-0.6.20-r2 (19 Jun 2012)
 
diff --git a/dev-libs/openct/openct-0.6.20-r3.ebuild b/dev-libs/openct/openct-0.6.20-r3.ebuild
new file mode 100644
index 000000000000..7f16a47f3013
--- /dev/null
+++ b/dev-libs/openct/openct-0.6.20-r3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/openct-0.6.20-r3.ebuild,v 1.1 2012/11/28 22:39:36 ssuominen Exp $
+
+EAPI=5
+
+inherit eutils flag-o-matic multilib udev user
+
+DESCRIPTION="library for accessing smart card terminals"
+HOMEPAGE="http://www.opensc-project.org/openct/"
+
+SRC_URI="http://www.opensc-project.org/files/${PN}/${P}.tar.gz"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc pcsc-lite usb debug +udev"
+
+# libtool is required at runtime for libltdl
+RDEPEND="pcsc-lite? ( >=sys-apps/pcsc-lite-1.7.2-r1 )
+	usb? ( virtual/libusb:0 )
+	sys-devel/libtool"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+# udev is not required at all at build-time as it's only a matter of
+# installing the rules; add openrc for the checkpath used in the new
+# init script
+RDEPEND="${RDEPEND}
+	udev? ( virtual/udev )
+	sys-apps/openrc"
+
+pkg_setup() {
+	enewgroup openct
+	enewuser openctd
+}
+
+src_configure() {
+	use debug && append-cppflags -DDEBUG_IFDH
+
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--htmldir="/usr/share/doc/${PF}/html" \
+		--localstatedir=/var \
+		--with-udev="$(udev_get_udevdir)" \
+		--enable-non-privileged \
+		--with-daemon-user=openctd \
+		--with-daemon-groups=usb \
+		--enable-shared --disable-static \
+		$(use_enable doc) \
+		$(use_enable doc api-doc) \
+		$(use_enable pcsc-lite pcsc) \
+		$(use_with pcsc-lite bundle /usr/$(get_libdir)/readers/usb) \
+		$(use_enable usb)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	prune_libtool_files --all
+	rm "${D}"/usr/$(get_libdir)/openct-ifd.*
+
+	if use udev; then
+		insinto "$(udev_get_udevdir)"/rules.d
+		newins etc/openct.udev 70-openct.rules
+	fi
+
+	newinitd "${FILESDIR}"/openct.rc.2 openct
+}
+
+pkg_postinst() {
+	elog
+	elog "You need to edit /etc/openct.conf to enable serial readers."
+	elog
+	elog "You should add \"openct\" to your default runlevel. To do so"
+	elog "type \"rc-update add openct default\"."
+	elog
+	elog "You need to be a member of the (newly created) group openct to"
+	elog "access smart card readers connected to this system. Set users'"
+	elog "groups with usermod -G.  root always has access."
+	elog
+}
diff --git a/dev-libs/openct/openct-0.6.20.ebuild b/dev-libs/openct/openct-0.6.20.ebuild
index 85f2255251fe..e233078d3f80 100644
--- a/dev-libs/openct/openct-0.6.20.ebuild
+++ b/dev-libs/openct/openct-0.6.20.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/openct-0.6.20.ebuild,v 1.8 2012/06/06 03:45:11 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/openct/openct-0.6.20.ebuild,v 1.9 2012/11/28 22:39:36 ssuominen Exp $
 
 EAPI="2"
 
@@ -19,7 +19,7 @@ IUSE="doc pcsc-lite usb"
 # libtool is required at runtime for libltdl
 RDEPEND="pcsc-lite? ( sys-apps/pcsc-lite )
 	usb? ( virtual/libusb:0 )
-	>=sys-fs/udev-096
+	virtual/udev
 	sys-devel/libtool"
 
 DEPEND="${RDEPEND}