Revision bump to use latest patchset, also seems to fix bug #417935 by Xake.

(Portage version: 2.1.10.65/cvs/Linux x86_64)

2 files changed, 60 insertions, 1 deletions

diff --git a/dev-libs/libtar/ChangeLog b/dev-libs/libtar/ChangeLog
index 3c5acd551f13..21b70a5468ef 100644
--- a/dev-libs/libtar/ChangeLog
+++ b/dev-libs/libtar/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libtar
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libtar/ChangeLog,v 1.22 2012/05/29 13:40:21 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libtar/ChangeLog,v 1.23 2012/06/07 10:28:53 pacho Exp $
+
+*libtar-1.2.11-r5 (07 Jun 2012)
+
+  07 Jun 2012; Pacho Ramos <pacho@gentoo.org> +libtar-1.2.11-r5.ebuild:
+  Revision bump to use latest patchset, also seems to fix bug #417935 by Xake.
 
   29 May 2012; Alexis Ballier <aballier@gentoo.org> libtar-1.2.11-r4.ebuild:
   keyword ~amd64-fbsd
diff --git a/dev-libs/libtar/libtar-1.2.11-r5.ebuild b/dev-libs/libtar/libtar-1.2.11-r5.ebuild
new file mode 100644
index 000000000000..ef7db4d072cb
--- /dev/null
+++ b/dev-libs/libtar/libtar-1.2.11-r5.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libtar/libtar-1.2.11-r5.ebuild,v 1.1 2012/06/07 10:28:53 pacho Exp $
+
+EAPI=4
+inherit autotools eutils multilib
+
+p_level=8
+
+DESCRIPTION="C library for manipulating tar archives"
+HOMEPAGE="http://www.feep.net/libtar/ http://packages.qa.debian.org/libt/libtar.html"
+SRC_URI="ftp://ftp.feep.net/pub/software/libtar/${P}.tar.gz
+	mirror://debian/pool/main/libt/${PN}/${PN}_${PV}-${p_level}.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="static-libs zlib"
+
+DEPEND="zlib? ( sys-libs/zlib )
+	!zlib? ( app-arch/gzip )"
+
+src_prepare() {
+	local d="${WORKDIR}"/debian/patches
+	sed -i -e '/#/d' "${d}"/series || die
+	EPATCH_SOURCE="${d}" epatch $(<"${d}"/series)
+
+	epatch "${FILESDIR}"/${P}-f{ree,ortify}.patch
+
+	sed -i \
+		-e '/INSTALL_PROGRAM/s:-s::' \
+		{doc,lib{,tar}}/Makefile.in || die
+
+	sed -i -e "/\/usr\/share\/aclocal/s:/usr:$EPREFIX/usr:" aclocal.m4
+	eautoreconf # reconf for missing config.sub
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with zlib)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc ChangeLog* README TODO
+	newdoc compat/README README.compat
+	newdoc compat/TODO TODO.compat
+	newdoc listhash/TODO TODO.listhash
+	newdoc "${WORKDIR}"/debian/changelog ChangeLog.debian
+
+	prune_libtool_files
+}