Version bump to netsurf-2.9 tarball, drop old

(Portage version: 2.1.11.8/cvs/Linux x86_64)

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-libs/libnsfb/libnsfb-0.0.2.ebuild b/dev-libs/libnsfb/libnsfb-0.0.2.ebuild
new file mode 100644
index 000000000000..8c98287ce2e8
--- /dev/null
+++ b/dev-libs/libnsfb/libnsfb-0.0.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libnsfb/libnsfb-0.0.2.ebuild,v 1.1 2012/07/18 16:00:36 xmw Exp $
+
+EAPI=4
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="framebuffer abstraction library, written in C"
+HOMEPAGE="http://www.netsurf-browser.org/projects/libnsfb/"
+SRC_URI="http://download.netsurf-browser.org/netsurf/releases/source-full/netsurf-2.9-full-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm"
+IUSE="static-libs"
+
+RDEPEND="media-libs/libsdl
+	net-libs/libvncserver
+	x11-libs/libxcb
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-keysyms"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+# we don't allow access to /dev/fb0
+RESTRICT="test"
+
+src_unpack() {
+	default
+	mv netsurf-2.9/${P} . || die
+	rm -r netsurf-2.9 || die
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-xcb-fix.patch
+	epatch "${FILESDIR}"/${P}-unused.patch
+
+	sed -e "/^INSTALL_ITEMS/s: /lib: /$(get_libdir):g" \
+		-i Makefile || die
+	sed -e "/^libdir/s:/lib:/$(get_libdir):g" \
+		-i ${PN}.pc.in || die
+	echo "Q := " >> Makefile.config.override
+	echo "CC := $(tc-getCC)" >> Makefile.config.override
+	echo "AR := $(tc-getAR)" >> Makefile.config.override
+}
+
+src_compile() {
+	emake COMPONENT_TYPE=lib-shared
+	use static-libs && \
+		emake COMPONENT_TYPE=lib-static
+}
+
+src_test() {
+	emake COMPONENT_TYPE=lib-shared test
+	use static-libs && \
+		emake COMPONENT_TYPE=lib-static test
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr COMPONENT_TYPE=lib-shared install
+	use static-libs && \
+		emake DESTDIR="${D}" PREFIX=/usr COMPONENT_TYPE=lib-static install
+	dodoc usage
+}