Split libltdl out of main libtool package per upstream recommendations.

(Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key D2E96200)

5 files changed, 143 insertions, 0 deletions

diff --git a/dev-libs/libltdl/ChangeLog b/dev-libs/libltdl/ChangeLog
new file mode 100644
index 000000000000..571dc3b1f2cb
--- /dev/null
+++ b/dev-libs/libltdl/ChangeLog
@@ -0,0 +1,12 @@
+# ChangeLog for dev-libs/libltdl
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libltdl/ChangeLog,v 1.1 2014/11/03 05:31:48 vapier Exp $
+
+*libltdl-2.4.3 (03 Nov 2014)
+*libltdl-1.5.26 (03 Nov 2014)
+*libltdl-1.3.5 (03 Nov 2014)
+
+  03 Nov 2014; Mike Frysinger <vapier@gentoo.org> +libltdl-1.3.5.ebuild,
+  +libltdl-1.5.26.ebuild, +libltdl-2.4.3.ebuild, +metadata.xml:
+  Split libltdl out of main libtool package per upstream recommendations.
+
diff --git a/dev-libs/libltdl/libltdl-1.3.5.ebuild b/dev-libs/libltdl/libltdl-1.3.5.ebuild
new file mode 100644
index 000000000000..be4185412a88
--- /dev/null
+++ b/dev-libs/libltdl/libltdl-1.3.5.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libltdl/libltdl-1.3.5.ebuild,v 1.1 2014/11/03 05:31:48 vapier Exp ${P}-r1.ebuild,v 1.8 2002/10/04 06:34:42 kloeri Exp $
+
+# This ebuild provides libltdl.so.0.
+
+EAPI="4"
+
+inherit multilib-minimal
+
+MY_P="libtool-${PV}"
+
+DESCRIPTION="A shared library tool for developers"
+HOMEPAGE="http://www.gnu.org/software/libtool/"
+SRC_URI="mirror://gnu/libtool/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1.3"
+KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86"
+IUSE=""
+# libltdl doesn't have a testsuite.
+RESTRICT="test"
+
+RDEPEND="!sys-devel/libtool:1.3"
+
+S="${WORKDIR}/${MY_P}"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-ltdl-install \
+		--disable-static
+}
+
+multilib_src_compile() {
+	emake -C libltdl
+}
+
+multilib_src_install() {
+	emake -C libltdl DESTDIR="${D}" install-exec
+	# basically we just install ABI libs for old packages
+	rm "${ED}"/usr/$(get_libdir)/libltdl.{la,so} || die
+}
diff --git a/dev-libs/libltdl/libltdl-1.5.26.ebuild b/dev-libs/libltdl/libltdl-1.5.26.ebuild
new file mode 100644
index 000000000000..48873ce511a0
--- /dev/null
+++ b/dev-libs/libltdl/libltdl-1.5.26.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libltdl/libltdl-1.5.26.ebuild,v 1.1 2014/11/03 05:31:48 vapier Exp $
+
+# This ebuild provides libltdl.so.3.
+
+EAPI="4"
+
+inherit multilib-minimal
+
+MY_P="libtool-${PV}"
+
+DESCRIPTION="A shared library tool for developers"
+HOMEPAGE="http://www.gnu.org/software/libtool/"
+SRC_URI="mirror://gnu/libtool/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="1.5"
+KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+# libltdl doesn't have a testsuite.
+RESTRICT="test"
+
+RDEPEND="!sys-devel/libtool:1.5"
+
+S="${WORKDIR}/${MY_P}/libltdl"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-ltdl-install \
+		--disable-static
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install-exec
+	# basically we just install ABI libs for old packages
+	rm "${ED}"/usr/$(get_libdir)/libltdl.{la,so} || die
+}
diff --git a/dev-libs/libltdl/libltdl-2.4.3.ebuild b/dev-libs/libltdl/libltdl-2.4.3.ebuild
new file mode 100644
index 000000000000..cd434f46723f
--- /dev/null
+++ b/dev-libs/libltdl/libltdl-2.4.3.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libltdl/libltdl-2.4.3.ebuild,v 1.1 2014/11/03 05:31:48 vapier Exp $
+
+EAPI="4"
+
+inherit multilib-minimal
+
+MY_P="libtool-${PV}"
+
+DESCRIPTION="A shared library tool for developers"
+HOMEPAGE="http://www.gnu.org/software/libtool/"
+SRC_URI="mirror://gnu/libtool/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
+IUSE="static-libs"
+# libltdl doesn't have a testsuite.
+RESTRICT="test"
+
+RDEPEND="!<sys-devel/libtool-2.4.3-r2:2
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20140406-r2
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+DEPEND="app-arch/xz-utils"
+
+S="${WORKDIR}/${MY_P}/libltdl"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-ltdl-install \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	# While the libltdl.la file is not used directly, the m4 ltdl logic
+	# keys off of its existence when searching for ltdl support. #293921
+	#use static-libs || find "${D}" -name libltdl.la -delete
+}
diff --git a/dev-libs/libltdl/metadata.xml b/dev-libs/libltdl/metadata.xml
new file mode 100644
index 000000000000..96a2d586367d
--- /dev/null
+++ b/dev-libs/libltdl/metadata.xml
@@ -0,0 +1,5 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<herd>base-system</herd>
+</pkgmetadata>