Version bump wrt #427512 by Pacho Ramos

(Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

2 files changed, 84 insertions, 1 deletions

diff --git a/dev-libs/libdbusmenu/ChangeLog b/dev-libs/libdbusmenu/ChangeLog
index 0ee6e199fd76..b88d9da50484 100644
--- a/dev-libs/libdbusmenu/ChangeLog
+++ b/dev-libs/libdbusmenu/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libdbusmenu
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libdbusmenu/ChangeLog,v 1.17 2012/07/20 10:45:29 angelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libdbusmenu/ChangeLog,v 1.18 2012/07/21 17:42:16 ssuominen Exp $
+
+*libdbusmenu-0.6.2 (21 Jul 2012)
+
+  21 Jul 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +libdbusmenu-0.6.2.ebuild:
+  Version bump wrt #427512 by Pacho Ramos
 
   20 Jul 2012; Christoph Mende <angelos@gentoo.org>
   libdbusmenu-0.5.1-r200.ebuild, libdbusmenu-0.5.1-r300.ebuild:
diff --git a/dev-libs/libdbusmenu/libdbusmenu-0.6.2.ebuild b/dev-libs/libdbusmenu/libdbusmenu-0.6.2.ebuild
new file mode 100644
index 000000000000..3b2a5639d56f
--- /dev/null
+++ b/dev-libs/libdbusmenu/libdbusmenu-0.6.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libdbusmenu/libdbusmenu-0.6.2.ebuild,v 1.1 2012/07/21 17:42:16 ssuominen Exp $
+
+EAPI=4
+
+AYATANA_VALA_VERSION=0.16
+
+inherit eutils flag-o-matic virtualx
+
+DESCRIPTION="Library to pass menu structure across DBus"
+HOMEPAGE="http://launchpad.net/dbusmenu"
+SRC_URI="http://launchpad.net/${PN/lib}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug gtk +introspection test"
+
+RDEPEND=">=dev-libs/glib-2.30
+	>=dev-libs/dbus-glib-0.100
+	dev-libs/libxml2
+	gtk? ( >=x11-libs/gtk+-3.2:3 )
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	!<${CATEGORY}/${PN}-0.5.1-r200"
+DEPEND="${RDEPEND}
+	app-text/gnome-doc-utils
+	dev-lang/vala:${AYATANA_VALA_VERSION}[vapigen]
+	dev-util/intltool
+	virtual/pkgconfig
+	test? (
+		>=dev-libs/json-glib-0.14[introspection?]
+		dev-util/dbus-test-runner
+		)"
+
+src_prepare() {
+	if use test; then
+		sed -i -e 's:-DG_DISABLE_DEPRECATED::' tests/Makefile.{am,in} || die #391103, #414323
+	fi
+}
+
+src_configure() {
+	append-flags -Wno-Werror #414323
+
+	export VALA_API_GEN="$(type -P vapigen-${AYATANA_VALA_VERSION})"
+
+	# dumper extra tool is only for GTK+-2.x
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-static \
+		--disable-silent-rules \
+		--disable-scrollkeeper \
+		$(use_enable gtk) \
+		--disable-dumper \
+		$(use_enable test tests) \
+		$(use_enable introspection) \
+		$(use_enable debug massivedebugging) \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		--with-gtk=3
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README
+
+	local a b
+	for a in ${PN}-{glib,gtk}; do
+		b=/usr/share/doc/${PF}/html/${a}
+		[[ -d ${ED}/${b} ]] && dosym ${b} /usr/share/gtk-doc/html/${a}
+	done
+
+	prune_libtool_files
+}