Minor version bump.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 74 insertions, 1 deletions

diff --git a/dev-libs/jsoncpp/ChangeLog b/dev-libs/jsoncpp/ChangeLog
index 96339c9089fa..cb4cca7a1637 100644
--- a/dev-libs/jsoncpp/ChangeLog
+++ b/dev-libs/jsoncpp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/jsoncpp
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/jsoncpp/ChangeLog,v 1.12 2015/04/04 08:11:39 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/jsoncpp/ChangeLog,v 1.13 2015/04/07 18:12:01 mgorny Exp $
+
+*jsoncpp-0.10.1 (07 Apr 2015)
+
+  07 Apr 2015; Michał Górny <mgorny@gentoo.org> +jsoncpp-0.10.1.ebuild:
+  Minor version bump.
 
   04 Apr 2015; Jeroen Roovers <jer@gentoo.org> jsoncpp-0.6.0_rc2.ebuild:
   Marked ~hppa (bug #539126).
diff --git a/dev-libs/jsoncpp/jsoncpp-0.10.1.ebuild b/dev-libs/jsoncpp/jsoncpp-0.10.1.ebuild
new file mode 100644
index 000000000000..bdfaa7834115
--- /dev/null
+++ b/dev-libs/jsoncpp/jsoncpp-0.10.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/jsoncpp/jsoncpp-0.10.1.ebuild,v 1.1 2015/04/07 18:12:01 mgorny Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils python-any-r1
+
+DESCRIPTION="C++ JSON reader and writer"
+HOMEPAGE="https://github.com/open-source-parsers/jsoncpp"
+SRC_URI="https://github.com/open-source-parsers/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( public-domain MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86"
+IUSE="doc test"
+
+DEPEND="
+	doc? (
+		app-doc/doxygen
+		${PYTHON_DEPS}
+	)
+	test? (
+		${PYTHON_DEPS}
+	)"
+RDEPEND=""
+
+pkg_setup() {
+	if use doc || use test; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DJSONCPP_WITH_TESTS=$(usex test)
+		-DJSONCPP_WITH_POST_BUILD_UNITTEST=OFF
+		-DJSONCPP_WITH_CMAKE_PACKAGE=ON
+
+		-DBUILD_SHARED_LIBS=ON
+		# Follow Debian, Ubuntu, Arch convention for headers location
+		# bug #452234
+		-DINCLUDE_INSTALL_DIR="${EPREFIX}"/usr/include/jsoncpp
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		"${EPYTHON}" doxybuild.py --doxygen=/usr/bin/doxygen || die
+	fi
+}
+
+src_test() {
+	emake -C "${BUILD_DIR}" jsoncpp_check
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		dohtml dist/doxygen/jsoncpp*/*
+	fi
+}