Add multilib support (bug #514006, thanks to Karl Lindén and tokiclover). Fix pthread linking weirdness. Fix USE=doc. Update license.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x18E5B6F2D8D5EC8D)

3 files changed, 78 insertions, 7 deletions

diff --git a/dev-libs/dbus-c++/ChangeLog b/dev-libs/dbus-c++/ChangeLog
index f0121fd9ef51..6a9c70062589 100644
--- a/dev-libs/dbus-c++/ChangeLog
+++ b/dev-libs/dbus-c++/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/dbus-c++
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-c++/ChangeLog,v 1.7 2014/02/16 10:34:54 pacho Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-c++/ChangeLog,v 1.8 2015/03/22 21:36:55 tetromino Exp $
+
+*dbus-c++-0.9.0-r2 (22 Mar 2015)
+
+  22 Mar 2015; Alexandre Rostovtsev <tetromino@gentoo.org>
+  dbus-c++-0.9.0-r1.ebuild, +dbus-c++-0.9.0-r2.ebuild:
+  Add multilib support (bug #514006, thanks to Karl Lindén and tokiclover).
+  Fix pthread linking weirdness. Fix USE=doc. Update license.
 
   16 Feb 2014; Pacho Ramos <pacho@gentoo.org> -dbus-c++-0.6.0_p20111126.ebuild,
   -dbus-c++-0.9.0.ebuild, metadata.xml:
diff --git a/dev-libs/dbus-c++/dbus-c++-0.9.0-r1.ebuild b/dev-libs/dbus-c++/dbus-c++-0.9.0-r1.ebuild
index c39793c3a9c7..58a8bf23a716 100644
--- a/dev-libs/dbus-c++/dbus-c++-0.9.0-r1.ebuild
+++ b/dev-libs/dbus-c++/dbus-c++-0.9.0-r1.ebuild
@@ -1,23 +1,23 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-c++/dbus-c++-0.9.0-r1.ebuild,v 1.2 2013/04/24 08:25:42 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-c++/dbus-c++-0.9.0-r1.ebuild,v 1.3 2015/03/22 21:36:55 tetromino Exp $
 
 EAPI="4"
 
 inherit eutils
 
-DESCRIPTION="provide a C++ API for D-BUS"
+DESCRIPTION="Provides a C++ API for D-BUS"
 HOMEPAGE="http://sourceforge.net/projects/dbus-cplusplus/ http://sourceforge.net/apps/mediawiki/dbus-cplusplus/index.php?title=Main_Page"
 SRC_URI="mirror://sourceforge/dbus-cplusplus/lib${P}.tar.gz"
 
-LICENSE="GPL-2"
+LICENSE="LGPL-2.1+"
 SLOT="0"
 KEYWORDS="~amd64 ~arm ~ppc ~x86"
 IUSE="doc ecore glib static-libs test"
 
 RDEPEND="sys-apps/dbus
 	ecore? ( dev-libs/ecore )
-	glib? ( dev-libs/glib )"
+	glib? ( dev-libs/glib:2 )"
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
 	dev-util/cppunit
diff --git a/dev-libs/dbus-c++/dbus-c++-0.9.0-r2.ebuild b/dev-libs/dbus-c++/dbus-c++-0.9.0-r2.ebuild
new file mode 100644
index 000000000000..38b7f383c4e7
--- /dev/null
+++ b/dev-libs/dbus-c++/dbus-c++-0.9.0-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-c++/dbus-c++-0.9.0-r2.ebuild,v 1.1 2015/03/22 21:36:55 tetromino Exp $
+
+EAPI="5"
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES="modules"
+
+inherit autotools-multilib
+
+DESCRIPTION="Provides a C++ API for D-BUS"
+HOMEPAGE="http://sourceforge.net/projects/dbus-cplusplus/ http://sourceforge.net/apps/mediawiki/dbus-cplusplus/index.php?title=Main_Page"
+SRC_URI="mirror://sourceforge/dbus-cplusplus/lib${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="doc ecore glib static-libs test"
+
+RDEPEND="sys-apps/dbus[${MULTILIB_USEDEP}]
+	ecore? ( dev-libs/ecore )
+	glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	dev-util/cppunit[${MULTILIB_USEDEP}]
+	virtual/pkgconfig"
+
+S=${WORKDIR}/lib${P}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc-4.7.patch #424707
+)
+
+multilib_src_configure() {
+	# not just using autotools-multilib_src_configure because of multilib_native... logic
+
+	# TODO : add ecore multilib support if/when it is multilibified
+	ECONF_SOURCE="${S}" econf \
+		--disable-examples \
+		$(multilib_native_use_enable doc doxygen-docs) \
+		$(multilib_native_use_enable ecore) \
+		$(use_enable glib) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests) \
+		PTHREAD_LIBS=-lpthread
+	# ACX_PTHREAD sets PTHREAD_CFLAGS but not PTHREAD_LIBS for some reason...
+
+	if multilib_is_native_abi; then
+		# docs don't like out-of-source builds
+		local d
+		for d in img html; do
+			ln -s "${S}"/doc/${d} "${BUILD_DIR}"/doc/${d} || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use doc; then
+		dohtml -r "${S}"/doc/html/*
+	fi
+}
+