Version bump by "der bastler" from Gentoo Forums.

(Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

2 files changed, 72 insertions, 2 deletions

diff --git a/dev-libs/cyberjack/ChangeLog b/dev-libs/cyberjack/ChangeLog
index e17aefb1beee..0e47de7b3087 100644
--- a/dev-libs/cyberjack/ChangeLog
+++ b/dev-libs/cyberjack/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/cyberjack
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/ChangeLog,v 1.22 2011/10/30 14:13:33 ssuominen Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/ChangeLog,v 1.23 2012/01/23 09:42:20 ssuominen Exp $
+
+*cyberjack-3.99.5_p03 (23 Jan 2012)
+
+  23 Jan 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +cyberjack-3.99.5_p03.ebuild:
+  Version bump by "der bastler" from Gentoo Forums.
 
   30 Oct 2011; Samuli Suominen <ssuominen@gentoo.org>
   -cyberjack-3.99.5_p02.ebuild:
diff --git a/dev-libs/cyberjack/cyberjack-3.99.5_p03.ebuild b/dev-libs/cyberjack/cyberjack-3.99.5_p03.ebuild
new file mode 100644
index 000000000000..dc0382da0450
--- /dev/null
+++ b/dev-libs/cyberjack/cyberjack-3.99.5_p03.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/cyberjack/cyberjack-3.99.5_p03.ebuild,v 1.1 2012/01/23 09:42:20 ssuominen Exp $
+
+EAPI=4
+inherit toolchain-funcs
+
+MY_P=pcsc-${PN}_${PV/_p/final.SP}
+
+DESCRIPTION="REINER SCT cyberJack pinpad/e-com USB user space driver library"
+HOMEPAGE="http://www.reiner-sct.de/ http://www.libchipcard.de/"
+SRC_URI="http://support.reiner-sct.de/downloads/LINUX/V${PV/_p/_SP}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="fox kernel_linux xml"
+
+COMMON_DEPEND="sys-apps/pcsc-lite
+	virtual/libusb:1
+	fox? ( >=x11-libs/fox-1.6 )
+	xml? ( dev-libs/libxml2 )"
+RDEPEND="${COMMON_DEPEND}
+	kernel_linux? ( sys-fs/udev )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P/_/-}
+
+DOCS="ChangeLog NEWS doc/*.txt"
+
+src_configure() {
+	econf \
+		--mandir=/usr/share/man/man8 \
+		--sysconfdir=/etc/${PN} \
+		--disable-hal \
+		--enable-pcsc \
+		$(use_enable xml xml2) \
+		$(use_enable fox) \
+		--with-usbdropdir="$($(tc-getPKG_CONFIG) libpcsclite --variable=usbdropdir)"
+}
+
+src_install() {
+	default
+
+	rm -f "${ED}"usr/lib*/cyberjack/pcscd_init.diff
+	find "${ED}"usr -name '*.la' -exec rm -f {} +
+
+	# http://bugs.gentoo.org/388329
+	if use kernel_linux; then
+		insinto /lib/udev/rules.d
+		newins "${FILESDIR}"/${PN}.rules 92-${PN}.rules
+	fi
+}
+
+pkg_postinst() {
+	local conf="${EROOT}/etc/${PN}/${PN}.conf"
+	elog
+	elog "To configure logging, key beep behaviour etc. you need to"
+	elog "copy ${conf}.default"
+	elog "to ${conf}"
+	elog "and modify the latter as needed."
+	elog
+}