Version bump (bug #165837). Dropped static USE-flag.

(Portage version: 2.1.2-r7)

4 files changed, 122 insertions, 9 deletions

diff --git a/dev-libs/STLport/ChangeLog b/dev-libs/STLport/ChangeLog
index 08a969788a82..de50c5d19d66 100644
--- a/dev-libs/STLport/ChangeLog
+++ b/dev-libs/STLport/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/STLport
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/ChangeLog,v 1.43 2007/01/26 22:21:13 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/ChangeLog,v 1.44 2007/02/11 23:56:09 dev-zero Exp $
+
+*STLport-5.0.3 (11 Feb 2007)
+
+  11 Feb 2007; Tiziano Müller <dev-zero@gentoo.org> +STLport-5.0.3.ebuild,
+  STLport-5.1.0.ebuild:
+  Version bump (bug #165837). Dropped static USE-flag.
 
   26 Jan 2007; Tiziano Müller <dev-zero@gentoo.org>
   files/STLport-5.1.0-wrong_russian_currency_name.patch:
diff --git a/dev-libs/STLport/STLport-5.0.3.ebuild b/dev-libs/STLport/STLport-5.0.3.ebuild
new file mode 100644
index 000000000000..93ded04924c2
--- /dev/null
+++ b/dev-libs/STLport/STLport-5.0.3.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/STLport-5.0.3.ebuild,v 1.1 2007/02/11 23:56:09 dev-zero Exp $
+
+inherit eutils versionator eutils toolchain-funcs multilib flag-o-matic
+
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+DESCRIPTION="C++ STL library"
+HOMEPAGE="http://stlport.sourceforge.net/"
+SRC_URI="mirror://sourceforge/stlport/${P}.tar.bz2"
+LICENSE="as-is"
+SLOT="0"
+IUSE="boost"
+
+DEPEND="boost? ( dev-libs/boost )"
+RDEPEND="${RDEPEND}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/STLport-5.0.2-gcc41.patch"
+	epatch "${FILESDIR}/STLport-5.1.0-wrong_russian_currency_name.patch"
+
+	sed -i \
+		-e 's/\(OPT += \)-O2/\1/' \
+		build/Makefiles/gmake/*cc.mak \
+		|| die "sed opts failed"
+
+	sed -i \
+		-e 's/_STLP_VENDOR_CSTD::wcsftime/::wcsftime/' \
+		stlport/stl/_cwchar.h || die "sed failed"
+
+}
+
+src_compile() {
+	cat <<- EOF >> stlport/stl_user_config.h
+	#define _STLP_NATIVE_INCLUDE_PATH ../g++-v$(gcc-major-version)
+	EOF
+
+	sed -i \
+		-e "s|\(CC :=\) gcc|\1 $(tc-getCC)|" \
+		-e "s|\(CXX :=\) c++|\1 $(tc-getCXX)|" \
+		-e "s|^\(CFLAGS = \)|\1 ${CFLAGS} |" \
+		-e "s|^\(CCFLAGS = \)|\1 ${CFLAGS} |" \
+		build/Makefiles/gmake/gcc.mak || die "sed failed"
+
+	local myconf
+	if use boost ; then
+		myconf="${myconf} --with-boost=${ROOT}usr/include"
+		sed -i \
+			-e 'N;N;N;s:/\**\n\(#define _STLP_USE_BOOST_SUPPORT 1\)*\n\*/:\1:' \
+			stlport/stl_user_config.h
+	fi
+
+	cd "${S}/build/lib"
+
+	append-lfs-flags
+
+	# It's not an autoconf script
+	./configure \
+		${myconf} \
+		--with-extra-cxxflags="${CXXFLAGS}" || die "configure failed"
+
+	cd "${S}"
+
+	cat <<- EOF >> build/Makefiles/config.mak
+	CFLAGS := ${CFLAGS}
+	EOF
+
+	local targets
+	targets="all-shared all-static"
+
+	# The build-system is broken in respect to parallel builds, bug #161881
+	emake \
+		-j1 \
+		-C build/lib \
+		-f gcc.mak \
+		depend ${targets} || die "Compile failed"
+}
+
+src_install() {
+	emake -C build/lib -f gcc.mak install
+	dolib.so lib/*
+
+	emake -C build/lib -f gcc.mak install-static
+	dolib.a lib/*.a
+
+	insinto /usr/include
+	doins -r stlport
+
+	dodoc README etc/ChangeLog* etc/*.txt doc/*
+}
+
+src_test() {
+	cd "${S}/build"
+
+	sed -i \
+		-e "1aLDFLAGS := -L${S}/build/lib/obj/gcc/shared -L${S}/build/lib/obj/gcc/shared-g -L${S}/build/lib/obj/gcc/shared-stlg" \
+		test/unit/gcc.mak || die "sed failed"
+
+	emake -j1 -C test/unit -f gcc.mak || die "emake tests failed"
+
+	export LD_LIBRARY_PATH="./lib/obj/gcc/shared-stlg"
+	./test/unit/obj/gcc/shared-stlg/stl_unit_test || die "unit tests failed"
+}
diff --git a/dev-libs/STLport/STLport-5.1.0.ebuild b/dev-libs/STLport/STLport-5.1.0.ebuild
index 4f7e3cfd80b7..b39ed1c4e857 100644
--- a/dev-libs/STLport/STLport-5.1.0.ebuild
+++ b/dev-libs/STLport/STLport-5.1.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/STLport-5.1.0.ebuild,v 1.10 2007/01/26 21:40:04 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/STLport/STLport-5.1.0.ebuild,v 1.11 2007/02/11 23:56:09 dev-zero Exp $
 
 inherit eutils versionator eutils toolchain-funcs multilib flag-o-matic
 
@@ -11,7 +11,7 @@ HOMEPAGE="http://stlport.sourceforge.net/"
 SRC_URI="mirror://sourceforge/stlport/${P}.tar.bz2"
 LICENSE="as-is"
 SLOT="0"
-IUSE="boost static"
+IUSE="boost"
 
 DEPEND="boost? ( dev-libs/boost )"
 RDEPEND="${RDEPEND}"
@@ -71,8 +71,7 @@ src_compile() {
 	EOF
 
 	local targets
-	targets="all-shared"
-	use static && targets="${targets} all-static"
+	targets="all-shared all-static"
 
 	# The build-system is broken in respect to parallel builds, bug #161881
 	emake \
@@ -86,10 +85,8 @@ src_install() {
 	emake -C build/lib -f gcc.mak install
 	dolib.so lib/*
 
-	if use static ; then
-		emake -C build/lib -f gcc.mak install-static
-		dolib.a lib/*.a
-	fi
+	emake -C build/lib -f gcc.mak install-static
+	dolib.a lib/*.a
 
 	insinto /usr/include
 	doins -r stlport
diff --git a/dev-libs/STLport/files/digest-STLport-5.0.3 b/dev-libs/STLport/files/digest-STLport-5.0.3
new file mode 100644
index 000000000000..056ef0057099
--- /dev/null
+++ b/dev-libs/STLport/files/digest-STLport-5.0.3
@@ -0,0 +1,3 @@
+MD5 21d5275f4f8b190be1572b8498382091 STLport-5.0.3.tar.bz2 639508
+RMD160 9fac74a7177812c338b0e9a996cf7557ee90a437 STLport-5.0.3.tar.bz2 639508
+SHA256 5bdc0bb07180a8463b480c940e4294ca46cfdfed50b00d254539cb68ae4c2b24 STLport-5.0.3.tar.bz2 639508