Bump

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 84 insertions, 2 deletions

diff --git a/dev-lang/ferite/ChangeLog b/dev-lang/ferite/ChangeLog
index d041064f33e4..5e5bf0f923d6 100644
--- a/dev-lang/ferite/ChangeLog
+++ b/dev-lang/ferite/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/ferite
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/ferite/ChangeLog,v 1.32 2012/11/26 22:11:54 ulm Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/ferite/ChangeLog,v 1.33 2013/01/30 06:41:34 patrick Exp $
+
+*ferite-1.1.17 (30 Jan 2013)
+
+  30 Jan 2013; Patrick Lauer <patrick@gentoo.org> +ferite-1.1.17.ebuild:
+  Bump
 
   26 Nov 2012; Ulrich Müller <ulm@gentoo.org> ferite-1.0.2.ebuild:
   Fix LICENSE, BSD (3-clause) according to LICENSE file in tarball.
diff --git a/dev-lang/ferite/ferite-1.1.17.ebuild b/dev-lang/ferite/ferite-1.1.17.ebuild
new file mode 100644
index 000000000000..e7a469791d82
--- /dev/null
+++ b/dev-lang/ferite/ferite-1.1.17.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/ferite/ferite-1.1.17.ebuild,v 1.1 2013/01/30 06:41:34 patrick Exp $
+
+EAPI=4
+
+inherit autotools eutils multilib
+
+DESCRIPTION="A clean, lightweight, object oriented scripting language"
+HOMEPAGE="http://www.ferite.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE=""
+
+DEPEND="
+	>=dev-libs/libpcre-5
+	dev-libs/libxml2"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# use docsdir variable, install to DESTDIR
+	sed \
+		-e '/docsdir =/!s:$(prefix)/share/doc/ferite:$(DESTDIR)$(docsdir):' \
+		-i docs/Makefile.am || die
+
+	# Install docs to /usr/share/doc/${PF}, not .../${PN}
+	sed \
+		-e "s:doc/ferite:doc/${PF}:" \
+		-i Makefile.am \
+		docs/Makefile.am \
+		scripts/test/Makefile.am \
+		scripts/test/rmi/Makefile.am || die
+
+	# Don't override the user's LDFLAGS
+	sed \
+		-e 's:_LDFLAGS = :&$(AM_LDFLAGS) :' \
+		-e '/^LDFLAGS/s:^:AM_:' \
+		-i modules/*/Makefile.am \
+		libs/{aphex,triton}/src/Makefile.am \
+		src/Makefile.am || die
+
+	# Only build/install shared libs for modules (can't use static anyway)
+	sed -i -e '/_LDFLAGS/s:-module:& -shared:' modules/*/Makefile.am || die
+
+	# use LIBADD to ensure proper deps (fix parallel build)
+	sed \
+		-e '/^stream_la_LDFLAGS/s:-L\. -lferitestream::' \
+		-e '/^stream_la_LIBADD/s:$:libferitestream.la:' \
+		-i modules/stream/Makefile.am || die
+
+	# Make sure we install in $(get_libdir), not lib
+	sed -i -e "s|\$prefix/lib|\$prefix/$(get_libdir)|g" configure.ac || die
+
+	# We copy feritedoc to ${T} in src_install, then patch it in-situ
+	# note that this doesn't actually work right, currently - it still tries
+	# to pull from / instead of ${D}, and I can't figure out how to fix that
+	sed -i -e 's:$(prefix)/bin/:${T}/:' docs/Makefile.am || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --libdir="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_install() {
+	cp tools/doc/feritedoc "${T}" || die
+	sed -i -e '/^prefix/s:prefix:${T}:g' "${T}"/feritedoc || die
+	sed -i -e '/^$prefix/s:$prefix/bin/ferite:'"${ED}"'usr/bin/ferite:' "${T}"/feritedoc || die
+	sed -i -e 's:$library_path $library_path:${S}/tools/doc ${S}/tools/doc:' "${T}"/feritedoc || die
+	export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}${LD_LIBRARY_PATH:+:}${ED}usr/lib"
+	emake DESTDIR="${D}" LIBDIR="${EPREFIX}"/usr/$(get_libdir) install
+	prune_libtool_files
+}