Bump to snapshot for #454500

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 67 insertions, 2 deletions

diff --git a/dev-lang/tcc/ChangeLog b/dev-lang/tcc/ChangeLog
index b73d66f7fa44..be230ad3834f 100644
--- a/dev-lang/tcc/ChangeLog
+++ b/dev-lang/tcc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/tcc
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/tcc/ChangeLog,v 1.31 2010/08/16 20:05:34 truedfx Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tcc/ChangeLog,v 1.32 2013/01/29 09:31:34 patrick Exp $
+
+*tcc-0.9.26_pre1 (29 Jan 2013)
+
+  29 Jan 2013; Patrick Lauer <patrick@gentoo.org> +tcc-0.9.26_pre1.ebuild:
+  Bump to snapshot for #454500
 
   16 Aug 2010; Harald van Dijk <truedfx@gentoo.org> tcc-0.9.25.ebuild,
   +files/tcc-0.9.25-flags.patch:
diff --git a/dev-lang/tcc/tcc-0.9.26_pre1.ebuild b/dev-lang/tcc/tcc-0.9.26_pre1.ebuild
new file mode 100644
index 000000000000..c3f2fd9ea6f5
--- /dev/null
+++ b/dev-lang/tcc/tcc-0.9.26_pre1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/tcc/tcc-0.9.26_pre1.ebuild,v 1.1 2013/01/29 09:31:34 patrick Exp $
+
+EAPI="5"
+
+inherit eutils toolchain-funcs
+
+IUSE=""
+DESCRIPTION="A very small C compiler for ix86/amd64"
+HOMEPAGE="http://bellard.org/tcc/"
+SRC_URI="http://dev.gentoo.org/~patrick/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="app-text/texi2html" # doc generation
+# Both tendra and tinycc install /usr/bin/tcc
+RDEPEND="!dev-lang/tendra"
+
+# Testsuite is broken, relies on gcc to compile
+# invalid C code that it no longer accepts
+RESTRICT="test"
+
+src_prepare() {
+	# Don't strip
+	sed -i -e 's|$(INSTALL) -s|$(INSTALL)|' Makefile || die
+
+	# Fix examples
+	sed -i -e '1{
+		i#! /usr/bin/tcc -run
+		/^#!/d
+	}' examples/ex*.c || die
+	sed -i -e '1s/$/ -lX11/' examples/ex4.c || die
+
+	# fix texi2html invocation
+	sed -i -e 's/-number//' Makefile || die
+}
+
+src_configure() {
+	local myopts
+	use x86 && myopts="--cpu=x86"
+	use amd64 && myopts="--cpu=x86-64"
+	econf ${myopts} --cc="$(tc-getCC)"
+}
+
+src_install() {
+	emake \
+		bindir="${D}"/usr/bin \
+		libdir="${D}"/usr/lib \
+		tccdir="${D}"/usr/lib/tcc \
+		includedir="${D}"/usr/include \
+		docdir="${D}"/usr/share/doc/${PF} \
+		mandir="${D}"/usr/share/man install || die "make install failed"
+	dodoc Changelog README TODO VERSION
+	dohtml tcc-doc.html
+	exeinto /usr/share/doc/${PF}/examples
+	doexe examples/ex*.c
+}