Version bump. Includes now commons-beanutils-bean-collections.jar fixing bug #178898.

(Portage version: 2.2_rc23/cvs/Linux x86_64)

2 files changed, 72 insertions, 2 deletions

diff --git a/dev-java/commons-beanutils/ChangeLog b/dev-java/commons-beanutils/ChangeLog
index 72483339831b..1b1b3c6ba0c7 100644
--- a/dev-java/commons-beanutils/ChangeLog
+++ b/dev-java/commons-beanutils/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/commons-beanutils
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-beanutils/ChangeLog,v 1.44 2008/04/12 19:10:10 dertobi123 Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-beanutils/ChangeLog,v 1.45 2009/02/15 19:46:57 caster Exp $
+
+*commons-beanutils-1.8.0 (15 Feb 2009)
+
+  15 Feb 2009; Vlastimil Babka <caster@gentoo.org>
+  +commons-beanutils-1.8.0.ebuild:
+  Version bump. Includes now commons-beanutils-bean-collections.jar fixing
+  bug #178898.
 
   12 Apr 2008; Tobias Scherbaum <dertobi123@gentoo.org>
   commons-beanutils-1.7.0-r3.ebuild:
diff --git a/dev-java/commons-beanutils/commons-beanutils-1.8.0.ebuild b/dev-java/commons-beanutils/commons-beanutils-1.8.0.ebuild
new file mode 100644
index 000000000000..dd6b9a1eb251
--- /dev/null
+++ b/dev-java/commons-beanutils/commons-beanutils-1.8.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-beanutils/commons-beanutils-1.8.0.ebuild,v 1.1 2009/02/15 19:46:57 caster Exp $
+
+EAPI=2
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Provides easy-to-use wrappers around Reflection and Introspection APIs"
+HOMEPAGE="http://commons.apache.org/beanutils/"
+SRC_URI="mirror://apache/commons/beanutils/source/${P}-src.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="1.7"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE=""
+
+COMMON_DEP="
+	>=dev-java/commons-collections-2.1:0
+	>=dev-java/commons-logging-1.0.2:0"
+RDEPEND=">=virtual/jre-1.4
+	!<=dev-java/commons-betwixt-0.7-r1:0.7
+	!dev-java/commons-beanutils-collections
+	${COMMON_DEP}"
+DEPEND=">=virtual/jdk-1.4
+	test? (
+		dev-java/ant-junit
+		dev-java/junit:0
+		dev-java/commons-collections[test-framework]
+	)
+	${COMMON_DEP}"
+
+S="${WORKDIR}/${P}-src"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	rm -vr src/java/org/apache/commons/collections/ || die
+	JAVA_ANT_CLASSPATH_TAGS="javac java" java-ant_rewrite-classpath
+}
+
+EANT_GENTOO_CLASSPATH="commons-logging,commons-collections"
+
+src_test() {
+	EANT_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit"
+	ANT_TASKS="ant-junit" eant \
+		-Dcommons-collections.jar=$(java-pkg_getjar commons-collections commons-collections.jar) \
+		-Dcommons-collections-testframework.jar=$(java-pkg_getjar commons-collections commons-collections-testframework.jar) \
+		-Dcommons-logging.jar=$(java-pkg_getjar commons-logging commons-logging.jar) \
+		test
+}
+
+src_install() {
+	java-pkg_newjar dist/${P}.jar
+	java-pkg_newjar dist/${PN}-core-${PV}.jar ${PN}-core.jar
+	java-pkg_newjar dist/${PN}-bean-collections-${PV}.jar ${PN}-bean-collections.jar
+
+	dodoc README.txt RELEASE-NOTES.txt || die
+
+	use doc && java-pkg_dojavadoc dist/docs/api
+	use source && java-pkg_dosrc src/java/org
+}