Respect LDFLAGS. #355057

Integrate prefix changes by Benda Xu <heroxbd@gentoo.org>. #416373
Stop using xargs, drop userland_GNU from IUSE and the dependency on findutils.
Allow eselect-java be used instead of eselect-ecj.
EAPI bump, cleanup, add missing die.
Use same launcher for all slots, update rational for gcc-config lookup.

(Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 3C5CF75A)

4 files changed, 261 insertions, 1 deletions

diff --git a/dev-java/ecj-gcj/ChangeLog b/dev-java/ecj-gcj/ChangeLog
index 7413292fc481..06a319793b2b 100644
--- a/dev-java/ecj-gcj/ChangeLog
+++ b/dev-java/ecj-gcj/ChangeLog
@@ -1,6 +1,19 @@
 # ChangeLog for dev-java/ecj-gcj
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/ecj-gcj/ChangeLog,v 1.5 2012/09/16 13:12:54 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/ecj-gcj/ChangeLog,v 1.6 2012/12/14 13:08:17 sera Exp $
+
+*ecj-gcj-3.6-r1 (14 Dec 2012)
+*ecj-gcj-3.5.2-r3 (14 Dec 2012)
+
+  14 Dec 2012; Ralph Sennhauser <sera@gentoo.org> +ecj-gcj-3.5.2-r3.ebuild,
+  +ecj-gcj-3.6-r1.ebuild, +files/ecj-gcj.in:
+  Respect LDFLAGS. #355057
+  Integrate prefix changes by Benda Xu <heroxbd@gentoo.org>. #416373
+  Stop using xargs, drop userland_GNU from IUSE and the dependency on
+  findutils.
+  Allow eselect-java be used instead of eselect-ecj.
+  EAPI bump, cleanup, add missing die.
+  Use same launcher for all slots, update rational for gcc-config lookup.
 
   16 Sep 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
   ecj-gcj-3.6.ebuild:
diff --git a/dev-java/ecj-gcj/ecj-gcj-3.5.2-r3.ebuild b/dev-java/ecj-gcj/ecj-gcj-3.5.2-r3.ebuild
new file mode 100644
index 000000000000..5be798d85b2f
--- /dev/null
+++ b/dev-java/ecj-gcj/ecj-gcj-3.5.2-r3.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/ecj-gcj/ecj-gcj-3.5.2-r3.ebuild,v 1.1 2012/12/14 13:08:17 sera Exp $
+
+EAPI=5
+
+inherit java-pkg-2 prefix toolchain-funcs
+
+MY_PN="ecj"
+DMF="R-${PV}-201002111343"
+
+DESCRIPTION="A subset of Eclipse Compiler for Java compiled by gcj, serving as javac in gcj-jdk"
+HOMEPAGE="http://www.eclipse.org/"
+SRC_URI="http://download.eclipse.org/eclipse/downloads/drops/${DMF}/${MY_PN}src-${PV}.zip"
+
+LICENSE="EPL-1.0"
+SLOT="3.5"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="+native"
+
+COMMON_DEPEND="
+	sys-devel/gcc[gcj]
+	|| ( app-admin/eselect-java >=app-admin/eselect-ecj-0.6 )"
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	!dev-java/eclipse-ecj:3.5[gcj]"
+
+S="${WORKDIR}"
+
+# for compatibility with java eclass functions
+JAVA_PKG_WANT_SOURCE=1.4
+JAVA_PKG_WANT_TARGET=1.4
+
+MY_PS="${MY_PN}-${SLOT}"
+
+java_prepare() {
+	# We don't need the ant adapter here
+	rm -f org/eclipse/jdt/core/JDTCompilerAdapter.java || die
+	rm -fr org/eclipse/jdt/internal/antadapter || die
+
+	# upstream build.xml excludes this
+	rm -f META-INF/eclipse.inf || die
+
+	# these java6 specific classes cannot compile with ecj
+	rm -fr org/eclipse/jdt/internal/compiler/{apt,tool}/ || die
+}
+
+src_compile() {
+	local javac_opts javac java jar
+
+	local gccbin=$(gcc-config -B)
+	local gccver=$(gcc-fullversion)
+
+	local gcj="${gccbin}/gcj"
+	javac="${gcj} -C --encoding=ISO-8859-1"
+	jar="${gccbin}/gjar"
+	java="${gccbin}/gij"
+
+	mkdir -p bootstrap || die
+	cp -pPR org bootstrap || die
+	cd "${S}/bootstrap" || die
+
+	einfo "bootstrapping ${MY_PN} with ${javac} ..."
+	${javac} ${javac_opts} $(find org/ -name '*.java') || die
+	find org/ \( -name '*.class' -o -name '*.properties' -o -name '*.rsc' \) \
+		-exec ${jar} cf ${MY_PN}.jar {} + || die
+
+	cd "${S}" || die
+
+	einfo "building ${MY_PN} with bootstrapped ${MY_PN} ..."
+	${java} -classpath bootstrap/${MY_PN}.jar \
+		org.eclipse.jdt.internal.compiler.batch.Main \
+		${javac_opts} -nowarn org || die
+	find org/ \( -name '*.class' -o -name '*.properties' -o -name '*.rsc' \) \
+		-exec ${jar} cf ${MY_PN}.jar {} + || die
+
+	if use native; then
+		einfo "Building native ${MY_PS} library, patience needed ..."
+		${gcj} ${CFLAGS} ${LDFLAGS} -findirect-dispatch -shared -fPIC -Wl,-Bsymbolic \
+			-o ${MY_PS}.so ${MY_PN}.jar || die
+	fi
+}
+
+src_install() {
+	java-pkg_dojar ${MY_PN}.jar
+
+	sed -e "s|@SLOT@|${SLOT}|" \
+		"${FILESDIR}/${PN}.in" \
+		> "${T}"/${PN}-${SLOT} || die
+	eprefixify "${T}/${PN}-${SLOT}"
+	dobin  "${T}/${PN}-${SLOT}"
+
+	use native && dolib.so ${MY_PS}.so
+}
+
+pkg_postinst() {
+	if use native; then
+		$(gcc-config -B)/gcj-dbtool -a $(gcj-dbtool -p) \
+			"${EPREFIX}"/usr/share/${PN}-${SLOT}/lib/ecj.jar \
+			"${EPREFIX}"/usr/$(get_libdir)/${MY_PN}-${SLOT}.so
+	fi
+
+	einfo "To select between slots of ECJ..."
+	einfo " # eselect ecj"
+
+	eselect ecj update ${PN}-${SLOT}
+}
+
+pkg_postrm() {
+	eselect ecj update
+}
diff --git a/dev-java/ecj-gcj/ecj-gcj-3.6-r1.ebuild b/dev-java/ecj-gcj/ecj-gcj-3.6-r1.ebuild
new file mode 100644
index 000000000000..87ed21a476c7
--- /dev/null
+++ b/dev-java/ecj-gcj/ecj-gcj-3.6-r1.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/ecj-gcj/ecj-gcj-3.6-r1.ebuild,v 1.1 2012/12/14 13:08:17 sera Exp $
+
+EAPI=5
+
+inherit java-pkg-2 prefix toolchain-funcs
+
+MY_PN="ecj"
+DMF="R-${PV}-201006080911"
+
+DESCRIPTION="A subset of Eclipse Compiler for Java compiled by gcj, serving as javac in gcj-jdk"
+HOMEPAGE="http://www.eclipse.org/"
+SRC_URI="http://download.eclipse.org/eclipse/downloads/drops/${DMF}/${MY_PN}src-${PV}.zip"
+
+LICENSE="EPL-1.0"
+SLOT="3.6"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="+native"
+
+COMMON_DEPEND="
+	sys-devel/gcc[gcj]
+	|| ( app-admin/eselect-java >=app-admin/eselect-ecj-0.6 )"
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	!dev-java/eclipse-ecj:3.5[gcj]"
+
+S="${WORKDIR}"
+
+# for compatibility with java eclass functions
+JAVA_PKG_WANT_SOURCE=1.4
+JAVA_PKG_WANT_TARGET=1.4
+
+MY_PS="${MY_PN}-${SLOT}"
+
+java_prepare() {
+	# We don't need the ant adapter here
+	rm -f org/eclipse/jdt/core/JDTCompilerAdapter.java || die
+	rm -fr org/eclipse/jdt/internal/antadapter || die
+
+	# upstream build.xml excludes this
+	rm -f META-INF/eclipse.inf || die
+
+	# these java6 specific classes cannot compile with ecj
+	rm -fr org/eclipse/jdt/internal/compiler/{apt,tool}/ || die
+}
+
+src_compile() {
+	local javac_opts javac java jar
+
+	local gccbin=$(gcc-config -B)
+	local gccver=$(gcc-fullversion)
+
+	local gcj="${gccbin}/gcj"
+	javac="${gcj} -C --encoding=ISO-8859-1"
+	jar="${gccbin}/gjar"
+	java="${gccbin}/gij"
+
+	mkdir -p bootstrap || die
+	cp -pPR org bootstrap || die
+	cd "${S}/bootstrap" || die
+
+	einfo "bootstrapping ${MY_PN} with ${javac} ..."
+	${javac} ${javac_opts} $(find org/ -name '*.java') || die
+	find org/ \( -name '*.class' -o -name '*.properties' -o -name '*.rsc' \) \
+		-exec ${jar} cf ${MY_PN}.jar {} + || die
+
+	cd "${S}" || die
+
+	einfo "building ${MY_PN} with bootstrapped ${MY_PN} ..."
+	${java} -classpath bootstrap/${MY_PN}.jar \
+		org.eclipse.jdt.internal.compiler.batch.Main \
+		${javac_opts} -nowarn org || die
+	find org/ \( -name '*.class' -o -name '*.properties' -o -name '*.rsc' \) \
+		-exec ${jar} cf ${MY_PN}.jar {} + || die
+
+	if use native; then
+		einfo "Building native ${MY_PS} library, patience needed ..."
+		${gcj} ${CFLAGS} ${LDFLAGS} -findirect-dispatch -shared -fPIC -Wl,-Bsymbolic \
+			-o ${MY_PS}.so ${MY_PN}.jar || die
+	fi
+}
+
+src_install() {
+	java-pkg_dojar ${MY_PN}.jar
+
+	sed -e "s|@SLOT@|${SLOT}|" \
+		"${FILESDIR}/${PN}.in" \
+		> "${T}"/${PN}-${SLOT} || die
+	eprefixify "${T}/${PN}-${SLOT}"
+	dobin  "${T}/${PN}-${SLOT}"
+
+	use native && dolib.so ${MY_PS}.so
+}
+
+pkg_postinst() {
+	if use native; then
+		$(gcc-config -B)/gcj-dbtool -a $(gcj-dbtool -p) \
+			"${EPREFIX}"/usr/share/${PN}-${SLOT}/lib/ecj.jar \
+			"${EPREFIX}"/usr/$(get_libdir)/${MY_PN}-${SLOT}.so
+	fi
+
+	einfo "To select between slots of ECJ..."
+	einfo " # eselect ecj"
+
+	eselect ecj update ${PN}-${SLOT}
+}
+
+pkg_postrm() {
+	eselect ecj update
+}
diff --git a/dev-java/ecj-gcj/files/ecj-gcj.in b/dev-java/ecj-gcj/files/ecj-gcj.in
new file mode 100755
index 000000000000..4f838d5de240
--- /dev/null
+++ b/dev-java/ecj-gcj/files/ecj-gcj.in
@@ -0,0 +1,23 @@
+#!/bin/bash
+
+# /usr/bin/gij was installed by gcj-jdk in the past and is now handled by
+# gcc-config, fall back to gcc-config to locate the binary should the
+# symlink/wrapper-binary not yet exists.
+GIJ_BIN="@GENTOO_PORTAGE_EPREFIX@/usr/bin/gij"
+if [[ ! -f ${GIJ_BIN} ]]; then
+	GIJ_BIN="$(gcc-config -B)/gij"
+fi
+if [[ ! -f ${GIJ_BIN} ]]; then
+	echo "gij not found! check that gcc is compiled with gcj flag"
+	exit 1
+fi
+# calling java-config would be an unnecessary slowdown here
+
+# we need to append user CLASSPATH otherwise it will be overriden by the -classpath parameter
+# this breaks e.g. bootstrap of ant-core
+ecj_cp="@GENTOO_PORTAGE_EPREFIX@/usr/share/ecj-gcj-@SLOT@/lib/ecj.jar"
+if [[ -n "${CLASSPATH}" ]]; then
+	ecj_cp="${ecj_cp}:${CLASSPATH}"
+fi
+
+${GIJ_BIN} -classpath "${ecj_cp}" org.eclipse.jdt.internal.compiler.batch.Main "${@}"