Bumped to latest release

(Portage version: 2.1.4_rc3)

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-java/bcprov/bcprov-1.38.ebuild b/dev-java/bcprov/bcprov-1.38.ebuild
new file mode 100644
index 000000000000..4f7def9ca3a4
--- /dev/null
+++ b/dev-java/bcprov/bcprov-1.38.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/bcprov/bcprov-1.38.ebuild,v 1.1 2007/11/29 16:16:35 wltjr Exp $
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2
+
+MY_P="${PN}-jdk14-${PV/./}"
+DESCRIPTION="Java cryptography APIs"
+HOMEPAGE="http://www.bouncycastle.org/java.html"
+SRC_URI="http://www.bouncycastle.org/download/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+
+# The src_unpack find needs a new find
+# https://bugs.gentoo.org/show_bug.cgi?id=182276
+DEPEND=">=virtual/jdk-1.4
+	userland_GNU? ( >=sys-apps/findutils-4.3 )
+	app-arch/unzip"
+RDEPEND=">=virtual/jre-1.4"
+
+IUSE="userland_GNU"
+
+S="${WORKDIR}/${MY_P}"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	unpack ./src.zip
+
+	# so that we don't need junit
+	echo "Removing testcases' sources:"
+	find . -path '*test/*.java' -print -delete \
+		|| die "Failed to delete testcases."
+	find . -name '*Test*.java' -print -delete \
+		|| die "Failed to delete testcases."
+}
+
+src_compile() {
+	mkdir "${S}/classes"
+
+	find . -name "*.java" > "${T}/src.list"
+	ejavac -encoding ISO-8859-1 -d "${S}/classes" "@${T}/src.list"
+
+	cd "${S}/classes"
+	jar -cf "${S}/${PN}.jar" * || die "failed to create jar"
+}
+
+src_install() {
+	java-pkg_dojar "${S}/${PN}.jar"
+
+	use source && java-pkg_dosrc org
+	use doc && java-pkg_dojavadoc docs
+}