Version bump

(Portage version: 2.2_rc33/cvs/Linux i686)

2 files changed, 77 insertions, 1 deletions

diff --git a/dev-games/ode/ChangeLog b/dev-games/ode/ChangeLog
index a078044292bd..b656d0464fb8 100644
--- a/dev-games/ode/ChangeLog
+++ b/dev-games/ode/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-games/ode
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/ode/ChangeLog,v 1.51 2009/03/05 17:32:11 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-games/ode/ChangeLog,v 1.52 2009/05/25 11:24:49 nyhm Exp $
+
+*ode-0.11.1 (25 May 2009)
+
+  25 May 2009; Tristan Heaven <nyhm@gentoo.org> +ode-0.11.1.ebuild:
+  Version bump
 
 *ode-0.11 (05 Mar 2009)
 
diff --git a/dev-games/ode/ode-0.11.1.ebuild b/dev-games/ode/ode-0.11.1.ebuild
new file mode 100644
index 000000000000..7d8f5bbdbc87
--- /dev/null
+++ b/dev-games/ode/ode-0.11.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/ode/ode-0.11.1.ebuild,v 1.1 2009/05/25 11:24:49 nyhm Exp $
+
+EAPI=2
+DESCRIPTION="Open Dynamics Engine SDK"
+HOMEPAGE="http://ode.org/"
+SRC_URI="mirror://sourceforge/opende/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-2.1 BSD )"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc double-precision examples gyroscopic"
+
+RDEPEND="examples? (
+		virtual/opengl
+		virtual/glu
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	sed -i \
+		-e "s:\$.*/drawstuff/textures:/usr/share/doc/${PF}/examples:" \
+		drawstuff/src/Makefile.in \
+		ode/demo/Makefile.in \
+		|| die "sed Makefile.in failed"
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		--enable-shared \
+		$(use_enable debug asserts) \
+		$(use_enable double-precision) \
+		$(use_enable examples demos) \
+		$(use_enable gyroscopic) \
+		$(use_with examples drawstuff X11)
+}
+
+src_compile() {
+	emake || die "emake failed"
+	if use doc ; then
+		cd ode/doc
+		doxygen Doxyfile || die "doxygen failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc CHANGELOG.txt README.txt
+	if use doc ; then
+		dohtml docs/* || die "dohtml failed"
+	fi
+	if use examples; then
+		cd ode/demo
+		exeinto /usr/share/doc/${PF}/examples
+		local f
+		for f in *.c* ; do
+			doexe .libs/${f%.*} || die "doexe ${f%.*} failed"
+		done
+		cd ../..
+		doexe drawstuff/dstest/dstest
+		insinto /usr/share/doc/${PF}/examples
+		doins ode/demo/*.{c,cpp,h} \
+			drawstuff/textures/*.ppm \
+			drawstuff/dstest/dstest.cpp \
+			drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp} \
+			|| die "doins failed"
+	fi
+}