Version bump #530730 by Alexander Stein.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

3 files changed, 81 insertions, 8 deletions

diff --git a/dev-embedded/libftdi/ChangeLog b/dev-embedded/libftdi/ChangeLog
index 60987313bb34..d861b788be96 100644
--- a/dev-embedded/libftdi/ChangeLog
+++ b/dev-embedded/libftdi/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-embedded/libftdi
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-embedded/libftdi/ChangeLog,v 1.67 2015/04/18 03:06:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/libftdi/ChangeLog,v 1.68 2015/05/13 10:46:17 vapier Exp $
+
+*libftdi-1.2 (13 May 2015)
+
+  13 May 2015; Mike Frysinger <vapier@gentoo.org> +libftdi-1.2.ebuild,
+  libftdi-9999.ebuild:
+  Version bump #530730 by Alexander Stein.
 
   18 Apr 2015; Mike Frysinger <vapier@gentoo.org> libftdi-1.0.ebuild,
   libftdi-9999.ebuild:
diff --git a/dev-embedded/libftdi/libftdi-1.2.ebuild b/dev-embedded/libftdi/libftdi-1.2.ebuild
new file mode 100644
index 000000000000..a85f8d7b5028
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-1.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/libftdi/libftdi-1.2.ebuild,v 1.1 2015/05/13 10:46:17 vapier Exp $
+
+EAPI="4"
+
+inherit cmake-utils
+
+MY_P="${PN}1-${PV}"
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+	inherit git-2
+else
+	SRC_URI="http://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="http://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="cxx doc examples python static-libs tools"
+
+RDEPEND="virtual/libusb:1
+	cxx? ( dev-libs/boost )
+	python? ( dev-lang/python )
+	tools? (
+		!<dev-embedded/ftdi_eeprom-1.0
+		dev-libs/confuse
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use cxx FTDIPP)
+		$(cmake-utils_use doc DOCUMENTATION)
+		$(cmake-utils_use examples EXAMPLES)
+		$(cmake-utils_use python PYTHON_BINDINGS)
+		$(cmake-utils_use static-libs STATICLIBS)
+		$(cmake-utils_use tools FTDI_EEPROM)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc AUTHORS ChangeLog README TODO
+
+	if use doc ; then
+		# Clean up crap man pages. #356369
+		rm -vf "${CMAKE_BUILD_DIR}"/doc/man/man3/_* || die
+
+		doman "${CMAKE_BUILD_DIR}"/doc/man/man3/*
+		dohtml "${CMAKE_BUILD_DIR}"/doc/html/*
+	fi
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}
diff --git a/dev-embedded/libftdi/libftdi-9999.ebuild b/dev-embedded/libftdi/libftdi-9999.ebuild
index 6ce7dd5bd5f6..c4bad917a3be 100644
--- a/dev-embedded/libftdi/libftdi-9999.ebuild
+++ b/dev-embedded/libftdi/libftdi-9999.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-embedded/libftdi/libftdi-9999.ebuild,v 1.9 2015/04/18 03:06:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/libftdi/libftdi-9999.ebuild,v 1.10 2015/05/13 10:46:17 vapier Exp $
 
 EAPI="4"
 
-inherit cmake-utils eutils
+inherit cmake-utils
 
 MY_P="${PN}1-${PV}"
 if [[ ${PV} == 9999* ]] ; then
@@ -25,16 +25,15 @@ IUSE="cxx doc examples python static-libs tools"
 RDEPEND="virtual/libusb:1
 	cxx? ( dev-libs/boost )
 	python? ( dev-lang/python )
-	tools? ( dev-libs/confuse )"
+	tools? (
+		!<dev-embedded/ftdi_eeprom-1.0
+		dev-libs/confuse
+	)"
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )"
 
 S=${WORKDIR}/${MY_P}
 
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-1.0-staticlibs.patch
-}
-
 src_configure() {
 	mycmakeargs=(
 		$(cmake-utils_use cxx FTDIPP)
@@ -53,6 +52,9 @@ src_install() {
 	dodoc AUTHORS ChangeLog README TODO
 
 	if use doc ; then
+		# Clean up crap man pages. #356369
+		rm -vf "${CMAKE_BUILD_DIR}"/doc/man/man3/_* || die
+
 		doman "${CMAKE_BUILD_DIR}"/doc/man/man3/*
 		dohtml "${CMAKE_BUILD_DIR}"/doc/html/*
 	fi