Version bump. Drop python patch since the new code works for us as well. Fix compatibility with newer paramiko versions.

(Portage version: 2.1.10.11/cvs/Linux x86_64)

2 files changed, 94 insertions, 1 deletions

diff --git a/dev-db/mysql-workbench/ChangeLog b/dev-db/mysql-workbench/ChangeLog
index 3ed3469441e7..7f409fddd733 100644
--- a/dev-db/mysql-workbench/ChangeLog
+++ b/dev-db/mysql-workbench/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-db/mysql-workbench
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/ChangeLog,v 1.44 2011/10/04 01:35:29 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/ChangeLog,v 1.45 2011/12/14 19:30:38 graaff Exp $
+
+*mysql-workbench-5.2.36 (14 Dec 2011)
+
+  14 Dec 2011; Hans de Graaff <graaff@gentoo.org>
+  +mysql-workbench-5.2.36.ebuild:
+  Version bump. Drop python patch since the new code works for us as well. Fix
+  compatibility with newer paramiko versions.
 
   04 Oct 2011; Joseph Jezak <josejx@gentoo.org> mysql-workbench-5.2.34.ebuild,
   mysql-workbench-5.2.35.ebuild:
diff --git a/dev-db/mysql-workbench/mysql-workbench-5.2.36.ebuild b/dev-db/mysql-workbench/mysql-workbench-5.2.36.ebuild
new file mode 100644
index 000000000000..61f6e0cf4cb3
--- /dev/null
+++ b/dev-db/mysql-workbench/mysql-workbench-5.2.36.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-workbench/mysql-workbench-5.2.36.ebuild,v 1.1 2011/12/14 19:30:38 graaff Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+PYTHON_DEPEND=2
+
+inherit gnome2 eutils flag-o-matic python autotools
+
+MY_P="${PN}-gpl-${PV}-src"
+
+DESCRIPTION="MySQL Workbench"
+HOMEPAGE="http://dev.mysql.com/workbench/"
+SRC_URI="mirror://mysql/Downloads/MySQLGUITools/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug doc nls readline static-libs"
+
+CDEPEND="dev-db/sqlite:3
+	>=x11-libs/gtk+-2.6:2
+	dev-libs/glib:2
+	gnome-base/libglade:2.0
+	dev-libs/libsigc++:2
+	dev-libs/boost
+	>=dev-cpp/ctemplate-0.95
+	>=dev-libs/libxml2-2.6.2:2
+	>=dev-cpp/glibmm-2.14:2
+	>=dev-cpp/gtkmm-2.14:2.4
+	dev-libs/libzip
+	>=virtual/mysql-5.1
+	dev-libs/libpcre
+	virtual/opengl
+	>=dev-lang/lua-5.1[deprecated]
+	x11-libs/pango
+	|| ( sys-libs/e2fsprogs-libs
+		dev-libs/ossp-uuid )
+	>=x11-libs/cairo-1.5.12[svg]
+	dev-python/pexpect
+	dev-python/paramiko
+	doc? ( dev-python/pysqlite:2 )
+	nls? ( sys-devel/gettext )
+	readline? ( sys-libs/readline )"
+RDEPEND="${CDEPEND}
+	app-admin/sudo
+	sys-apps/net-tools"
+DEPEND="${CDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}"/"${MY_P}"
+
+pkg_setup() {
+	# Make sure we use Python 2 since the code is not compatible with 3.
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	# ifconfig isn't in the normal path
+	sed -i -e 's:ifconfig:/sbin/ifconfig:' plugins/wb.admin/backend/wb_server_control.py || die
+
+	# paramiko 1.7.7.1 is newer, update version range check:
+	# http://bugs.mysql.com/bug.php?id=63750
+	sed -i -e 's/4,5,6/4,5,6,7/' plugins/wb.admin/backend/wb_admin_ssh.py || die
+
+	# Remove bundled ctemplate version to make sure we use the system
+	# version, but leave a directory to avoid confusing configure, bug
+	# 357539.
+	rm -rf ext/ctemplate || die
+	mkdir -p ext/ctemplate/ctemplate-src || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls i18n) \
+		$(use_enable readline readline) \
+		$(use_enable debug) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	find "${ED}" -name '*.la' -delete || die
+}