Version bump per bug #237993.

(Portage version: 2.2_rc11/cvs/Linux 2.6.27-rc1-10246-gca5de40 x86_64)

2 files changed, 83 insertions, 1 deletions

diff --git a/dev-db/libdbi-drivers/ChangeLog b/dev-db/libdbi-drivers/ChangeLog
index 12fda3df9168..170837b5be9d 100644
--- a/dev-db/libdbi-drivers/ChangeLog
+++ b/dev-db/libdbi-drivers/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/libdbi-drivers
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v 1.26 2008/05/21 15:54:57 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/ChangeLog,v 1.27 2008/09/29 02:41:13 robbat2 Exp $
+
+*libdbi-drivers-0.8.3 (29 Sep 2008)
+
+  29 Sep 2008; Robin H. Johnson <robbat2@gentoo.org>
+  +libdbi-drivers-0.8.3.ebuild:
+  Version bump per bug #237993.
 
   21 May 2008; Tiziano Müller <dev-zero@gentoo.org>
   libdbi-drivers-0.7.1-r1.ebuild, libdbi-drivers-0.8.0.ebuild,
diff --git a/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild b/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild
new file mode 100644
index 000000000000..a2ad7c7f5455
--- /dev/null
+++ b/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/libdbi-drivers/libdbi-drivers-0.8.3.ebuild,v 1.1 2008/09/29 02:41:13 robbat2 Exp $
+
+inherit eutils
+
+MY_PV="${PV}-1"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="The libdbi-drivers project maintains drivers for libdbi."
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+HOMEPAGE="http://libdbi-drivers.sourceforge.net/"
+LICENSE="LGPL-2.1"
+DEPEND=">=dev-db/libdbi-0.8.3
+		mysql? ( virtual/mysql )
+		postgres? ( virtual/postgresql-server )
+		sqlite? ( <dev-db/sqlite-3 )
+		sqlite3? ( >=dev-db/sqlite-3 )
+		!bindist? ( firebird? ( dev-db/firebird ) )"
+
+IUSE="mysql postgres sqlite oci8 firebird sqlite3 bindist"
+KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
+SLOT=0
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	local drivers=""
+	use mysql && drivers="${drivers} mysql"
+	use postgres && drivers="${drivers} pgsql"
+	use sqlite && drivers="${drivers} sqlite"
+	use sqlite3 && drivers="${drivers} sqlite3"
+	if use firebird; then
+		if use bindist; then
+			eerror "The Interbase Public License is incompatible with LGPL, see bug #200284."
+			eerror "Disabling firebird in the build"
+		else
+			drivers="${drivers} firebird"
+		fi
+	fi
+	if use oci8; then
+		if [ -z "${ORACLE_HOME}" ]; then
+			die "\$ORACLE_HOME is not set!"
+		fi
+		drivers="${drivers} oracle"
+	fi
+	# safety check
+	if [ -z "${drivers// /}" ]; then
+		die "No supported databases in your USE flags! (mysql, postgres, sqlite, sqlite3, oracle, firebird)"
+	fi
+}
+
+src_compile() {
+	local myconf=""
+	# WARNING: the configure script does NOT work correctly
+	# --without-$driver does NOT work
+	# so do NOT use `use_with...`
+	use mysql && myconf="${myconf} --with-mysql"
+	use postgres && myconf="${myconf} --with-pgsql"
+	use sqlite && myconf="${myconf} --with-sqlite"
+	use sqlite3 && myconf="${myconf} --with-sqlite3"
+	use !bindist && use firebird && myconf="${myconf} --with-firebird"
+	if use oci8; then
+		if [ -z "${ORACLE_HOME}" ]; then
+			die "\$ORACLE_HOME is not set!"
+		fi
+		myconf="${myconf} --with-oracle-dir=${ORACLE_HOME} --with-oracle"
+	fi
+
+	econf ${myconf} || die "econf failed"
+	emake || die "emake failed"
+}
+
+src_install () {
+	emake install DESTDIR="${D}" || die "make install failed"
+	dodoc AUTHORS ChangeLog NEWS README README.osx TODO
+}